Dll для побайтового чтения из файла

[ALX_2002]

Челы.... Сейчас я буду позориться....

Мне нужна ваша хелпа...

не могу написать простейшую DLL. Прошу у вас помощи

Функции

1) Открывает файл для Binary чтения

2) Чтение из файла с параметром (SIZE)

При каждом обращении смещается по файлу. Когда файл

кончается возвращает - ""

3) Закрывает файл

Помогите плиз. Совсем синтаксис забыл...

[Eugenio]

Извини, тебе нужна именно DLL на Basic?
Короче так: тебе нужен объект, который скрывает функции для работы с файлом или бинарник с кодом функции, которую ты хочешь вызывать? Если второе - пиши на C++, юзай fstream.
Если все-таки первое:

Код: Выделить всё

open fileName for Binary Access Read (Write) Lock (Read) Write as FileNumber

1.
Do while not EOF(FileNumber)
Get FileNumber, ByteNumber, MyByte
'еще вариант чтения: MyString=Input(NumberOfBytes, FileNumber)
Loop

2.
For ByteNumber=1 to LOF(FileNumber)
Get FileNumber, ByteNumber, MyByte
Next ByteNumber



и т.п.
Cвободный FileNumber, если хочешь открывать несколько файлов, лучше всего получить так:

Код: Выделить всё

FileNumber=FreeFile

Еще способ: подключи библиотеку Microsoft Scripting Runtime и посмотри в Object Browser про FileSystemObject

[ANDLL]

Моежт ПОБАЙТОВОЕ чтение из файла? Побитового не бывавет...

[tyomitch]

Побитовое бывает, и иногда полезно - например, для тех же GIF-ов. Но у ALX_2002 имхо именно побайтовое.

[ALX_2002]

2 ANDLL: Я в двойне опозорен

2 Eugenio: В кратце - мне нужно сделать DLL, к которой можно будет

обратиться из ASP.

При использовании FSO возникла проблема одновременного чтения из файла

Я думал, что при "open fileName for Binary Access Read" 2

пользователя, подключившиеся к ASP смогут чиать файл.

P.s Спасибо за код - пойду пробывать

[Eugenio]

В кратце - мне нужно сделать DLL, к которой можно будет

обратиться из ASP.

ActiveX DLL, короче, с объектами, которые будут создаваться - на стороне сервера, да? ИМХО, с asp'ом лучше все-таки FSO юзать. Открывай файл ForReading

При использовании FSO возникла проблема одновременного чтения из файла

Я думал, что при "open fileName for Binary Access Read" 2

пользователя, подключившиеся к ASP смогут чиать файл.

Смогут.

[ANDLL]

Побитовое бывает, и иногда полезно - например, для тех же GIF-ов. Но у ALX_2002 имхо именно побайтовое.

Продемонстрируй-ка код, считывающий бит № 158 из файла text1.txt

[Eugenio]

Продемонстрируй-ка код, считывающий бит "158 из файла text1.txt

Считывается GIF'ы конечно тоже побайтово, но ALX_2002'а могли же, теоретически, интересовать побитовые операции

[ALX_2002]

Новая проблема возникла. Мне нужно получить реальный размер файла

File.Size - возращает размер на диске, а мне нужен реальный размер файла...

Никак не могу придумать через что в ASP его получить

[tyomitch]

Побитовое бывает, и иногда полезно - например, для тех же GIF-ов. Но у ALX_2002 имхо именно побайтовое.

Продемонстрируй-ка код, считывающий бит № 158 из файла text1.txt

Код: Выделить всё

Public Function GetBit(ByVal bn As Long) As Boolean
Dim b As Byte
Get #1, 1 + (bn \ 8), b
GetBit = b And (2 ^ (bn Mod 8))
End Function


В реальном коде, конечно, последний считанный байт запоминается, а не пересчитывается 8 раз.

[ALX_2002]

Удивительно, как только я произношу кодовое слово ASP, тут же в пост перестают писать

Это закономерность такая ?

[ANDLL]

Удивительно, как только я произношу кодовое слово ASP, тут же в пост перестают писать

Это закономерность такая ?

Да. Мало кто его знает, по ходу.

Побитовое бывает, и иногда полезно - например, для тех же GIF-ов. Но у ALX_2002 имхо именно побайтовое.

Продемонстрируй-ка код, считывающий бит № 158 из файла text1.txt

Код: Выделить всё

Public Function GetBit(ByVal bn As Long) As Boolean
Dim b As Byte
Get #1, 1 + (bn \ 8), b
GetBit = b And (2 ^ (bn Mod 8))
End Function


В реальном коде, конечно, последний считанный байт запоминается, а не пересчитывается 8 раз.

Ну, Темыч, это побайтовое чтение из файла...

[ALX_2002]

Вы чего хотите то ? Читать файл как 000111001111011 ?

Если я ничего не путаю, то по идее ADODB.Stream возвращает файлы

в таком виде ? Или нет ?

[ANDLL]

По большому счету наш с tiomitch'ем спор исключительно номенклатурный - никакого отношения к рассматриваему вопросу и к прикладному программированию он не имеет.

[GSerg]

Минимальной адресуемой единицей является байт. Не прите против архитектуры

[tyomitch]

Ну, Темыч, это побайтовое чтение из файла...

Пользователь этой длл-ки, однако, этого не знает. С его точки зрения, чтение идёт побитно.
Речь идёт об "инкапсуляции" "особенностей архитектуры" PC в удобную для использования структуру (поток битов).

А как это реализовано внутри длл-ки - пользователя не волнует. Хоть телепатически прямо магнитные домены прямо с блина винта считывает, до пользователя доходят только биты.

Спор не номенклатурный, спор как раз прикладной

[ALX_2002]

Народ... Я задрался с этим GET , INPUT , RANDOM..... ужас

Помогите плиз

Мне нужно написать функцию

Код: Выделить всё

Function ReadFile(BYTES)

End Function


Чтобы ей передавалось количество байт, сколько нужно считать, и при каждом обращении она смещалась на это колличество. А когда файл закончится возвращала пустую строку - ""

Т.е

Код: Выделить всё

Do
Bits=ReadFile(100)
Loop Until Bits=""


Я замучался

[ANDLL]

Попробуй:

Код: Выделить всё

Private Sub Form_Load()
MsgBox RF(1)
End Sub

Public Function RF(ByVal nBytes As Long) As String
Static nCurPos As Long, fNum As Long, nFileSize As Long
If fNum = 0 Then
    fNum = FreeFile
    Open "C:\file.txt" For Binary Access Read As #fNum
    nCurPos = 1
End If
If nCurPos > LOF(fNum) Then
    RF = ""
    Close #fNum
    fNum = 0
    Exit Function
End If
Dim nStr As String
nStr = Space(nBytes)
Get #fNum, nCurPos, nStr
nCurPos = nCurPos + nBytes
RF = nStr
End Function

[ALX_2002]

Ух... Вроде пошло.... ПАСИБА !!!

Ещё 1 вопр. При чтении через FSO.OpenTextStream

Как строку переводить в двоичные данные ?

[ANDLL]

А не как. Строка это и есть двоичные данные. Или тебя интересует массив байтов?

Код: Выделить всё

dim A as string,B() as Byte
A="ABC"
B=A

[tyomitch]

Попробуй:

Код: Выделить всё

Private Sub Form_Load()
MsgBox RF(1)
End Sub

Public Function RF(ByVal nBytes As Long) As String
Static nCurPos As Long, fNum As Long, nFileSize As Long
If fNum = 0 Then
    fNum = FreeFile
    Open "C:\file.txt" For Binary Access Read As #fNum
    nCurPos = 1
End If
If nCurPos > LOF(fNum) Then
    RF = ""
    Close #fNum
    fNum = 0
    Exit Function
End If
Dim nStr As String
nStr = Space(nBytes)
Get #fNum, nCurPos, nStr
nCurPos = nCurPos + nBytes
RF = nStr
End Function

Способ короче:

Код: Выделить всё

Private Sub Form_Load()
MsgBox RF(1)
End Sub

Public Function RF(ByVal nBytes As Long) As String
Static fNum As Long
If fNum = 0 Then
    fNum = FreeFile
    Open "C:\file.txt" For Binary Access Read As #fNum
End If
If EOF(fNum) Then
    RF = ""
    Close #fNum
    fNum = 0
Else
    RF = Space(nBytes)
    Get #fNum, , RF
End If
End Function

Сравни длину

[ALX_2002]

http://www.activeserverpages.ru/articles/read.asp?id=25

2 ANDLL - Я прочёл, что FSO не может нормально читать двоичные данные. Она портит символы переноса строки.

Я нашёл код, который передаёт картинку,
BinArray = BinArray & chrB(asc(a.Read(1)))

И хотел узнать - можно ли просто в прочитанной строке заменять эти 2

символа на то что нужно, а не читать таким [censored]ым

методом ?

2 Tyomitch: Хм.... Чем меньше код, тем понятнее.... Пасиба.

[ANDLL]

Попробуй:

Код: Выделить всё

...

Способ короче:

Код: Выделить всё

...

Сравни длину

А я не знал, что get сам смещает позицию в файле
2ALX_2002: никогда с FSO не работал на таком уровне. Зачем?

[ANDLL]

Еще: бредова идея, но:

Код: Выделить всё

dim A as string,B() as Byte
A="ABC"
B=strconv(A,vbFromUnicode)


Впрочем, идея, как я сказал бредовая

[ALX_2002]

Облом.... При этом всё равно надо делать цикл перебора всей строки.....эх...

Пилохо

[tyomitch]

ALX_2002, а чем тебя не устраивает наша с ANDLL "Dll для побайтового чтения из файла"? Или надо именно через FSO?

[ALX_2002]

1) Просто с FSO было бы проще в плане написания кода... но тормозит..

2) Трабл... ваш код не до конца файл читает. Из-за того что длина файла произвольная, а делим его равными кусками, лезут глюки

последний кусок не читается

[ALX_2002]

Прочитал, что при Random эта ошибка исчезает

Облом... Терь говорит размер буфера не подхдит...

[tyomitch]

2) Трабл... ваш код не до конца файл читает. Из-за того что длина файла произвольная, а делим его равными кусками, лезут глюки

Попробуй такой код:

Код: Выделить всё

Private Sub Form_Load()
MsgBox RF(1)
End Sub

Public Function RF(ByVal nBytes As Long) As String
Static fNum As Long
If fNum = 0 Then
    fNum = FreeFile
    Open "C:\file.txt" For Binary Access Read As #fNum
End If
If EOF(fNum) Then
    RF = ""
    Close #fNum
    fNum = 0
Else
    If nBytes > (LOF(1) - Seek(1)) Then nBytes = (LOF(1) - Seek(1))
    RF = Space(nBytes)
    Get #fNum, , RF
End If
End Function

[Eugenio]

Зачем все эти мучения, не пойму.. LOF() - Seek() юзать неверно, потому что Seek() возвратит следующую, еще нечитанную позицию. Например: длина файла (LOF) - 10b, хотим читать его по 5b:
1-й вызов: LOF - Seek() = 9, читаем с 1-го по 5-й
2-й вызов: LOF - Seek() = 4, читаем с 6-го по 9-й


Надо вроде вот этого:

Код: Выделить всё

Public Function RF(ByVal nBytes As Long,ResStr As String) As Boolean
Static fNum As Long

RF = False: ResStr = ""

If fNum = 0 Then
    fNum = FreeFile
    Open "C:\file.txt" For Binary Access Read As #fNum
End If

If EOF(fNum) Then
    Close #fNum
    fNum = 0
Else
  If Loc(fNum) + nBytes > LOF(fNum) then
    nBytes = LOF(fNum) - Loc(fNum)
  EndIf

  ResStr = Space(nBytes)
  Get #fNum, , ResStr

  RF = True
End If
End Function


Код: Выделить всё

Do While RF(BytesNumber,Str)
    .......
Loop


Во, так, пожалуй, нормально