Запрос на БД

[TextBox1]

Сделал своё первое приложение к базе данных Access на Visual Basic .Net 2008.
Итак, на форме стоят:

- NameTextBox
- AdressTextBox

Теперь я хочу поставить на форму новый TextBox1 и кнопку (Button1) для ввода в текстовом поле нужной фамилии, а при нажатии кнопки происходил бы поиск по данному запросу. Но как это сделать, я пока не знаю. Помогите пожалуйста новичку.

[TextBox1]

Мда.... не густо с информацией ))

[MIT]

Теперь я хочу поставить на форму новый TextBox1 и кнопку (Button1)

Добавить новый TextBox1 и кнопку на форму за тебя?

[Roman Koff]

Код: Выделить всё

Imports System.Data
Imports System.Data.OleDb

Namespace DB

   Public Class OleDbClass : Implements System.IDisposable

      Public Connection As OleDbConnection
      Public Command As OleDbCommand
      Public DataReader As OleDbDataReader
      Public Result As Integer = 0
      Public ErrorMessage As String = ""

      Private _ConnectionString As String = ""
      Private _FieldPrefix As String = ""
      Private _DisposedValue As Boolean = False

      ' propeties ---------------------------------------------------------------------------------

      WriteOnly Property FieldPrefix() As String
         Set(ByVal value As String)
            Me._FieldPrefix = "@" & value
         End Set
      End Property

      ' functions ---------------------------------------------------------------------------------

      Function GetDataTable() As DataTable
         Dim _DataAdapter As New OleDbDataAdapter(Me.Command)
         Dim _DataTable As New DataTable
         _DataAdapter.Fill(_DataTable)
         Return _DataTable
      End Function

      Function GetInt(ByVal pFieldName As String) As Integer
         Dim _FieldName As String = Me._FieldPrefix & pFieldName
         Dim _Param As New OleDbParameter(_FieldName, System.Data.OleDb.OleDbType.Integer)
         _Param.Direction = ParameterDirection.Output
         Me.Command.Parameters.Add(_Param)
         Try
            Me.Connection.Open()
            Me.Command.ExecuteNonQuery()
         Catch
            Return -1
         Finally
            If Me.Connection.State = ConnectionState.Open Then Me.Connection.Close()
         End Try
         Return CType(_Param.Value, Integer)
      End Function

      Function GetValue(Of T)(ByVal pFieldName As String, ByVal pNullValue As T) As T
         Dim _FieldName As String = Me._FieldPrefix & pFieldName
         Dim _Value As T
         Dim _Data As Object = Me.DataReader(_FieldName)
         If Convert.IsDBNull(_Data) Then
            _Value = pNullValue
         Else
            _Value = CType(_Data, T)
         End If
         Return _Value
      End Function

      ' methods -----------------------------------------------------------------------------------

      Sub SetSql(ByVal pSql As String)
         Me.Connection = New OleDbConnection(Me._ConnectionString)
         Me.Command = New OleDbCommand(pSql, Me.Connection)
         Me.Command.CommandType = CommandType.Text
      End Sub

      Sub DataReaderOpen()
         Me.Connection.Open()
         Me.DataReader = Me.Command.ExecuteReader
      End Sub

      Sub DataReaderClose()
         Me.DataReader.Close()
         Me.Connection.Close()
      End Sub

      '============================================================================================

      Sub New(ByVal pDataBaseFile As String)
         Me._ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & pDataBaseFile
      End Sub

      Protected Overridable Sub Dispose(ByVal disposing As Boolean)
         If Not Me._DisposedValue Then
            If disposing Then
               ' TODO: free managed resources when explicitly called
            End If
            ' TODO: free shared unmanaged resources
            Me.Command.Dispose()
            Me.Connection.Dispose()
         End If
         Me._DisposedValue = True
      End Sub

      Public Sub Dispose() Implements IDisposable.Dispose
         Dispose(True)
         GC.SuppressFinalize(Me)
      End Sub

   End Class

End Namespace