Как создать свойство в свойстве?

[Don Leno]

В класс модуле можно создать свойство и оно будет выглядеть так:

Код: Выделить всё

    object.property=1

Вопрос как сделать чтобы было так:

Код: Выделить всё

   object.prop.my=1
   object.prop.you=2

то есть в одном свойстве есть еще подмножество.

[alibek]

Создаешь класс PropList со свойствами my as long и you as long.
Затем создаешь класс MyObject со свойством prop as PropList.

[Don Leno]

alibek, если можно строчками кода. Недопонимаю как сделать "prop as PropList"

[Хакер]

Код: Выделить всё

Public prop As PropList

[Don Leno]

СПС!!!!!!!

[Don Leno]

))) После спс не я писал ))) Но верно - затупил)))

[Хакер]

))) После спс не я писал )))

Писал-писал.

[Don Leno]

спорить бесполезно=)

[Don Leno]

возможно ли такой метод сделать в одном классе? И как?

[Хакер]

возможно ли такой метод сделать в одном классе? И как?

Какой метод?

[Don Leno]

свойство в свойстве только в одном классе?

[Хакер]

свойство в свойстве только в одном классе?

Свойство не бывает в свойстве. Свойство бывает у интерфейса объекта.
Интерфейсов у объекта может быть много. Дальше думай.

[Don Leno]

Тогда как создать еще интерфейс?

[Хакер]

Тогда как создать еще интерфейс?

Объявить (или использовать существующий, если есть подходящий).

[Don Leno]

Стоп! Что такое интерфейс объекта и как его объявить?

[Хакер]

Что такое интерфейс объекта

Интерфейс — это зафиксированный набор публично доступных членов объекта (методов и свойств).
Интерфейсы могут наследоваться.

Почитай вот это: viewtopic.php?f=92&t=43751&p=6760534#p6760534
Поищи по форуму по фразе «com-интерфейс».

Только всё равно ты пытаешься сделать малополезное дело. Хоть и осуществимое.

[Don Leno]

спасибо за подробный ответ. Буду изучать))

[Хакер]

и как его объявить?

На языка IDL с компиляцией в TLB.
Либо на VB, объявив класс с пустыми методами.

[Mikle]

А может достаточно будет Type вместо класса?

[Jack Ferre]

Интерфейс IProp:

Код: Выделить всё

Option Explicit

Public Property Get Secondary() As Long: End Property
Public Property Let Secondary(ByVal Value As Long): End Property

Класс CTest:

Код: Выделить всё

Option Explicit

Implements IProp

Dim m_primary_secondary As Long



Public Property Get Primary() As IProp
    Set Primary = Me
End Property

Private Property Get IProp_Secondary() As Long
    IProp_Secondary = m_primary_secondary
End Property

Private Property Let IProp_Secondary(ByVal Value As Long)
    m_primary_secondary = Value
End Property

Тест:

Код: Выделить всё

    Dim test As New CTest
   
    test.Primary.Secondary = 123
    Debug.Print test.Primary.Secondary

[Хакер]

А может достаточно будет Type вместо класса?

Будет большой сюрприз при передачи свойств ByRef.



Jack Ferre ,
Твой код плох тем, что создаёт утечку памяти: экземпляры CTest никогда не уничтожаются в нужный момент.

[Jack Ferre]

Хакер,
Можно подробнее.

[Sam777e]

Предполагаю, что грех здесь

Dim test As New CTest

, а правильно так

Код: Выделить всё

Dim test As CTest
Set test = New  CTest
. . .
Set test = Nothing


[Хакер]

Это вообще ничего не измеит. Засуньте брекоинт или Debug.Print в Class_Uninitialize. Оно никогда не выполнится.

[Jack Ferre]

Хакер,
Так что на счёт утечки памяти?

экземпляры CTest никогда не уничтожаются в нужный момент

Только если создать ссылку на test.Primary. Но это же не утечка памяти - программист сам её создает.

А в примере после Debug.Print test.Primary.Secondary test и test.Primary освобождаются одновременно.

[Хакер]

Только если создать ссылку на test.Primary. Но это же не утечка памяти - программист сам её создает.

А утечка памяти это только то, что создаётся не руками программиста, а шалостью демонов? Её программист и создаёт.

Извиняюсь, но дело в том, что я невнимательно смотрел на код и подумал, что там

Код: Выделить всё

Public Primary As IProp

Private sub Class_Initialize()
    Set Primary = Me
End Sub

В этом случае получался бы неубиваемый экземпляр (неубиваемый в рамках обычной концепции подсчёта ссылок). А с get-хендлером свойства — всё окей.

[Jack Ferre]

Так как до этого я свойство в свойстве не писал - пришлось изобретать.

И именно так

Public Primary As IProp

Private sub Class_Initialize()
    Set Primary = Me
End Sub

и было сначала написано и объект становился бессмертным