Значение гиперссылок

[gigamaxx]

пытаюсь получить значение гиперссылок в листе excel. Вобщем делаю (точнее пытаюсь сделать) это так:

Код: Выделить всё

Dim objExcel As Object
Dim objBook As Object
Dim objSheet As Object
Dim c_rng() As Variant

Set objExcel = CreateObject("Excel.Application")
Set objBook = objExcel.Workbooks.Open(fil)
Set objSheet = objBook.Worksheets(1)

c_rng = objSheet.Range("C1:С100").Value ' в этом диапазоне есть гиперссылки


В результате получаю только текст гиперссылок.

Строка типа

Код: Выделить всё

c_rng = objSheet.Range("C1:С100").Hyperlinks(1).Address

вызывает ошибку.
Буду благодарен за любую подсказку...

[Template]

Код: Выделить всё

Dim objExcel As Object
Dim objBook  As Object
Dim objSheet As Object
Dim objRange As Object
Dim objHyperlink As Object
Dim strFileName  As String

strFileName = "C:\Мои документы\Моя рабочая книга.xls"

If Len(Dir(strFileName)) Then

   Set objExcel = CreateObject("Excel.Application")
   Set objBook = objExcel.Workbooks.Open(strFileName, 0)
   Set objSheet = objBook.Worksheets(1)
   Set objRange = objSheet.Range("C1:C100")
   
   For Each objHyperlink In objRange.Hyperlinks
       With objHyperlink 'типа, для примера
            MsgBox "Name: " & .Name
            MsgBox "Address: " & .Address
            MsgBox "SubAddress: " & .SubAddress
            MsgBox "TextToDisplay: " & .TextToDisplay
            MsgBox "Range_Value: " & .Range.Value
       End With
   Next
Else
   MsgBox "Чаво-то не видать нашей книжки :)"
End If

[gigamaxx]

Template
Спасибо! Попорбую и отпишусь!

[Template]

gigamaxx, Дык, перед тем как постить я проверил - работает, впрочем, ежели гиперссылки созданы с помощью функции ГИПЕРССЫЛКА() , то, видимо, придется парсить формулу.

[gigamaxx]

Template
Значит буду парсить, В любом случае спасибо. Ваш код буду использовать также, в зависимости от того, каким образом создана гиперссылка.

(В работе с Excel из VB опыта практически нет, так что приходится задавать такие простые (наверное) вопросы).

[Template]

gigamaxx, Увы, но не всегда можно добраться до адреса гиперссылки, созданной с помощью функции ГИПЕРССЫЛКА(), к примеру, ежели у ячейки с такой формулой, установлена опция "Скрыть формулу" , а лист защищен, то получить текст формулы не представляется возможным ...

=ГИПЕРССЫЛКА("http://bbs.vbstreets.ru/viewtopic.php?f=1&t=43900";"Значение гиперссылок")

[gigamaxx]

Template
Такой вариант я не предусмотрел, но не думаю что книги, с которыми придётся работать, будут защищены.

[Template]

gigamaxx, Небольшое уточнение, если защищена книга (т.е. установлен пароль на открытие), то ничего страшного не будет, за иcключением необходимости указать этот пароль при программном открытии книги, а вот если защищен рабочий лист (в Вашем примере это objSheet), то поможет только отсутствие второго аргумента у функции ГИПЕРССЫЛКА()

В общем, если у Вас есть возможность избежать создания гиперссылок с помощью функции, то рекомендую ей воспользоваться.

[gigamaxx]

gigamaxx, Небольшое уточнение, если защищена книга (т.е. установлен пароль на открытие), то ничего страшного не будет, за иcключением необходимости указать этот пароль при программном открытии книги, а вот если защищен рабочий лист (в Вашем примере это objSheet), то поможет только отсутствие второго аргумента у функции ГИПЕРССЫЛКА()

Я Вас понял, просто неправильно выразился . Тем не менее, objSheet в моём случае защищен скорее всего не будет (с большой вероятностью).
Насчет избегания создания гиперссылок при помощи формул - так их не я создаю, к сожалению... (но принял к сведению на будущее).