Разбить Long

[artyuha]

Привет всем!

Вот возник тут у меня такой вопрос. Как 4-х байтное целое раскидать по 4-м одно байтным.

Я думаю, что примерно так:

Dim L as long

L=36000000

Dim f1, f2, f3, f4 As Byte

f1 = L / 256 ^ 3
f2 = (L - f1 * 256 ^ 3) / 256 ^ 2
f3 = (L - f1 * 256 ^ 3 - f2 * 256 ^ 2) / 256
f4 = (L - f1 * 256 ^ 3 - f2 * 256 ^ 2 - f3 * 256)
MsgBox f1 & ":" & f2 & ":" & f3 & ":" & f4

, но при этом выйдут запары с округлением чисел. Т. е. Мне надо так разделить, чтоб остаток от деления не принимался во внимание.

[_Мика_]

Int откидывает дробную часть числа т.е. (наверное) остаток!

[Amed]

Код: Выделить всё

Dim byte1 As Byte, byte2 As Byte, byte3 As Byte, byte4 As Byte
Dim sum As Long

sum = 255& * 255& * 255& * 15

byte1 = sum \ 255 \ 255 \ 255
byte2 = (sum - byte1 * 255& * 255& * 255&) \ 255
byte3 = sum - byte1 * 255& * 255& * 255& - byte2 * 255& * 255&
byte4 = sum - byte1 * 255& * 255& * 255& - byte2 * 255& * 255& - byte3 * 255&

MsgBox sum = byte1 * 255& * 255& * 255& + byte2 * 255& * 255& + byte3 * 255& + byte4


[tyomitch]

Оператор деления без остатка - "\"

Код: Выделить всё

MsgBox 10 \ 3 ' выведет 3


Int здесь не нужен.


[edit]2Amed: [/edit]
[edit2]2AAZ: [/edit2]

[A.A.Z.]

Противоречишь сам себе То "/", то "\"

[Amed]

[edit]2Amed: [/edit]
[edit2]2AAZ: [/edit2]

[A.A.Z.]

http://bbs.vbstreets.ru/viewtopic.php?t=13432

[A.A.Z.]

Блин, че-то сообщения слишом быстро добавляются Я, как обычно, не в тему

[tyomitch]

Эх, жалко alibek-а нету, а то бы початились...

[artyuha]

Нефига. Пишу:

Dim L As Long

L = 36.6

Print Int(L)

Выдаёт 37. Хотя Print Int(36.6) выдаёт 36

[Amed]

Dim L as Long

Поэтому L по любому будет целым... И при присваивании

Код: Выделить всё

L=36.6

L сразу же округляется до 37. А Int(36.6) возвращает целую часть числа, т.е. 36...

Понятно?

[artyuha]

Плуганул. Понятно

[artyuha]

Тут Amed писал:

byte1 = sum \ 255 \ 255 \ 255

разве это не будет равнозначно

byte1 = sum * 255 \ 255^2

, как это бы соответствывало при преобразовании 4-х этажной дроби (в математике)

[Amed]

Это не четырёхэтажная дробь получается, а

byte1 = sum \ (255& * 255& * 255&)

[alibek]

Эх, опять опоздал
А нельзя однобайтные объявить как массив и воспользоваться CopyMemory? И проще и быстрее.

[GSerg]

Да, да!
Давайте ещё byte safearray создадим на основе long!

А ещё есть LSet - тоже ага!

[alibek]

LSet не покатит, разве что создавать промежуточные Integer

[GSerg]

Код: Выделить всё

Option Explicit

Private Type l
  l As Long
End Type

Private Type b
  a As Byte
  b As Byte
  c As Byte
  d As Byte
End Type

Private Sub Form_Load()
  Dim l As l, b As b
 
  l.l = &H12345678
  LSet b = l
 
  MsgBox Hex$(b.d) & "-" & Hex$(b.c) & "-" & Hex$(b.b) & "-" & Hex$(b.a)
End Sub

[alibek]

Э... А... Ну да
Я что-то перепутал наоборот, в Long вписать Byte.

[GSerg]

Код: Выделить всё

Option Explicit

Private Type l
  l As Long
End Type

Private Type b
  a As Byte
  b As Byte
  c As Byte
  d As Byte
End Type

Private Sub Form_Load()
  Dim l As l, b As b
 
  b.a = &H78
  b.b = &H56
  b.c = &H34
  b.d = &H12
 
  LSet l = b
 
  MsgBox Hex$(l.l)
End Sub

[alibek]

Все, молчу, молчу...

[Andrey Fedorov]

Что-то вы накрутили - ведь тут все дюже просто:

Код: Выделить всё

    Dim m(3) As Byte, a As Long
   
    a = &H343E45CA
    CopyMemory m(0), a, 4
    Debug.Print Hex(m(3)), Hex(m(2)), Hex(m(1)), Hex(m(0))


И только-то...

[tyomitch]

Утверждается, что это медленнее, чем делением.

[artyuha]

Кажыся раздуплился как делением. Кому интересно вышл код у меня такого плана:

Dim byte1 As Byte, byte2 As Byte, byte3 As Byte, byte4 As Byte
Dim sum As Long, f As Long

sum = -2000000056

If sum >= 0 Then
byte1 = sum \ 256 ^ 3
byte2 = (sum - byte1 * 256 ^ 3) \ 256 ^ 2
byte3 = (sum - byte1 * 256 ^ 3 - byte2 * 256 ^ 2) \ 256
f = byte3
byte4 = sum - byte1 * 256 ^ 3 - byte2 * 256 ^ 2 - 256 * f
Else
sum = Abs(sum) - 1
byte1 = sum \ 256 ^ 3
byte2 = (sum - byte1 * 256 ^ 3) \ 256 ^ 2
byte3 = (sum - byte1 * 256 ^ 3 - byte2 * 256 ^ 2) \ 256
f = byte3
byte4 = sum - byte1 * 256 ^ 3 - byte2 * 256 ^ 2 - 256 * f

byte1 = 255 - byte1
byte2 = 255 - byte2
byte3 = 255 - byte3
byte4 = 255 - byte4
End If

MsgBox byte1 & ":" & byte2 & ":" & byte3 & ":" & byte4

Накручен, но всё вроде работает.
Проверял кодом другого плана :

Dim L As Long
Dim Fileno As Byte
Dim byte1 As Byte, byte2 As Byte, byte3 As Byte, byte4 As Byte

L = -2000000056
Fileno = FreeFile

Open App.Path & "\1.ini" For Output As Fileno
Close Fileno

Open App.Path & "\1.ini" For Binary As Fileno
Put #Fileno, , L

Get #Fileno, 1, byte1
Get #Fileno, 2, byte2
Get #Fileno, 3, byte3
Get #Fileno, 4, byte4
Close Fileno

MsgBox byte4 & ":" & byte3 & ":" & byte2 & ":" & byte1

ТОЖЕ ТАК НИЧЁ

Спасибо за “\”

Только у меня возник ещё один вопрос. Почему byte1 * 256 ^ 3 работает отлично, а 256 * byte3 выдаёт ошибку переполнения.

[tyomitch]

Потому что пиши 256& вместо 256, и будет тебе Щастье.