Заполнение TreeView из массива

[Dmitry81]

Ребят, мучаюсь уже второй день, но никак не могу допереть, как сделать такое:

есть массив из строк:
УзелА\УзелБ\УзелВ
УзелА\УзелБ\УзелС
УзелF\УзелБ

надо из него построить в TreeView дерево, которое будет отображать приведенный выше массив. Условие: на каждом уровне имена узлов уникальны, т.е. по моему примеру будет один узел А, в нем один узел Б и в нем два узла(В и С), далее идет узел А и в нем узел Б...

Строки массива - не элементы файловой системы, просто строки с разделителями в виде "\".

[Alec]

как-то так

Код: Выделить всё

Sub sub1()
    'исходные значения
    Dim St() As String = {"УзелА\УзелБ\УзелВ", "УзелА\УзелБ\УзелС", "УзелF\УзелБ"}
    Dim P = "\"

    Dim i As Long
    Dim j As Long
    Dim S() As String
    Dim Nodes As TreeNodeCollection

    For i = 0 To St.Count - 1 'перебираем элементы исходного массива
      S = St(i).Split(P) 'разделяем на массив узлов
      Nodes = TreeView1.Nodes 'начинаем искать с корня дерева
      For j = 0 To S.Count - 1 'перебираем массив узлов
        If Nodes(S(j)) IsNot Nothing Then 'если такой узел есть, то "переходим" в него
          Nodes = Nodes(S(j)).Nodes
        Else ' иначе добавляем и "переходим"
          Nodes = Nodes.Add(S(j), S(j)).Nodes
        End If
      Next
    Next
  End Sub


[Dmitry81]

Спасибо огроменное. Немного порихтовал и под себя наладил: крайние узлы (последние в каждой строке) должны иметь другие картинки и теги.

Код: Выделить всё

Sub FillTree()
        'исходные значения
        Dim i As Integer
        Dim St As String() = {"УзелА\УзелБ\УзелВ", "УзелА\УзелБ\УзелС", "УзелF\УзелБ", "УзелF-\УзелБ-"}
        Dim P = Me.tvwStructure.PathSeparator
        Dim j As Integer
        Dim S() As String
        Dim Nodes As TreeNodeCollection
        Dim node As TreeNode
        For i = 0 To St.Length - 1 'перебираем элементы исходного массива
            S = St(i).Split(P) 'разделяем на массив узлов
            Nodes = Me.tvwStructure.Nodes 'начинаем искать с корня дерева
            For j = 0 To S.Length - 1 'перебираем массив узлов
                Try
                    If Nodes(S(j)) IsNot Nothing Then 'если такой узел есть, то "переходим" в него
                        Nodes = Nodes(S(j)).Nodes
                    Else ' иначе добавляем и "переходим"
                        If j < S.Length - 1 Then
                            node = Nodes.Add(S(j), S(j), "Folder", "Folder open")
                            node.Tag = "Folder"
                            Nodes = node.Nodes
                        Else
                            node = Nodes.Add(S(j), S(j), "Contact", "Contact open")
                            node.Tag = "Kontact"
                            Nodes = node.Nodes
                        End If
                    End If
                Catch ex As Exception
                End Try
            Next
        Next
    End Sub


еще раз сенкс! А то уже чет голова квадратная...

[1Steps]

Код: Выделить всё

Public Class Form1

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim st() As String = New String() {"УзелА\УзелБ\УзелВ", _
                                           "УзелА\УзелБ\УзелС", _
                                           "УзелА\УзелБ\УзелС", _
                                           "УзелА\УзелБ\УзелВ", _
                                           "УзелF\УзелБ\УзелВ"}

        For i As Integer = 0 To st.Length - 1
            Dim s() As String = st(i).Split("\"c)
            Me.AddItemToTreeview(s)
        Next
    End Sub

    Public Sub AddItemToTreeview(ByVal item As String())
        Dim nodes As TreeNodeCollection = TreeView1.Nodes
        For i As Integer = 0 To item.Length - 1
            nodes = If(nodes.Find(item(i), False).Length > 0, _
                       nodes.Find(item(i), False)(0).Nodes, _
                       nodes.Add(item(i), item(i)).Nodes)
        Next
    End Sub

[Dmitry81]

1Steps, спасибо. Я заценил твой код уже на pirit-e

[Nord777]

1Steps, а код Alec'а работает в два раза быстрее...

[1Steps]

1Steps, а код Alec'а работает в два раза быстрее...

Ну это и ежу понятно. Я подозреваю, в тривью не надо грузить ноды тысячами

[Nord777]

Я просто не понимаю, что вам обоим мешало написать такой вот простой код, который не только более читаемый, но и более быстрый.
Всё же на поверхности лежит...
Лень посмотреть в Object Browser?

Код: Выделить всё

      Dim nodes As TreeNodeCollection
      For Each S As String In st
         nodes = TreeView1.Nodes
         For Each S1 As String In S.Split("\"c)
            If nodes.ContainsKey(S1) Then
               nodes = nodes(S1).Nodes
            Else
               nodes = nodes.Add(S1, S1).Nodes
            End If
         Next
      Next

[Dmitry81]

ну вы даете!
Не думал, что мой вопрос создаст такое оживление...
Спасибо, други!

P.S. Да, действительно, я не собираюсь грузить ноды тысячами Думаю, сотни 3 максимум, да и то со временем.