Указатель на переменную

[Jack Ferre]

Как (если возможно) изменить указатель на переменную?

Что-то вроде VarPtr(MyVar) = MyPtr.

[Mikle]

Можно только для массивов, ищи "safearray".

[The trick]

Можно только для массивов, ищи "safearray".

Не только, можно изменить еще в стеке (аргументы функций), в Variant переменных с флагом VT_BYREF, в строках и т.д. Для статических массивов нельзя.

[Mikle]

Для статических массивов нельзя.

А у меня получилось...

[ger_kar]

Тут главное, в зависимости от того, какой применяется массив не забыть все вернуть обратно, чтобы исключить падения и утечку памяти.

[Хакер]

Бредовый вопрос.

[The trick]

Для статических массивов нельзя.

А у меня получилось...

Скомпилируй.

[Mikle]

Скомпилируй.

Скомпилировано. Старый проект, посмотри в модуле modTex:

[The trick]

Скомпилировано. Старый проект, посмотри в модуле modTex:

Такое не прокатит для локальный переменных процедуры, или полей UDT.
Туман кстати классно сделал.

[Jack Ferre]

Был занят, не отвечал.

Про safearray понравилось.

Мне нужно чтобы переменная UDT указывала на участок в массиве байт. Переменную объявляю как одномерный массив с одним элементом и меняю указатель на данные. Вот что получилось:

Код: Выделить всё

Option Explicit

Private Declare Function GetMem4 Lib "msvbvm60" (ByVal lpSrc As Long, ByVal lpDst As Long) As Long
Private Declare Function PutMem4 Lib "msvbvm60" (ByVal lpDst As Long, ByVal Value As Long) As Long
Private Declare Function AryPtr Lib "msvbvm60" Alias "VarPtr" (Ary() As Any) As Long

Private Type My4BYTES
    b1 As Byte
    b2 As Byte
    b3 As Long
    b4 As Byte
End Type



Private Function SetDataPtr(ByVal ppAry As Long, ByVal pvData As Long) As Long
    Dim p As Long
   
    GetMem4 ppAry, VarPtr(p)
    GetMem4 p + 12, VarPtr(SetDataPtr)
    PutMem4 p + 12, pvData
End Function

Private Sub Form_Load()
    Debug.Print "======================================================"
   
    Dim TestAry(1 To 16) As Byte
    Dim TestVar(0) As My4BYTES
    Dim pvOld As Long
    Dim i As Long
   
    pvOld = SetDataPtr(AryPtr(TestVar), VarPtr(TestAry(3)))
   
    For i = 1 To 16
        TestAry(i) = i
    Next
   
    Debug.Print Hex(TestVar(0).b1), Hex(TestVar(0).b2), Hex(TestVar(0).b3), Hex(TestVar(0).b4)
   
    TestVar(0).b1 = &HF0
    TestVar(0).b2 = &HF0
    TestVar(0).b3 = &HF0F0F0F0
    TestVar(0).b4 = &HF0
   
    Dim sTmp As String
    For i = 1 To 16
        sTmp = sTmp & Hex(TestAry(i)) & "  "
    Next
    Debug.Print sTmp
   
    SetDataPtr AryPtr(TestVar), pvOld
End Sub

По идее должно работать, но при разных длинах полей UDT (как в примере Byte и Long) появляются какие-то пробелы.
Я ожидал на выходе:
3 4 8070605 9
А получаю:
3 4 A090807 B

Почему байты 5 и 6 пропускаются?

[Хакер]

Почему байты 5 и 6 пропускаются?

Учи матчасть

[ger_kar]

Они не пропускаются, а просто идут в другом порядке. В переменной Long 4 байта и в памяти они расположены в порядке от более младших разрядов к старшим, т.е. можно сказать ровно наоборот, если сравнивать с человеческим порядком восприятия. А информацию, которую дал Хакер можно найти и в более удобоваримом виде - на русском.

[Хакер]

Они не пропускаются, а просто идут в другом порядке. В переменной Long 4 байта и в памяти они расположены в порядке от более младших разрядов к старшим, т.е. можно сказать ровно наоборот, если сравнивать с человеческим порядком восприятия.

Это вообще никак не относится к теме. Он спрашивал не почему там 3 4 A090807 B вместо 3 4 708090A B, а почему нет байтов 5 и 6. Это из-за выравнивания, а порядок байтов тут не причём.

Более того, он пишет, что ожилал 3 4 8070605 9, что означает, что он в курсе порядка байтов для long.

[Jack Ferre]

UPD
Т.е. адрес переменной в структуре должен быть кратен её длине?

Я так понимаю все стандартные структуры удовлетворяют этому условию.

Если я присваиваю адрес UDT своей функцией SetDataPtr и поля UDT имеют формат Byte, Integer, Long, то адрес должен быть кратен 4-м иначе в UDT будут неправильные значения?

[Хакер]

Т.е. адрес переменной в структуре должен быть кратен её длине?

Не переменной, а поля. И не кратен, а есть более сложные правила. В противном случае само начало структуры пришлось бы выравнивать по границе, кратной размеру самого большого поля структуры. Чего в реальности, конечно, нет.