Копирование(Буфер).

[Akella]

Скажите как отследить тот момент когда в буфер обмена попадает скопированные данные.И как отследить когда нажимается кнопка КОПИРОВАТЬ. Спасибо

[alibek]

Таймером или сабклассировать буфер обмена. Но в последнем случае надо быть аккуратным и передавать управление предыдущему обработчику.

[XairOn]

Вот пример сабклассинга из API-Guide:
Фрома

Код: Выделить всё

Private Sub Form_Load()
    HookForm Me
    SetClipboardViewer Me.hwnd
End Sub
Private Sub Form_Unload(Cancel As Integer)
    UnHookForm Me
End Sub
Private Sub Command1_Click()
    Clipboard.Clear
    Clipboard.SetText "Hello !"
End Sub


А вот и модуль:

Код: Выделить всё

Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Declare Function SetClipboardViewer Lib "user32" (ByVal hwnd As Long) As Long
Public Const WM_DRAWCLIPBOARD = &H308
Public Const GWL_WNDPROC = (-4)
Dim PrevProc As Long
Public Sub HookForm(F As Form)
    PrevProc = SetWindowLong(F.hwnd, GWL_WNDPROC, AddressOf WindowProc)
End Sub
Public Sub UnHookForm(F As Form)
    SetWindowLong F.hwnd, GWL_WNDPROC, PrevProc
End Sub
Public Function WindowProc(ByVal hwnd As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    WindowProc = CallWindowProc(PrevProc, hwnd, uMsg, wParam, lParam)
    If uMsg = WM_DRAWCLIPBOARD Then
        MsgBox "Clipboard changed ..."
    End If
End Function