Вытащить данные из окна чужой программы

[KrisKelvin]

есть программа, из которой нужно прочитать содержимое окошек
скрин программы на рисунке



программа "WinSpy" отлично видит все окна и показывает содержимое нужных окошек, на примере окна помеченного красной стрелкой на "scr01.jpg" и "scr02.jpg"



таким-же образом нужно выташить содержание окон помеченных зеленой кляксой на "scr03.jpg"




прошу помощи растолковать мне на примере VB как добратся до этих окошек и выдрать данные окна в переменную для последующей обработки

заранее благодарен за советы и наглядные примеры для начинающего, (по возможности в формате VB6) !

[pronto]

Функции в помощь: FindWindow, FindWindowEx, GetWindowText (или SendMessage с сообщениями WM_GETTEXT и WM_GETTEXTLENGTH)

[ger_kar]

Сначала нужно найти окно верхнего уровня через функцию FindWindow
А далее использую дескриптор полученный из первой функции использовать FindWindowEx для поиска вложенных окон.
Русскоязычное описание можно найти тут FindWindow, FindWindowEx
Декларация этих функций в VB:

Код: Выделить всё

Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Declare Function FindWindowEx Lib "user32.dll" Alias "FindWindowExA" (ByVal hWndParent As Long, ByVal hWndChildAfter As Long, ByVal lpszClass As String, ByVal lpszWindow As String) As Long

После того как искомое окно будет найдено (будет получен дескриптор этого окна или по другому хендл) тогда используя полученный дескриптор с помощью функции GetWindowText можно получить текст.
Описание функции на русском GetWindowText
Декларация функции в VB

Код: Выделить всё

Declare Function GetWindowText Lib "user32.dll" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long


[ger_kar]

Вобщем я лажанулся, GetWindowText для получения текста из окна принадлежащего другому процессу не подходит, нужно юзать

(или SendMessage с сообщениями WM_GETTEXT и WM_GETTEXTLENGTH)

Вот пример получения текста из окна калькулятора

Код: Выделить всё

Option Explicit

Private Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function FindWindowEx Lib "user32.dll" Alias "FindWindowExA" (ByVal hWndParent As Long, ByVal hWndChildAfter As Long, ByVal lpszClass As String, ByVal lpszWindow As String) As Long
Private Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByRef lParam As Any) As Long
'
Private Const WM_GETTEXT As Long = &HD
Private Const WM_GETTEXTLENGTH As Long = &HE
'


Private Sub cmdStart_Click()
   
    Dim hTopWind    As Long
    Dim hWinEdit    As Long
    Dim lRetLen     As Long
    Dim sWinText    As String
   
    hTopWind = FindWindow("SciCalc", "Калькулятор")
    If hTopWind <> 0 Then
        hWinEdit = FindWindowEx(hTopWind, 0, "Edit", "")
        If hWinEdit <> 0 Then
            lRetLen = SendMessage(hWinEdit, WM_GETTEXTLENGTH, 0, ByVal 0&)
            If lRetLen <> 0 Then
                sWinText = Space(lRetLen + 1)
                lRetLen = SendMessage(hWinEdit, WM_GETTEXT, Len(sWinText), ByVal sWinText)
                If lRetLen <> 0 Then
                    sWinText = Left$(sWinText, lRetLen - 1)
                    Debug.Print Hex(hTopWind), Hex(hWinEdit), sWinText
                End If
            End If
        End If
    End If
   
End Sub


[KrisKelvin]

спасибо БОЛЬШОЕ !
проблема решена !!!