Range и области печати

[Sedge]

Дано: лист MS Excel 2000, на котором выделена области печати, разбитая на некоторое количество страниц. Как определить, к какой странице принадлежит произвольная ячейка этого же листа?

[alibek]

Интересный вопрос
Я бы поискал в направлении VPageBreaks/HPageBreaks (предварительно выполнив Preview), но помоему в Excel нет нормальных средств, чтобы определить, на какой странице будет напечатана та или иная ячейка.

[Sedge]

А интересная мысль... Собственно, по индексу HPageBreak мы можем определить номер страницы, которая с него начинается. Пойду думать.

[Sedge]

Если кому интересно.
Задача была в том, чтобы определить, укладывается ли таблица при печати в одну страницу. По ряду причин известно, что данная таблица по горизонтальным и вертикальным размерам никогда не привышает печатного листа формата А4.
Решение: начало и конец таблицы отмечается именованным диапазоном. Далее - функция:

Код: Выделить всё

Private Function IsRangeInPage(sRangeOne As String, sRangeTwo As String, ws As Object) As Boolean
'
On Error GoTo eRes

'//////////////////////////////////////////////////////////////////////////////////////
  Dim j As Long
  Dim bIsSame As Boolean, lRangeOneRow As Long, lRangeTwoRow As Long
  Dim lPageBreakRow As Long
  Dim lPagePrevBreakRow As Long
'//////////////////////////////////////////////////////////////////////////////////////

If ws.HPageBreaks.Count = 0 Then
  IsRangeInPage = True
  Exit Function
End If

lRangeOneRow = ws.Range(sRangeOne).Row
lRangeTwoRow = ws.Range(sRangeTwo).Row

lPageBreakRow = ws.HPageBreaks(1).Location.Row
If lRangeOneRow < lPageBreakRow And lRangeTwoRow < lPageBreakRow Then
  IsRangeInPage = True
  Exit Function
End If

bIsSame = False
For j = 2 To ws.HPageBreaks.Count
  lPageBreakRow = ws.HPageBreaks(j).Location.Row
  lPagePrevBreakRow = ws.HPageBreaks(j - 1).Location.Row
  If lRangeOneRow < lPageBreakRow And _
    lRangeTwoRow < lPageBreakRow And _
    lRangeOneRow > lPagePrevBreakRow And _
    lRangeTwoRow > lPagePrevBreakRow Then
      bIsSame = True
      Exit For
  End If
Next

IsRangeInPage = bIsSame
Exit Function
eRes:
  Call Err.Raise(Err.Number, "IsRangeInPage", Err.Description)
End Function



Если IsRangeInPage возвращает False, то перед именованным диапазоном-началом таблицы добавляем разрыв страницы:

Код: Выделить всё

  HPageBreaks.Add Before:=.Range(<имя диапазона>)