Чтение png в матрицу . . .

[программист]

Необходимо прочитать png-рисунок 256x256 и занести цвет каждаго пиксела в матрицу 256x256, те пиксел 0,0 в эл матрицы (0,0).

P.S. - такой темы не нашел...

[Создатель]

Код: Выделить всё

Dim b As New System.Drawing.Bitmap("C:\1.png")
        MessageBox.Show(b.GetPixel(0, 0).ToString)
        MessageBox.Show(Convert.ToString(b.Height))
        MessageBox.Show(Convert.ToString(b.Width))
        b.SetPixel(0, 0, Color.Black)

С забиванием значений в матрицу я думаю проблем быть не должно?

[Viper]

Создатель, все правильно, только вместо GetPixel надо использовать метод LockBits.

[программист]

Создатель
с матрицами проблем нет (по крайней мере за 5 лет не возникало, пока что), а если не влом в 2-х словах раскажи как ентот код работает?

[Viper]

программист, код от Создатель будет работать медленно! Суть его кода в том, что он считывает методом GetPixel значение каждого пикселя матрицы рисунка. Правильный способ - использование метда LockBits. Пример вытащен из MSDN:

Код: Выделить всё

Private Sub LockUnlockBitsExample()

    ' Create a new bitmap.
    Dim bmp As New Bitmap("c:\picture.png")

    ' Lock the bitmap's bits. 
    Dim rect As New Rectangle(0, 0, bmp.Width, bmp.Height)
    Dim bmpData As System.Drawing.Imaging.BitmapData = bmp.LockBits(rect, _
        Drawing.Imaging.ImageLockMode.ReadWrite, bmp.PixelFormat)

    ' Get the address of the first line.
    Dim ptr As IntPtr = bmpData.Scan0

    ' Declare an array to hold the bytes of the bitmap.
    ' This code is specific to a bitmap with 24 bits per pixels.
    Dim bytes As Integer = bmp.Width * bmp.Height * 3
    Dim rgbValues(bytes - 1) As Byte

    ' Copy the RGB values into the array.
    System.Runtime.InteropServices.Marshal.Copy(ptr, rgbValues, 0, bytes)

    ' Set every red value to 255. 
    For counter As Integer = 0 To rgbValues.Length - 1 Step 3
        rgbValues(counter) = 255
    Next

    ' Copy the RGB values back to the bitmap
    System.Runtime.InteropServices.Marshal.Copy(rgbValues, 0, ptr, bytes)

    ' Unlock the bits.
    bmp.UnlockBits(bmpData)
End Sub

[программист]

спасибо всем! теперь буду разбиратья...

[программист]

С читалкой пиксела разобрался. А как теперь из матрицы считать эти самые пикселы на форму (left=0, top=0 - для простоты примера)???

[Viper]

На форму в каком смысле? Отрисовать штоль?

[программист]

ну да

[Viper]

так у тебя же изначально рисунок есть, отображай его там где надо через Graphics.DrawImage

[программист]

Код: Выделить всё

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim b As Image = Image.FromFile("C:\1.png")
        Me.CreateGraphics.DrawImage(b, 0, 0, 256, 256)
    End Sub

Что-то ничего не грузит

[программист]

запихнул изо в ресурс
пишу:

Код: Выделить всё

Me.CreateGraphics.DrawImage(bit_read.My.Resources._1, 0, 0, 256, 256)

тоже ничего на форме не рисуется

[Nord777]

либо так:

Код: Выделить всё

Public Class Form1
  Dim b As Image = Image.FromFile("C:\1.png")

   Private Sub Form1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
    e.Graphics.DrawImage(b, 0, 0, 256, 256)
  End Sub
End Class

либо так:

Код: Выделить всё

Public Class Form1

  Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    Me.BackgroundImage = Image.FromFile("C:\1.png")
  End Sub

End Class

[программист]

Nord777
не пашет!

[Viper]

программист, а должно! Который вариант не пашет? Используемый вариант кода приведи.

[программист]

Вариант с BackgroundImage (приведенный Nord777) не подходит.
.....
.....
.....
Ура заработало!!!
короче копировал себе в проект след код (первый приведенный Nord777) :

Код: Выделить всё


Dim b As Image = Image.FromFile("C:\1.png")
Private Sub Form1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
          e.Graphics.DrawImage(b, 0, 0, 256, 256)
End Sub

... не работал.
А когда скопировал весь класс Form1:

Код: Выделить всё


Public Class Form1
  Dim b As Image = Image.FromFile("C:\1.png")
  Private Sub Form1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
        e.Graphics.DrawImage(b, 0, 0, 256, 256)
  End Sub
End Class

- все заработало!

[программист]

Создатель, Viper, Nord777, ОГРОМНОЕ ВАМ СПАСИБО!!!