Этот глюк в WORD-е только у меня?

[Shurrik]

WORD 2003. Делаю поиск и замену текста. Все ОК. Записываю макрос, чтобы узнать, как это делается. Запускаю этот макрос. Замена происходит, но не везде, в надписях остается по старому. Когда надпись выделена, то замена происходит, но только в одной надписи. А их у меня много.
Вопрос: а можно, чтобы макрос делал то же самое, что я ручками? Или у меня WORD с глюками?

[Evans]

Попробовал...

Код: Выделить всё

Sub GoToOpenSource()
Dim aStory
   
For Each aStory In StoryRanges
    If aStory.StoryType = wdTextFrameStory Then
        aStory.Find.Execute FindText:="Windows", ReplaceWith:="Linux", Replace:=wdReplaceAll
    End If
Next
End Sub


Заменяет указанный текст только в последней надписи в документе. Чума какая-то ((.

[Shurrik]

Уточняю. Если выделена одна надпись, то замена только в ней, а в тексте документа нет. Если выделить несколько надписей, то замена только в одной. Странная какая-то логика.
Выделяю по очереди все надписи и делаю замену. А вот как снять выделение с надписи, чтобы сделать замену в самом документе - облом. Вроде простое действие, а как сделать? Может кто знает?

[Gloom]

Попробовал...
Заменяет указанный текст только в последней надписи в документе. Чума какая-то ((.

...Use the NextStoryRange property to loop through all stories in a document...

Код: Выделить всё

Public Sub ReplaceTextInRange(RangeToReplace As Range, ByVal Text As String, ByVal ReplacementText As String)
       
        With RangeToReplace.Find
       
            .Text = Text
            .Replacement.Text = ReplacementText
            .Wrap = wdFindContinue
            .Execute Replace:=wdReplaceAll
           
        End With
       
End Sub

Public Sub ReplaceText(ByVal Text As String, ByVal ReplacementText As String)
    Dim Story As Range
   
    For Each Story In ActiveDocument.StoryRanges
       
        Do
       
            ReplaceTextInRange Story, Text, ReplacementText
            Set Story = Story.NextStoryRange
           
        Loop While Not Story Is Nothing
       
    Next
   
End Sub

ReplaceText "Windows", "Linux"


[Shurrik]

Gloom, огромное спасибо!
Все работает отлично!