Код продукта Windows

[АндрейБ]

Подскажите где можно взять в системе информацию: Код продукта Windows.

[Gasparini]

Берётся в реестре "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"

Затем расшифровывается:

Код: Выделить всё

Public Function ConvertToOSProductKey(sKey() As Byte) As String
    Dim X As Long, i As Long, Chars As String, Cur As Long, Last As Long, KeyPart1 As String, IsWin8 As Integer, KeyOutput As String
    Dim Key() As Byte
    Key = Binary1ArrayTo0Array(sKey)
    IsWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((IsWin8 And 2) * 4)
    i = 24
    Chars = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        X = 14
        Do
            Cur = Cur * 256
            Cur = Key(X + 52) + Cur
            Key(X + 52) = (Cur \ 24)
            Cur = Cur Mod 24
            X = X - 1
        Loop While X >= 0
        i = i - 1
        KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
        Last = Cur
    Loop While i >= 0
    If (IsWin8 = 1) Then
        KeyPart1 = Mid(KeyOutput, 2, Last)
        KeyOutput = Replace(KeyOutput, KeyPart1, KeyPart1 & "N", 2, 1, 0)
        If Last = 0 Then KeyOutput = "N" & KeyOutput
    End If
    ConvertToOSProductKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function


[АндрейБ]

Dim Reg As Variant
Dim timezone_system As String
Set Reg = CreateObject("WScript.Shell")
timezone_system = Reg.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId")

Ругается что не может открыть для чтения раздел реестра - почему?

[Gasparini]

Во вложенном архиве VBS-скрипт, который получает код продукта.
Надеюсь уж его-то вы сможете перевести в VB6.

[АндрейБ]

Спасибо - надеюсь что смогу перевести в VB6:)

[АндрейБ]

Gasparini, переработал ваш код в VB6, он не сильно отличатся от того что я написал до этого сам, но суть не изменилась:

On Error Resume Next
Dim WshShell As Variant, DigitalID As Variant
Dim KEY As String, ProductName As String, ProductID As String
Set WshShell = CreateObject("WScript.Shell")
KEY = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
DigitalID = WshShell.RegRead(KEY & "DigitalProductId")
ProductName = "Product Name: " & WshShell.RegRead(KEY & "ProductName")
ProductID = "Product ID: " & WshShell.RegRead(KEY & "ProductID")

В окне отладки DigitalID , ProductID = Empty,
а когда пытаешь напрямую в отладочном окне указать например
?ProductID
Ругается что не может открыть для чтения раздел реестра

[АндрейБ]

Gasparini, если убрать строку пропуска ошибок 'On Error Resume Next
то в VB6 ругается что не может открыть для чтения раздел реестра.

[Qwertiy]

Run as administrator?

[АндрейБ]

В системе пользователь администратор.
В VB6 надо тоже это как то декларировать?
Реест значение ProductName - дает, а DigitalProductId и ProductID - выдает ошибку может открыть для чтение.

[Qwertiy]

Речь не о Win7?
А ещё, подобные штуки может блокировать антивирус.

[АндрейБ]

Каспер отключил - все равно не работает.

[АндрейБ]

у меня win8.

[Qwertiy]

В системе пользователь администратор.

у меня win8.

Ну так UAC?

[АндрейБ]

UAC поставил на самый низ. Перезагрузил машину. Касперский отключил. Все равно ошибка чтение реестра.

Главное скрипт от Gasparini ShowKey_v1.3.zip - работает, а через VB6 не могу получить
из реестра DigitalProductId и ProductID , хотя ProductName дает.

[Gasparini]

Дело не в UAC и не в правах, уверен в ними всё в порядке.
С вероятностью 99.99% твоя Windows 8 - 64-битная.
А твоя программа работает как 32-битное приложение, которым и является.
Соответственно на неё автоматически распространяется механизм перенаправления WOW64 в реестре и твоя программа на самом деле пытается прочитать следующий путь: "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion", а не тот, что ты указываешь.
На VBS-скрипты механизм перенаправления WOW64 не распространяется, так как его исполняет родной виндовский 64-битный Windows Script Host.

Как обойти данное ограничение?
Читать реестр через API, там есть флаги, позволяющие игнорировать WOW64 перенаправление и читать напрямую.