Kak можно отследить попадание мыши

[Akella]

Kak можно отследить попадание мыши в облость заданную N-точками (например: трапеция, Триугольник). Спасибо

[GSerg]

По mousemove проверять PtInRgn.

[Akella]

Это как ?

[Akella]

Ну скажите ктонибудь, как это провернуть

[GSerg]

Для начала, на чём (своя форма, не своя форма, весь экран...)

[Akella]

На своей форме , и на экране тоже можно на всякий случай

[Konst_One]

Код: Выделить всё

Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
Private Declare Function PtInRect Lib "user32" (lpRect As RECT, ByVal x As Long, ByVal y As Long) As Long
Private Declare Function PtInRegion Lib "gdi32" (ByVal hRgn As Long, ByVal x As Long, ByVal y As Long) As Long
Private Declare Function CreateEllipticRgnIndirect Lib "gdi32" (lpRect As RECT) As Long
Private Declare Function SetPixelV Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal crColor As Long) As Long
Private Declare Function SetRect Lib "user32" (lpRect As RECT, ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
Private Sub Form_Load()
    'KPD-Team 1999
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    Dim mRGN As Long, R As RECT, x As Long, y As Long
    'Set the graphical mode to persistent
    Me.AutoRedraw = True
    'Set the rectangle's values
    SetRect R, 0, 0, 50, 50
    'Create an elliptical region
    mRGN = CreateEllipticRgnIndirect(R)
    For x = R.Left To R.Right
        For y = R.Top To R.Bottom
            'If the point is in the region, draw a green pixel
            If PtInRegion(mRGN, x, y) <> 0 Then
                'Draw a green pixel
                SetPixelV Me.hdc, x, y, vbGreen
            ElseIf PtInRect(R, x, y) <> 0 Then
                'Draw a red pixel
                SetPixelV Me.hdc, x, y, vbRed
            End If
        Next y
    Next x
    'delete our region
    DeleteObject mRGN
End Sub

[Akella]

а как узнать попала мыщь в облость

[A.A.Z.]

Код: Выделить всё

Option Explicit

Private Type POINTAPI
X As Long
Y As Long
End Type

Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
Private Declare Function PtInRegion Lib "gdi32" (ByVal hRgn As Long, ByVal X As Long, ByVal Y As Long) As Long
Private Declare Function CreatePolygonRgn Lib "gdi32" (lpPoint As Any, ByVal nCount As Long, ByVal nPolyFillMode As Long) As Long

Private N() As POINTAPI, hRgn&

Private Sub Form_Load()
ReDim N(3) As POINTAPI 'вместо квадрата можно было хоть 100-угольник нарисовать
Me.ScaleMode = vbPixels 'обязательно
N(1).X = 101 '101 для границ
N(2).X = 101
N(2).Y = 101
N(3).Y = 101
'для наглядности нарисуем эти точки
Show
Me.DrawWidth = 5
PSet (0, 0)
PSet (100, 0)
PSet (0, 100)
PSet (100, 100)
Me.DrawWidth = 1
hRgn = CreatePolygonRgn(N(0), UBound(N) - LBound(N) + 1, 1)
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Debug.Print "(" & X & ";" & Y & ")"
If PtInRegion(hRgn, CLng(X), CLng(Y)) Then Debug.Print "Ага" Else Debug.Print "Не-а"
End Sub