Обработка word-файлов

[Bananovyy]

ИДЕЯ:
Свести кучу word-файлов («*.docx») стандартного образца в единую базу

РЕШЕНИЕ:
- Поочередно открываю файлы «*.docx» из книги Excel
- Копирую содержимое и вставляю на первый лист Excel
- Откуда затем из определенных ячеек переношу информацию в базу
- Удаляю вставленную ранее информацию
- Повторяю процедуру по новой…

ПРОБЛЕМА:
- Макрос каждый раз прерывается «ошибкой 1004» на строке: ActiveSheet.Paste
- Есть какие-нидь другие варианты / примеры подобной обработки word-файлов?

КОД:

Код: Выделить всё

Sub Обработка_файлов()
i = 1
MyPath = ThisWorkbook.Path & "\"
MyName = Dir(MyPath & "*.docx")
Do While MyName <> ""
   doc = MyPath & MyName
   Set wd = CreateObject("Word.Application")
   Set wdd = wd.Documents.Open(doc)
   wdd.Content.Select
   wdd.Content.Copy
   wdd.Close (False)
   wd.Quit (False)

   Sheets(1).Activate
   ActiveSheet.Paste

   'ЗДЕСЬ БУДЕТ БЛОК ОБРАБОТКИ ВСТАВЛЕННОЙ ИНФОРМАЦИИ   

   Rows("1:50").Delete Shift:=xlUp
   i = i + 1
   MyName = Dir
Loop
End Sub


[ger_kar]

Что-то какое то нагромождение.
Если идея

Свести кучу word-файлов («*.docx») стандартного образца в единую базу

Какую базу?
И зачем промежуточно использовать Excel, какой в этом смысл? Может проще сразу обрабатывать (парсить) текст в Word, получать нужные элементы и сразу вставлять их в базу данных?
Что касается приведенного кода, то нафига в цикле каждый раз создавать Set wd = CreateObject("Word.Application")?
это же будет жуткий тормоз. Создай уж тогда его перед циклом, а в цикле открывай/закрывай документ, без создания/уничтожения "Word.Application"

- Есть какие-нидь другие варианты / примеры подобной обработки word-файлов?

Да вариантов валом, но пока сама задача не ясна, то что-то более конкретное сказать сложно.
Что за текст? Что нужно из него выделить? Что за база данных и т.д.

[Bananovyy]

Да вариантов валом, но пока сама задача не ясна, то что-то более конкретное сказать сложно.
Что за текст? Что нужно из него выделить? Что за база данных и т.д.

Прикладываю образец файла word – необходимо вытащить данные из желтых ячеек и систематизировать их в табличке (базе) Excel, типа:
№ | ИМЯ | ИНН | ОГРН | Бланки

[Qwertiy]

А ты уверен, что такое закрытие Word'a не очищает буфер обмена?
А ещё в возможности вставить то, что ты скопировал?

[Bananovyy]

А ты уверен, что такое закрытие Word'a не очищает буфер обмена?
А ещё в возможности вставить то, что ты скопировал?

Все копируется отлично… если прогнать макрос через F8, то вообще проблем нет. Выхожу из режима редактирования, запускаю… вылетает «ошибка 1004»… жму Debug / F8 – код прокручивается дальше, опять до этой строчки

[Sam777e]

Ну, если не обращать внимания на сказанное коллегой ger_kar [- а, в принципе, он всё сказал правильно ] и помочь сделать так, как тебе удобно / привычно / понятно . . . то вот модель. Перед запуском запихни что-либо в БуферОбмена. [ Я проверял на WinXP SP2 Excel 2003 ].

Код: Выделить всё

Sub Обработка_файлов()
  Dim i As Long
 
  For i = 1 To 5
    Sheets(1).Activate
    Cells(1, 1) = i
    Rows("2:50").Delete Shift:=xlUp
    Cells(2, 1).Select                      ' <<<<
     
    ActiveSheet.Paste
    DoEvents                                ' <<<<

    '  ЗДЕСЬ БУДЕТ БЛОК ОБРАБОТКИ ВСТАВЛЕННОЙ ИНФОРМАЦИИ 
  Next i
End Sub


[ger_kar]

Посмотрел я твой документ и пришел к выводу, что использование Excel там нафиг не нужно. это лишние нагромождения и жуткие тормоза. В твоем документе даже парсить то особо ничего не надо, ибо у тебя там и так всё разложено по полочкам, то бишь по ячейкам таблицы.
Надо просто брать нужные значения используя при этом коллекцию Tables и объекты этой коллекции Table, и далее использовать Cell и Range.
Если до вечера ничего не получиться, вечером напишу тебе код. Сейчас просто некогда этим заниматься.

[Bananovyy]

Посмотрел я твой документ и пришел к выводу, что использование Excel там нафиг не нужно. это лишние нагромождения и жуткие тормоза. В твоем документе даже парсить то особо ничего не надо, ибо у тебя там и так всё разложено по полочкам, то бишь по ячейкам таблицы.
Надо просто брать нужные значения используя при этом коллекцию Tables и объекты этой коллекции Table, и далее использовать Cell и Range.
Если до вечера ничего не получиться, вечером напишу тебе код. Сейчас просто некогда этим заниматься.

Если не трудно, был бы благодарен, опыта шары word-файлов вообще не имею...

[ger_kar]

Вот тебе код

Код: Выделить всё

Function GetName(oActiveDocument As Document) As String

    Dim objRange        As Range
    Dim strReplacement  As String
   
    strReplacement = Chr$(13) & Chr$(7)
   
    Set objRange = oActiveDocument.Tables(1).Cell(8, 2).Range
    GetName = objRange.Text
    GetName = Replace(GetName, strReplacement, vbNullString)
   
End Function


Function GetOGRN(oActiveDocument As Document) As String

    Dim lngColumn   As Long
    Dim objRange    As Range
    Dim strReplacement  As String
   
    strReplacement = Chr$(13) & Chr$(7)
   
    For lngColumn = 2 To 17
        Set objRange = oActiveDocument.Tables(1).Cell(10, lngColumn).Range
        GetOGRN = GetOGRN & Replace(objRange.Text, strReplacement, vbNullString)
    Next
   
End Function


Function GetINN(oActiveDocument As Document) As String

    Dim lngColumn   As Long
    Dim objRange    As Range
    Dim strReplacement  As String
   
    strReplacement = Chr$(13) & Chr$(7)
   
    For lngColumn = 2 To 11
        Set objRange = oActiveDocument.Tables(1).Cell(12, lngColumn).Range
        GetINN = GetINN & Replace(objRange.Text, strReplacement, vbNullString)
    Next
   
End Function

А вот твой документ с работающим примером (смотри модуль). Сделал три ф-ции. Остальное надеюсь сам доделаешь как тебе надо. Там все очень просто

[Bananovyy]

А вот твой документ с работающим примером (смотри модуль). Сделал три ф-ции. Остальное надеюсь сам доделаешь как тебе надо. Там все очень просто

Спсб, как забирать данные понял.
Не ясно как это реализовать для группы файлов:
- Откуда будет запускаться макрос
- Как в этой цепочке открываются word-файлы
- Где соответственно сохранять результаты

хотя бы на словах

[Bananovyy]

Ну, если не обращать внимания на сказанное коллегой ger_kar [- а, в принципе, он всё сказал правильно ] и помочь сделать так, как тебе удобно / привычно / понятно . . . то вот модель. Перед запуском запихни что-либо в БуферОбмена. [ Я проверял на WinXP SP2 Excel 2003 ].

DoEvents в 2007 видимо не пашет... та же 1004 ошибка

[ger_kar]

Не ясно как это реализовать для группы файлов:

Ну у тебя же, в том куске кода, который ты привел в первом посте это уже реализовано, надо его просто немного видоизменить выкинув ненужное и воспользовавшись моим советом с выносом Set wd = CreateObject("Word.Application") за тело цикла.
Например так:

Код: Выделить всё

Sub Обработка_файлов()
     Dim i as Long
     Dim MyPath as string, MyName as string, doc as string
     Dim wd as Word.Application, wdd as Word.Document
     Dim strName as string
     
     i = 1
     MyPath = ThisWorkbook.Path & "\"
     MyName = Dir(MyPath & "*.docx")
     Set wd = CreateObject("Word.Application")
     Do While MyName <> ""
         doc = MyPath & MyName
         Set wdd = wd.Documents.Open(doc)
         
        'Вызываем ф-цию из моего примера       
        strName = GetName(wdd)
        'Вызываем другие ф-ции аналогичным образом

                   'ЗДЕСЬ БУДЕТ БЛОК ВСТАВКИ В БАЗУ ДАННЫХ   

         wdd.close 'закрываем документ
         MyName = Dir
     Loop
     wd.Quit 'Закрываем Word
     set wd = Nothing 'Обнуляем объектную переменную
End Sub

- Откуда будет запускаться макрос

Странный вопрос. Я откуда знаю, как тебе надо и откуда надо его запускать? Вариантов валом. Можно сделать процедуру экспорта из Word. Можно сделать процедуру импорта в той базе, куда ты это все собираешься вставлять. Можно сделать отдельное приложение на VB. Тут уж как тебе удобно, так и надо делать.

- Где соответственно сохранять результаты

Ну в базу которую ты собираешься заполнять, ты же этого хотел. Ты в самом первом посте писал:

- Поочередно открываю файлы «*.docx» из книги Excel
- Копирую содержимое и вставляю на первый лист Excel
- Откуда затем из определенных ячеек переношу информацию в базу
- Удаляю вставленную ранее информацию
- Повторяю процедуру по новой…

Получится:
- Открываю документ
- Откуда затем из определенных ячеек переношу информацию в базу
- Закрываю документ
- Открываю другой документ
И так много раз подряд

[Bananovyy]

Получится:
- Открываю документ
- Откуда затем из определенных ячеек переношу информацию в базу
- Закрываю документ
- Открываю другой документ
И так много раз подряд

А мне не до смеха)))
Спасибо, поковыряюсь вечером

[ger_kar]

А мне не до смеха)))

Надо ко всему относиться с юмором! Нам юмор строить и жить помогает
Тут все элементарно, у тебя все получится, ну а если... Тогда поможем.

[Bananovyy]

Вопрос по теме, вдогонку: подскажите дельные ссылки по парсингу интернета / вордов на VBA, может примеры где-то в нете весят?

[Sam777e]

Вопрос по теме, вдогонку: подскажите дельные ссылки по парсингу интернета / вордов на VBA, может примеры где-то в нете весят?

http://word.tips.net/

[ger_kar]

Я думаю, что в данном деле (парсинге) тебе обязательно понадобятся регулярные выражения, поэтому если ты что-то будешь серьезно парсить, то без изучения регулярных выражений тебе не обойтись, да и для общего развития их изучить будет полезно.
Начни пожалуй с этой статьи, а потом прочти здесь

[ger_kar]

Что касается именно Word, то обязательно почитай Это и вот здесь
И еще вот

[Bananovyy]

Я думаю, что в данном деле (парсинге) тебе обязательно понадобятся регулярные выражения, поэтому если ты что-то будешь серьезно парсить, то без изучения регулярных выражений тебе не обойтись, да и для общего развития их изучить будет полезно.
Начни пожалуй с этой статьи, а потом прочти здесь

Блин, даже здесь Wikipedia)))
Спасибо!