События массива элементов управления TextBox

[AlekseyVB]

Создал массив элементов управления TextBox.

Код: Выделить всё

Dim arrTextBoxIncome(24) As TextBox
arrTextBoxIncome(1) = TextBox1 : arrTextBoxIncome(2) = TextBox2 : ..............


Мне нужно что бы работало что-то вроде события LostFocus для всех элементов массива. Например, что бы пересчитывалась сумма всех полей при каждом событии LostFocus. В ВБ6 это можно было легко реализовать. Как реализовать это в .Net?

[MIT]

Код: Выделить всё

public sub MyLostFocus(sender as object,e as object)
magbox (sender.tag)
end sub
Dim arrTextBoxIncome(24) As TextBox
arrTextBoxIncome(0) = TextBox1 : arrTextBoxIncome(0).tag = 0 : addhandler arrTextBoxIncome(0).lostfocus, addressof MyLostFocus

[AlekseyVB]

Спасибо, всё работает. Только приходится писать строку:

Код: Выделить всё

arrTextBoxIncome(1) = TextBox1 : arrTextBoxIncome(1).Tag = 1 : AddHandler arrTextBoxIncome(1).LostFocus, AddressOf subLostFocus


столько раз сколько количество элементов управления в массиве. Можно ли как-то сократить количество строк?

[MIT]

Можно попробовать засунуть все в 3 строчки.
Но для этого необходимо, что бы текстбоксы находились в одном контейнере (например все на форме) и имели что-то схожее в именах (или как вариант - что бы помимо нужных в контейнере не было других текстбоксов). Просто перебор коллекции Controls с отсеивающим условием - тип контрола (только текстбокс) и шаблоном имени (StartWith, например).

[Alec]

Дык массив уже есть:

Создал массив элементов управления TextBox.

По нему и перебирать

[MIT]

Заметь, что массив-то массивом, но он пустой и его надо заполнить:

Код: Выделить всё

arrTextBoxIncome(0) = TextBox1

[Alec]

Цитирую целиком:

Создал массив элементов управления TextBox.

Код: Выделить всё

Dim arrTextBoxIncome(24) As TextBox
arrTextBoxIncome(1) = TextBox1 : arrTextBoxIncome(2) = TextBox2 : ..............


Т.е. часть задачи, а именно заполнение массива, решена

[Alec]

To AlekseyVB:
А не проще ли создавать TextBox'ы при заполнении массива? Предполагаю они располагаются как-то упорядоченно?

[Денис]

Правильное .NET-решение это создавать элементы управления кодом и помещать их на форме в тех местах, где они должны стоять.
Автор же сначала кидает контролы на форму в дизайнере, а потом еще в коде дурную работу делает.
AlekseyVB, только без обид:
"Бешенной собаке и сто вёрст не крюк."

__________________
Зацените код (на форму ничего кидать не нужно!!):

Код: Выделить всё

Public Class Form1

    Private txtArray(5) As TextBox

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        Dim i As Integer

        For i = 0 To 5
            txtArray(i) = New TextBox
            With txtArray(i)
                .Parent = Me
                .Left = 10
                .Top = (.Height + 4) * i
                .Tag = i
                AddHandler .GotFocus, AddressOf MyGotFocus
            End With
        Next
    End Sub

    Private Sub MyGotFocus(ByVal Sender As System.Object, ByVal e As System.EventArgs)

        Dim i As Integer

        For i = 0 To 5
            txtArray(i).BackColor = Color.White
        Next

        txtArray(Sender.Tag).BackColor = Color.LightGray

    End Sub

End Class

Если вместо 5 проставить 50 то тот же код сделает 50 текстбоксов.

_________________
Иногда свойство Tag необходимо в работе, тогда сделаем полную эмуляцию массива контролов как в vb6.
Создадим новый класс, унаследуем его от TextBox, и пропишем в нем публичную переменную Index. Модифицированный код будет выглядеть так:

Код: Выделить всё

Public Class Form1

    Private txtArray(5) As IdxTextBox

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        Dim i As Integer

        For i = 0 To 5
            txtArray(i) = New IdxTextBox
            With txtArray(i)
                .Parent = Me
                .Left = 10
                .Top = (.Height + 4) * i
                .Index = i
                AddHandler .GotFocus, AddressOf MyGotFocus
            End With
        Next

    End Sub

    Private Sub MyGotFocus(ByVal Sender As System.Object, ByVal e As System.EventArgs)

        Dim i As Integer

        For i = 0 To 5
            txtArray(i).BackColor = Color.White
        Next

        txtArray(Sender.Index).BackColor = Color.LightGray

    End Sub

End Class

'------------------------------------------
'Вот он новый класс:
'------------------------------------------

Public Class IdxTextBox
    Inherits TextBox

    Public Index As Integer

End Class

[Nord777]

Денис, а для каких целей ты использовал класс IdxTextBox ?

[Денис]

Денис, а для каких целей ты использовал класс IdxTextBox ?

Невнимательно читаешь:

Иногда свойство Tag необходимо в работе, тогда сделаем полную эмуляцию массива контролов как в vb6.
Создадим новый класс, унаследуем его от TextBox, и пропишем в нем публичную переменную Index. Модифицированный код будет выглядеть так:

И да, я там правил код, сейчас поправил. Первая портянка со словом Index не работала бы я вернул туда Tag.

[Nord777]

Хорошо, тогда поверну по-другому: какова надобность в переменной index ?

[Денис]

Для удобства. И чтобы Tag использовать для других нужд.

[Nord777]

Я почему спрашиваю... я думал есть какой-то сакральный смысл...
Судя по всему нет, поэтому:
DirectCast( Sender, TextBox ).BackColor = ....