Перехват вывода VBScript

[Tathagata]

Подскажите, плз, можно ли в VBScript запустив к выполнению консольное приложение перехватить вывод результата?

[Ruslan Demidow]

Код: Выделить всё

'*******************************************************************
' Имя: StdIn1.vbs                                               
' Язык: VBScript                                                   
' Описание: Пример использования метода StdIn.WriteLine           
'*******************************************************************
' Функция для перевода строки из DOS- в Windows-кодировку
Function DosToWin(s)
Dim i,k,ss
  ss=""
  For i=1 To Len(s)  ' Цикл по всем символам в строке
    k = Asc(Mid(s,i,1))  ' Определяем ANSI-код i-го символа
    ' Изменяем код k на код соответствующего символа в
    ' Windows-кодировке
    If (128 <= k) And (k <= 175) Then
      k=k+64
    ElseIf (224 <= k) And (k <= 239) Then
      k=k+16
    ElseIf k = 240 Then
      k=168
    ElseIf k = 241 Then
      k=184
    End If
    ss=ss+Chr(k)  ' Возвращаем преобразованную строку
  Next
DosToWin=ss
End Function

'*************  Начало *********************************************
Dim s
' Печатаем приглашение для ввода
WScript.StdOut.Write "Введите одну строку: "
s = WScript.StdIn.ReadLine  ' Вводим строку с клавиатуры
WScript.StdOut.WriteBlankLines 1   ' Печатаем пустую строку
WScript.StdOut.Write "Было введено: "
' Преобразовываем введенную строку в Windows-кодировку
' и выводим ее на экран
WScript.StdOut.WriteLine DosToWin(s)
'*************  Конец *********************************************


Или

Код: Выделить всё

'*******************************************************************
' Имя: StdIn2.vbs                                               
' Язык: VBScript                                                 
' Описание: Пример использования метода StdIn.ReadAll           
'*******************************************************************
Option Explicit
' Функция для перевода строки из DOS- в Windows-кодировку
Function DosToWin(s)
Dim i,k,ss
  ss=""
  For i=1 To Len(s)  ' Цикл по всем символам в строке
    k = Asc(Mid(s,i,1))  ' Определяем ANSI-код i-го символа
    ' Изменяем код k на код соответствующего символа в
    ' Windows-кодировке
    If (128 <= k) And (k <= 175) Then
      k=k+64
    ElseIf (224 <= k) And (k <= 239) Then
      k=k+16
    ElseIf k = 240 Then
      k=168
    ElseIf k = 241 Then
      k=184
    End If
    ss=ss+Chr(k)
  Next
  DosToWin=ss   ' Возвращаем преобразованную строку
End Function

'*************  Начало *********************************************
Dim s,ArrS,i,ColStr   ' Объявляем переменные
' Печатаем приглашение для ввода
WScript.StdOut.WriteLine "Вводите строки:"
s = WScript.StdIn.ReadAll  ' Вводим строки с клавиатуры
WScript.StdOut.WriteBlankLines 3  ' Печатаем пустые строки
ArrS=Split(s,vbCrLf)  ' Формируем массив из введенных строк
ColStr=UBound(ArrS)+1
' Печатаем введенные строки
WScript.StdOut.WriteLine "Всего ведено строк: " & ColStr
For i=1 To ColStr
  ' Преобразовываем введенные строки в Windows-кодировку
  ' и выводим их на экран
  WScript.StdOut.WriteLine i & ": " & DosToWin(ArrS(i-1))
Next
'*************  Конец *********************************************/


Или вот ещё - в этом скрипте у меня выводится UpTime системы

Код: Выделить всё

'==========================================================================
'
' VBScript Source File -- Created with SAPIEN Technologies PrimalScript 3.0
'
' NAME: UpTime XP
'
' AUTHOR:  Demidow Ruslan,
' DATE  : 14.10.2003
'
' COMMENT: Get uptime of system
'
'==========================================================================
Option Explicit
Const ForReading = 1, ForWriting = 2, ForAppending = 8
Const vbHidden=4
Dim Wshell, TempText, SysInfo, FSO, Result, strInfo, text, info, findInfo,s, WinString

Function DosToWin(s)
Dim i,k,ss
  ss=""
  For i=1 To Len(s)  ' Цикл по всем символам в строке
    k = Asc(Mid(s,i,1))  ' Определяем ANSI-код i-го символа
    ' Изменяем код k на код соответствующего символа в
    ' Windows-кодировке
    If (128 <= k) And (k <= 175) Then
      k=k+64
    ElseIf (224 <= k) And (k <= 239) Then
      k=k+16
    ElseIf k = 240 Then
      k=168
    ElseIf k = 241 Then
      k=184
    End If
    ss=ss+Chr(k)  ' Возвращаем преобразованную строку
  Next
DosToWin=ss
End Function

Function WinToDos(WinString)
Dim i,k,ss,L
ss=""
   For i=1 to Len(WinString)
   k=Asc(Mid(WinString,i,1))
   L=k
   If (128<=k) And (k<=175) Then
     k=k-16
    Elseif (k>=224) And (k <= 239) Then
     k=k-64
    ElseIf k = 168 Then
      k=240
    ElseIf k = 184 Then
      k=241
    End If
    ss=ss+Chr(k)  ' Возвращаем преобразованную строку
  Next
WinToDos=ss   
End Function

findInfo="‚६п а Ў®вл бЁб⥬л:"
Set Wshell=Wscript.CreateObject("Wscript.Shell")
Set fso=CreateObject("Scripting.FileSystemObject")
set Result=Wshell.Exec ("C:\windows\system32\SystemInfo.exe")
Set strInfo=Result.StdOut


Do While strInfo.AtEndOfStream=False
Info=strInfo.ReadLine

If Left(info,Len(FindInfo))=FindInfo Then
   MsgBox DosToWin(info)
End If
Loop


[Tathagata]

Код: Выделить всё

Set strInfo=Result.StdOut


Спасибо - это то что нужно.