Запуск файла соотв. программой

[Алексей К.]

К примеру есть:
имя_файла_с_путем="c:\text.doc"
имя_файла_с_путем1="c:\tabl.xls"
имя_файла_с_путем2="c:\img.dwg"
Можно ли и как сделать загрузку этих файлов из проги VB. Т.е. нажимаем кнопку, передаем имя файла и загружается программа соответствующая этому типу файла (будет загружаться word или excell и тд.). Типа shell имя_файла. Хочу свой мини-командер написать.
Если можно приведите пример кода.

[XairOn]

А чем тебя "shell имя_файла" не устраивает?

[VOS]

Мне кажется, что просто при указании "shell имя_файла" должна открываться сопоставленная программа? Или нет?


[off]
Черт! меня опередили!
[/off]

[Александр80]

можно с помощью API
ShellExecute

'This example requires a command button (Command1)
Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function GetSystemDirectory Lib "kernel32" Alias "GetSystemDirectoryA" (ByVal lpBuffer As String, ByVal nSize As Long) As Long
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
Const SW_SHOWNORMAL = 1
Const SE_ERR_NOASSOC = 31
Const sOperation As String = "open" ' Constants for shell operations
Const sRun As String = "RUNDLL32.EXE"
Const sParameters As String = "shell32.dll,OpenAs_RunDLL "
Private Function shelldoc(sfile As String)
Dim sPath As String, RetVal As Long, _
lRet As Long
lRet = ShellExecute(GetDesktopWindow(), sOperation, sfile, _
vbNullString, vbNullString, SW_SHOWNORMAL)
If lRet = SE_ERR_NOASSOC Then ' No association exists
'Create a buffer
sPath = Space(255)
'Get the system directory
RetVal = GetSystemDirectory(sPath, 255)
'Remove all unnecessary chr$(0)'s
'and move on the stack
sPath = Left$(sPath, RetVal)

lRet = ShellExecute(GetDesktopWindow(), "open", sRun, _
sParameters + sfile, sPath, SW_SHOWNORMAL)
End If
End Function
Private Sub Command1_Click()
Call shelldoc("C:\myfile.txt")
End Sub

[hCORe]

Мне кажется, что просто при указании "shell имя_файла" должна открываться сопоставленная программа? Или нет?


[off]
Черт! меня опередили!
[/off]

Увы, нет!

[XairOn]

Я наверное опять что-то не так понял, но почему бы не просто вот так это делать:

Код: Выделить всё

ShellExecute Me.hwnd, "open", FileName, vbNullString, vbNullString, 1

[Александр80]

Тогда еще вот это...

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long


XairOn - Так.... Кажется

[Алексей К.]

Всем спасибо, вариант ShellExecute работает нормально. Только когда нет файла в указанном пути - никаких ошибок не выдает, и когда неизвестное расширение (винда не знает его) как отловить диалоговое окно windows "открыть с помощью"?

[Eugenio]

Типа, наверное, наиболее полная инфа про ассоциацию файлов (начало, дальше по ссылкам, наверно, можно отыскать полезное).
http://search.microsoft.com/search/results.aspx?qu=file+associations&View=msdn&st=b&c=0&s=1&swc=0