Enum, определяющий выбор параметра

[MIT]

Если задачу упростить до самого минимума, то в качестве "дано" есть:

Код: Выделить всё

        Public Enum SomeCEnum
            first = 1
            second = 2
            third = 3
            fourth = 4
        End Enum
        Public Structure SomeStructure
            Dim param1 As Integer
            Dim param2 As Integer
            Dim param3 As Integer
            Dim param4 As Integer
            Dim UParan As Integer
        End Structure
        Public Function GetParam(ByVal ss As SomeStructure, ByVal sce As SomeCEnum) As Integer

        End Function

Задача функции GetParam в следующем: она должна посмотреть на пришедший параметр sce и по нему вернуть paramX (например - пришло third, вернули param3). Прибегать к использованию конструкции Select Case не хотелось бы. Также возможна вариация задачи - вместо SomeCEnum может использоваться цифра.

[Debugger]

А объявить параметры типа как массив? Если не хочешь терять имена - можно создать еще один тип (с массивом), а потом CopyMemory'кать в него из первого типа.

[MIT]

А объявить параметры типа как массив?

Нет, массив тут не сделать. Как я сказал пример очень упрощенный, на самом деле структура довольно сложная, и имеет примерно такой вид (наверно так сильно упрощать не стоило... ):

Код: Выделить всё

    <StructLayout(LayoutKind.Explicit, Size:=8)> _
    Structure SomeStructure
        <FieldOffset(0)> Dim UParam As Integer
        <FieldOffset(0)> Dim param1 As Short
        <FieldOffset(2)> Dim param2 As Short
        <FieldOffset(4)> Dim HParam As Integer
        <FieldOffset(4)> Dim param3 As Short
        <FieldOffset(6)> Dim param4 As Short
    End Structure

Да, и производительность тут очень важна, т.е. желательно прямое обращение к параметру.

Конечно, можно использовать какую-нибудь такую функцию: GetShortData(ByVal ss as SomeStructure,ByVal Offset as byte) as short, но я не знаю, есть ли что-то подобное в функционале дотнета.

[MIT]

Блин, Маршалинг рулит неимоверно!

Код: Выделить всё

System.Runtime.InteropServices.Marshal.ReadInt16

[Nord777]

Блин, Маршалинг рулит неимоверно!

Не думаю что это самый быстрый способ.

[MIT]

Не думаю что это самый быстрый способ.

А какой же самый быстрый?

[Nord777]

Насчет самого быстрого не знаю, но только что сделал в 90 раз быстрее.
Я думаю это сильный аргумент, для того чтобы ты задумался о своем выборе.
А выглядит он примерно так:

Код: Выделить всё

   Dim i16 As ULong
   If sce <> 0 Then
      i16 = (ss.All >> (sce << 4))
   End If
   i16 = i16 And &HFFFF
   Return CType(i16, Integer)

[MIT]

Это типа как-то так:

Код: Выделить всё

    <StructLayout(LayoutKind.Explicit, Size:=8)> _
    Structure SomeStructure
        <FieldOffset(0)> Dim All As Long
        <FieldOffset(0)> Dim UParam As Integer
        <FieldOffset(0)> Dim param1 As Short
        <FieldOffset(2)> Dim param2 As Short
        <FieldOffset(4)> Dim HParam As Integer
        <FieldOffset(4)> Dim param3 As Short
        <FieldOffset(6)> Dim param4 As Short
    End Structure
    Public Enum SomeCEnum
        first = 1
        second = 2
        third = 3
        fourth = 4
    End Enum
    Public Function GetParam(ByVal ss As SomeStructure, ByVal sce As SomeCEnum) As Integer
        Dim i16 As ULong
        If sce <> 0 Then
            i16 = (ss.All >> (sce << 4))
        End If
        i16 = i16 And &HFFFF
        Return CType(i16, Integer)
    End Function

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim s As SomeStructure
        s.UParam = 1345135656
        s.HParam = 607560474

        Dim str As String = "Norm" & vbCrLf & s.param1 & "; " & s.param2 & "; " & s.param3 & "; " & s.param4 & vbCrLf & "Result" & vbCrLf

        For i As Integer = 1 To 4
            str &= GetParam(s, i) & "; "
        Next
        MsgBox(str)
        End
    End Sub

Но то ли я просто хочу спать, то ли работает оно как-то неверно...

добавлено:
Наверно ты имел в виду что-то типа

Return CType((ss.All >> ((sce - 1) << 4)) And &HFFFF, Integer)

Хотя и тут какая-то ошипка есть

еще добавлено:

Return CType((ss.All >> ((sce - 1) << 4)) And &HFFFF, Short)

еще чуть-чуть добавлено: + Remove integer overflow checks

[Nord777]

Почти угадал:

Код: Выделить всё

   Public Enum SomeCEnum As Integer
      first = 0
      second = 1
      third = 2
      fourth = 3
   End Enum

Код: Выделить всё

<FieldOffset(0)> Dim All As ULong

[MIT]

Код: Выделить всё

<FieldOffset(0)> Dim All As ULong

А какая разница, если мы число-то и не используем?

[Nord777]

Код: Выделить всё

   Public Enum SomeCEnum As Integer
      first = 0
      second = 1
      third = 2
      fourth = 3
   End Enum

   <StructLayout(LayoutKind.Explicit, Size:=8)> _
    Structure SomeStructure
      <FieldOffset(0)> Dim All As ULong
      <FieldOffset(0)> Dim UParam As UInteger
      <FieldOffset(0)> Dim param1 As UShort
      <FieldOffset(2)> Dim param2 As UShort
      <FieldOffset(4)> Dim HParam As UInteger
      <FieldOffset(4)> Dim param3 As UShort
      <FieldOffset(6)> Dim param4 As UShort
   End Structure

   Const Count As Integer = 1000000

   Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
      Dim out As UShort
      Dim Struct As New SomeStructure With {.param1 = &HAAAA, .param2 = &HBBBB, .param3 = &HCCCC, .param4 = &HDDDD}

      Dim Sw As Stopwatch = Stopwatch.StartNew
      For i As Integer = 0 To Count
         out = GetParam(Struct, SomeCEnum.third)
      Next
      Sw.Stop()
      MsgBox(Sw.ElapsedMilliseconds)
   End Sub

   Public Function GetParam(ByVal ss As SomeStructure, ByVal sce As Integer) As UShort
      Dim i16 As ULong
      If sce <> 0 Then
         i16 = (ss.All >> (sce << 4))
      End If
      Return CUShort(i16 And &HFFFF)
   End Function

Добавлено:

А какая разница, если мы число-то и не используем?

Ты наверно имел ввиду знак?
Если параметр ALL обьявить как Long, то на этой строке будет исключение:
i16 = (ss.All >> (sce << 4))
Впрочем, если тело функции будет содержать только одну строку
Return CUShort((ss.All >> (sce << 4)) And &HFFFF)
то можно оставить Long, исключения не будет.
Нет, вру, исключение всё же будет при SomeCEnum.first

[MIT]

Ты наверно имел ввиду знак?

Ну, как бы, да

Нет, вру, исключение всё же будет при SomeCEnum.first

Хде?

Код: Выделить всё

  <StructLayout(LayoutKind.Explicit, Size:=8)> _
    Structure SomeStructure
        <FieldOffset(0)> Dim All As Long
        <FieldOffset(0)> Dim UParam As Integer
        <FieldOffset(0)> Dim param1 As Short
        <FieldOffset(2)> Dim param2 As Short
        <FieldOffset(4)> Dim HParam As Integer
        <FieldOffset(4)> Dim param3 As Short
        <FieldOffset(6)> Dim param4 As Short
    End Structure
    Public Enum SomeCEnum As Integer
        first = 1
        second = 2
        third = 3
        fourth = 4
    End Enum
    Public Function GetParam(ByVal ss As SomeStructure, ByVal sce As SomeCEnum) As Short
        Return CType((ss.All >> ((sce - 1) << 4)) And &HFFFF, Short)
    End Function

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim s As New SomeStructure With {.param1 = &HAAAA, .param2 = &HBBBB, .param3 = &HCCCC, .param4 = &HDDDD}
       
        Dim str As String = s.param1 & "; " & s.param2 & "; " & s.param3 & "; " & s.param4 & vbCrLf & "Result" & vbCrLf
        For i As Integer = 1 To 4
            str &= GetParam(s, i) & "; "
        Next
        MsgBox(str)
        End
    End Sub

Ммм... Может дело в

еще чуть-чуть добавлено: + Remove integer overflow checks

P.S.:
Про

As New SomeStructure With

не знал. Прикольно

[Nord777]

Ммм... Может дело в

еще чуть-чуть добавлено: + Remove integer overflow checks

Ты отключил проверку? Надеюсь ты понимаешь, что отключил "доброго избавителя" от глюков?
Я не спорю, так оно конечно проще...
А не пробовал разобраться, почему происходит переполнение?

[MIT]

А не пробовал разобраться, почему происходит переполнение?

Ну, я впринципе понимаю почему так происходит (в 2х-байтовый Short "засовывается" 4х байтовый Integer, что может вызвать ошибку), но в чем тут разбираться?

[Nord777]

Ну, я впринципе понимаю почему так происходит (в 2х-байтовый Short "засовывается" 4х байтовый Integer, что может вызвать ошибку),

Ты ошибаешься.

[MIT]

Поправь

[Nord777]

А ты разбей одно строку на несколько. Чтобы в каждой строке было по одному оператору.
И увидишь где происходит ошибка.