Реагирование на прекращение работы можема......Я идиот! Убейте меня, кто-нибудь!?

[Den_86]

Народ!!! Подскажите хотя бы примерно как в Visual Basic или Visual Basic Script описать реакцию на прекращение работы модема


короче что написать чтобы при прекращении работы модема можно совершить какие-то действия.................



препод лох си не знает(((

[Santa]

Option Explicit

Private Declare Function RasEnumConnections Lib "RasApi32.dll" Alias "RasEnumConnectionsA" (lpRasCon As Any, lpcb As Long, lpcConnections As Long) As Long
Private Declare Function RasGetConnectStatus Lib "RasApi32.dll" Alias "RasGetConnectStatusA" (ByVal hRasCon As Long, lpStatus As Any) As Long
Const RAS95_MaxEntryName = 256
Const RAS95_MaxDeviceType = 16
Const RAS95_MaxDeviceName = 32
Private Type RASCONN95
dwSize As Long
hRasCon As Long
szEntryName(RAS95_MaxEntryName) As Byte
szDeviceType(RAS95_MaxDeviceType) As Byte
szDeviceName(RAS95_MaxDeviceName) As Byte
End Type
Private Type RASCONNSTATUS95
dwSize As Long
RasConnState As Long
dwError As Long
szDeviceType(RAS95_MaxDeviceType) As Byte
szDeviceName(RAS95_MaxDeviceName) As Byte
End Type

Public Function IsModemConnected() As Boolean
Dim TRasCon(255) As RASCONN95
Dim lg As Long
Dim lpcon As Long
Dim RetVal As Long
Dim Tstatus As RASCONNSTATUS95
TRasCon(0).dwSize = 412
lg = 256 * TRasCon(0).dwSize
RetVal = RasEnumConnections(TRasCon(0), lg, lpcon)
If RetVal <> 0 Then
MsgBox "Ошибка!", vbCritical, Me.Caption
Exit Function
End If

Tstatus.dwSize = 160
RetVal = RasGetConnectStatus(TRasCon(0).hRasCon, Tstatus)
If Tstatus.RasConnState = &H2000 Then
IsModemConnected = True
Else
IsModemConnected = False
End If
End Function

Private Sub Command1_Click()
If IsModemConnected = False Then
MsgBox "Модем не подключен", vbInformation, Me.Caption
Else
MsgBox "Модем подключен", vbInformation, Me.Caption
End If
End Sub


Я считаю что этого вполне должно быть достаточно.

[Den_86]

Я бы сказал исч5ерпывающий!!!!!

Огромное спасибо!!!!!!