Вопрос про ТРЕЙ

[X-BOND]

Привет!
Имею программку, которая при запуске прописывает свою иконку в трее. Проблема возникает, когда глючит Explorer и его приходится перезагружать. И значек исчезает из трея. Так вот я хотел бы узнать, какими методами можно перехватить момент перезагрузки TaskBar-а и вновь прописать там свою иконку.

[MEMBER]

Сабклассишь форму и перехватываешь сообщение TaskBarCreated.

[X-BOND]

А можно пример какой нибудь

[MEMBER]

Что, лениво разбираться?
В форму:

Код: Выделить всё

Public TaskBar
Private Sub Form_Load()
    AddIcon ' Добавляем иконку
    TaskBar = RegisterWindowMessage("TaskbarCreated")
    gWH = Me.hwnd 'дескриптор нашего окна
    OldWndProc = SetWindowLong(gWH, GWL_WNDPROC, AddressOf WindowProc)
End Sub
Private Sub Form_Unload(Cancel As Integer)
    Shell_NotifyIcon NIM_DELETE, nid
End Sub


В модуль:

Код: Выделить всё

' Сабклассинг
Declare Function SetWindowLong Lib "user32" Alias _
            "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex _
            As Long, ByVal dwNewLong As Long) As Long
Declare Function CallWindowProc Lib "user32" Alias _
            "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
            ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam _
            As Long, ByVal lParam As Long) As Long
Declare Function RegisterWindowMessage Lib "user32" _
            Alias "RegisterWindowMessageA" (ByVal lpString As String) As Long
Public Const GWL_WNDPROC = -4
Public gWH As Long
Public OldWndProc As Long
   
Public Declare Function Shell_NotifyIcon Lib "shell32" _
            Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, _
            pnid As NOTIFYICONDATA) As Boolean

Public Type NOTIFYICONDATA
   cbSize As Long
   hwnd As Long
   uId As Long
   uFlags As Long
   uCallBackMessage As Long
   hIcon As Long
   szTip As String * 64
End Type

' Эти константы нужны для добавления, обновления
' и удаления иконки в SysTray
Public Const NIM_ADD = &H0
Public Const NIM_MODIFY = &H1
Public Const NIM_DELETE = &H2

' Следующая константа нужна для показа всплывающей подсказки
' когда курсор наводится на иконку в SysTray
Public Const WM_MOUSEMOVE = &H200

' Принимаем значения констант NOTIFYICONDATA
Public Const NIF_MESSAGE = &H1
Public Const NIF_ICON = &H2
Public Const NIF_TIP = &H4

' Следующие константы нужны для проверки нажатий клавиш мышки

' Константы при нажатии левой кнопки мышки
Public Const WM_LBUTTONDBLCLK = &H203
Public Const WM_LBUTTONDOWN = &H201
Public Const WM_LBUTTONUP = &H202

' Константы при нажатии правой кнопки мышки
Public Const WM_RBUTTONDBLCLK = &H206
Public Const WM_RBUTTONDOWN = &H204
Public Const WM_RBUTTONUP = &H205
Public nid As NOTIFYICONDATA

Public Sub AddIcon()
' добавляем иконку от формы в SysTray
    nid.cbSize = Len(nid)
    nid.hwnd = frmMain.hwnd
    nid.uId = vbNull
    nid.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
    nid.uCallBackMessage = WM_MOUSEMOVE
    nid.hIcon = frmMain.Icon
    nid.szTip = "Autologin" & vbNullChar
' добавим иконку в SysTray
    Shell_NotifyIcon NIM_ADD, nid
    Shell_NotifyIcon NIM_MODIFY, nid
End Sub
Function WindowProc(ByVal hwnd As Long, ByVal Msg As Long, ByVal _
                    wParam As Long, ByVal lParam As Long) As Long
    Dim lReturn As Long
    TaskBarcreated = frmMain.TaskBar
   
    'вначале позволим произвести обработку стандартной оконной процедуре процедуре, а затем сами
    lReturn = CallWindowProc(OldWndProc, hwnd, Msg, wParam, lParam)
    Select Case Msg 'проверяем сообщения
        Case TaskBarcreated 'если нужное нам, то выполняем некоторые действия
        AddIcon
    End Select
    WindowProc = lReturn 'вернем значение функции
End Function


[X-BOND]

Благодарствую, MEMBER, за приведенный пример
А вообще ты прав, ленивый я . И еще не совсем понимаю, что такое Сабклассинг .
Щас буду разбираться...

[emlen]

Большущее спасибо МЕМБЕР за пример, нигде не мог найти, очень и очень благодарен!!!!!

[VBTerminator]

MEMBER, лучше не Public TaskBar, а Public TaskBar As Long.

[Хакер]

Сразу обоим предупреждение за некрофилию?

[Qwertiy]

А как можно чужие иконки в трей вернуть? Или это невозможно?

[tav]

А как можно чужие иконки в трей вернуть? Или это невозможно?

теоретически, зная какие программы добавили иконки в трей, т.е. придется отлавливать всех кто туда добавляется, и после "попросить" обновить их свои иконки.