Параметры командной строки

[Александр Андреев]

Как в VB обработать параметры командной строки exe-шника?

[FaKk2]

Ищи на форуме.
100% уже было и не раз

[Cyrax]

из хелпа по VB5

В данном примере функция Command используется для передачи аргументов командной строки в функцию, которая возвращает их в переменной типа Variant, содержащей массив.

Код: Выделить всё

Function GetCommandLine(Optional MaxArgs)
   'Описание переменных.
   Dim C, CmdLine, CmdLnLen, InArg, I, NumArgs
   'Проверяет наличие MaxArgs.
   If IsMissing(MaxArgs) Then MaxArgs = 10
   'Задание правильной размерности массива.
   ReDim ArgArray(MaxArgs)
   NumArgs = 0: InArg = False
   'Получает аргументы командной строки.
   CmdLine = Command()
   CmdLnLen = Len(CmdLine)
   'Последовательный анализ всех символов
   'командной строки.
   For I = 1 To CmdLnLen

C = Mid(CmdLine, I, 1)
      'Проверка на наличие пробела или табуляции.
      If (C <> " " And C <> vbTab) Then
         'Символы пробела и табуляции не обнаружены.
         'Проверяет, является ли символ частью аргумента.
         If Not InArg Then
         'Начинается новый аргумент.
         'Проверка количества аргументов.
            If NumArgs = MaxArgs Then Exit For
               NumArgs = NumArgs + 1
               InArg = True
            End If
         'Добавление символа к текущему аргументу.

ArgArray(NumArgs) = ArgArray(NumArgs) + C
      Else
         'Найден символ пробела или табуляции.
         'Устанавливает для флага InArg значение False.
         InArg = False
      End If
   Next I
   'Изменение размера массива для хранения аргументов.
   ReDim Preserve ArgArray(NumArgs)
   'Возвращает массив в качестве имени функции.
   GetCommandLine = ArgArray()
End Function

[Александр Андреев]

Вот эта строчка:

Код: Выделить всё

    CmdLine = Command()

ругается следующими словами: "Run-time error 450. Wrong number of arguments or invalid property assignment".

[Cyrax]

Вот эта строчка:

Код: Выделить всё

    CmdLine = Command()

ругается следующими словами: "Run-time error 450. Wrong number of arguments or invalid property assignment".

а ты скобки-то убери . они там вобще не нужни. вот только какой идиот (не я, это точно) их туда вставил.
а вообще эта функция звучит так Command$

[Александр Андреев]

Тоже пробовал. Не работает (ругается уже по-другому).

[Cyrax]

Тоже пробовал. Не работает (ругается уже по-другому).

а ты откуда запускаешь программу-то?
из среды или exe-файл

хотя.... только что скопировал этот код, вставил в код формы
все работает прекрасно, без ошибок.

[skiperski]

Наступи F2, потом в комбобоксе Search набери "command" и нажми Enter или кликни на бинокль. Должны найтись минимум:

Код: Выделить всё

VBA        Interaction               Command
VBA        Interaction               Command$
VBA        CommandButton


Если кроме них есть ещё чего-то, то в этом чего-то и есть твоя трабла. В этом случае вызывай в функцию с указанием библы: VBA.Command$

Твори, выдумывай, пробуй!

[Александр Андреев]

skiperski сотворил верное решение... спасибо