Как сохранить столбец в *.txt файл?

[qwertyhp]

Здравствуйте!
Необходимо сохранить столбец данных в текстовый файл. Делать это циклом по ячейкам - долго. Вручную - скопировать в Excel'е и через буфер обмена вставить в "Блокнот" - неприемлемо.
Пожалуйста, подскажите - можно ли как-то программно взять столбец и сохранить его в текстовый файл? И как это сделать? Чувствую, что можно, но не соображу - как.
Спасибо.

[Template]

Ежели в других столбцах нет данных, то можно, к примеру, активировать нужный лист и сохранить рабочую книгу как текстовый файл, если есть, то ... несколько вариантов, но хотелось бы знать сколько ~ ячеек нам придется обрабатывать.

[Template]

P.S. Как вариант, цикл, но не по ячейкам

Код: Выделить всё

Sub SaveColumnToText()

    Dim varArray As Variant, lngRow As Long, intFreeNum As Integer
   
    With ThisWorkbook.Worksheets("Лист1")
         varArray = .Range(.Cells(1, "A"), .Cells(.Rows.Count, "A").End(xlUp)).Value
    End With
   
    intFreeNum = FreeFile
    Open ThisWorkbook.Path & "\Column_A_Data.txt" For Output As #intFreeNum
         For lngRow = 1 To UBound(varArray)
             Print #intFreeNum, varArray(lngRow, 1)
         Next
    Close #intFreeNum

End Sub

[Alec]

А скопировать столбец в новую книгу, ее сохранить в текстовый файл, а потом закрыть?

[iGrok]

А скопировать столбец в новую книгу, ее сохранить в текстовый файл, а потом закрыть?

Мъсье знает толк в извращениях.

Имхо, вариант с циклом от Template - оптимален.

[Qwertiy]

А скопировать столбец в новую книгу, ее сохранить в текстовый файл, а потом закрыть?

Эм.. А просто скопировать и взять из буфера текст?
И вообще, надо быть осторожнее с копированием, т. к. в буфере может быть что-то полезное...

PS: А почему цикл по ячейкам - это долго?

[qwertyhp]

Спасибо Всем!
Qwertiy, Ваше решение очень интересное (не только для этого случая). Как я сам не додумался...

[Qwertiy]

Не за что
А чем интересное моё решение? Вроде бы всё стандартно...

[Starik]

Sub Export ()
Dim lngRow As Long
Dim intCol As Integer
Open ThisWorkbook.Path & "\1.txt" For Output As #1
For lngRow = 1 To Selection.Rows.Count
For intCol = 1 To Selection.Columns.Count
Write #1, Selection.Cells(lngRow, intCol).Value;
Next intCol
Print #1, ""
Next lngRow
Close #1
End Sub