распечатать в бинарном формате

[dima-pol]

Здраствуйте!

Как в VB6 вывести целое число в строковую переменную в бинарном виде?

Спасибо

[Qwertiy]

Подозреваю, что только руками...

[Хакер]

Как в VB6 вывести целое число в строковую переменную в бинарном виде?

Пример? И куда вывести?

[Qwertiy]

Пример? И куда вывести?

Что тут может быть непонятно?

Код: Выделить всё

Public Function IntToBin(ByVal X As Integer) As String
  If X < 0 Then
    Dim Q As Integer
    IntToBin = IntToBin(Not X)
    For Q = 1 To Len(IntToBin)
      Mid$(IntToBin, Q, 1) = Chr$(Asc(Mid$(IntToBin, Q, 1)) Xor 1)
    Next Q
    For Q = Len(IntToBin) To 15
      IntToBin = "1" & IntToBin
    Next Q
  Else
    IntToBin = ""
    Do
      IntToBin = (X And 1) & IntToBin
      X = X \ 2
    Loop While X
  End If
End Function

Public Sub Main()
  MsgBox (IntToBin(117))
  MsgBox (IntToBin(-117))
  MsgBox (IntToBin(0))
End Sub

[Хакер]

Что тут может быть непонятно?

Это называется не число в бинарном формате, а текстовое представление числа в двоичной системе счисления.

Это делается это не таким уродским образом, а вот так:

Код: Выделить всё

Function ValueToBinRepresentation(ByVal value As Long) As String
    Const ConvTable$ = "0000000100100011010001010110011110001001101010111100110111101111"
    Dim i As Long, qbitpart As Long, msb As Boolean
    ValueToBinRepresentation = String(32, "0")
    If value And &H80000000 Then
        value = value And Not &H80000000: msb = True
    End If
    For i = 7 To 0 Step -1
        qbitpart = value And &HF: value = value \ &H10
        Mid$(ValueToBinRepresentation, 1 + i * 4, 4) = Mid$(ConvTable, 1 + qbitpart * 4, 4)
    Next i
    If msb Then Mid$(ValueToBinRepresentation, 1, 1) = "1"
End Function

[Qwertiy]

Это делается это не таким уродским образом, а вот так:

И чем же это лучше?

[Хакер]

Тем, что это не быдлокодерский код.
Он меньше твоего, понятнее твоего, лучше по этим параметрами, и в равных условиях (конвертация всех Long-чисел из диапазона Long-чисел с шагом 1111d) отработал все числа за 9 секунд, против 86 секунд твоего кода.

Вопросы?

[Хакер]

Нет, правда. Человек инвертирует биты в числе, потом получает bin-представление инвертированного числа, потом проходится по строчке с представлением инвертированного числа, меняет символы «0» на символы «1», а символы «1» на символы «0», а потом наращивает ведущие биты префиксируя символы «0» по одному символу в начало строки в цикле?

И хватает совести спрашивать, чем такой подход на замечателен?

[dima-pol]

Спасибо всем!
Получается, что встроенных средств для вывода в бинарном формате у VB6 нет?

Хакер, я воспользовался Вашей идеей (ConvTable) и попыталься чуть подсократить код:

Код: Выделить всё

Function ValueToBinRepresentation8(ByVal value As Long) As String
    Const ConvTable$ = "000001010011100101110111"
    Dim i As Long, str As String
    str = Oct(value)
    ValueToBinRepresentation8 = ""
    For i = 1 To Len(str)
        ValueToBinRepresentation8 = ValueToBinRepresentation8 & Mid$(ConvTable, 1 + (Asc(Mid$(str, i, 1)) - 48) * 3, 3)
    Next i
    ValueToBinRepresentation8 = String(32 - Len(ValueToBinRepresentation8), "0") & ValueToBinRepresentation8 ' эта команда не обязательна
End Function

Не могли бы его потестить по времени.
Спасибо.

[Хакер]

Даже не буду тестить, это отвратительно.