помогите разобратся с WebBrowser

[medvedinyatko]

Как реализовать клик по ссылке в компоненте WebBrowser?
viewtopic.php?f=1&t=38404
Был такой топик а мне надо тоже самое только не по ссылке а по кнопке и выбор выпадающей вкладки.
на примере http://www.mail.ru
выпадающая вкладка @mail.ru/@list.ru/@bk.ru/inbox.ru
кнопка "Войти"

[Vova_2581]

Код: Выделить всё

Const READYSTATE_COMPLETE = 4

Private Sub Command1_Click()
With WebBrowser1.Document
  .getElementById("Domain").Value = "mail.ru" 'выпадающая вкладка @mail.ru/@list.ru/@bk.ru/inbox.ru
  .getElementById("Login").Value = "Login"
  .getElementById("Password").Value = "Password"
  .Forms(2).submit 'Войти
End With
End Sub

Private Sub Form_Load()
Show
WebBrowser1.Navigate "http://mail.ru"
While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
   DoEvents
Wend
End Sub

[Invader]

Код: Выделить всё

Const READYSTATE_COMPLETE = 4

Private Sub Command1_Click()
With WebBrowser1.Document
  .getElementById("Domain").Value = "mail.ru" 'выпадающая вкладка @mail.ru/@list.ru/@bk.ru/inbox.ru
  .getElementById("Login").Value = "Login"
  .getElementById("Password").Value = "Password"
  .Forms(2).submit 'Войти
End With
End Sub

Private Sub Form_Load()
Show
WebBrowser1.Navigate "http://mail.ru"
While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
   DoEvents
Wend
End Sub

на странице в коде www.mail.ru я не нашел .getElementById("Password") как в прочем и других элементов
пример рабочий и хороший, но как можно вызвать дерево элементов формы и конкретной формы
а также было бы интересно узнать как например список входящие письма вывести в свой textbox на своей форме а не через WebBrowser

[Vova_2581]

на странице в коде http://www.mail.ru я не нашел .getElementById("Password") как в прочем и других элементов

Плохо искал значит. MSDN указывает, что в методе getElementById можно использовать, как ID так и NAME элементов. В данном случаи выполнилось обращение к объекту Password в тэге TD формы авторизации. У этого объекта есть имя = "Password". И все остальные также.

Вызвать все элементы конкретной формы можно так --

Код: Выделить всё

For Each MyObject In WebBrowser1.Document.Forms(2).getElementsByTagName("*")
   Debug.Print MyObject.innerHTML
Next

или конкретных тэгов -- getElementsByTagName("TD") ‘("DIV") ‘("SPAN") и т.д.

Перейти во «Входящие» можно по ссылке указатель на которую получаем по ID "folderLink_0" --

Код: Выделить всё

WebBrowser1.Navigate WebBrowser1.Document.getElementById("folderLink_0").href

Другие -- «Сомнительные», «Отправленные» и т.д. соответственно ID -- «folderLink_950», «folderLink_500000».

Поставить отметку «Чужой компьютер» можно тоже по ID «alien» --

Код: Выделить всё

WebBrowser1.Document.getElementById("alien").Checked = 1

Ну а получить список писем, например, полей -- «Автор» и «Тема» можно через тэг “U” --

Код: Выделить всё

For Each MyObject In WebBrowser1.Document.getElementsByTagName("U")
   List1.AddItem CStr(MyObject.innerText)
Next

Короче, внимательно изучай HTML листинг и JavaScript.

[Invader]

ОГРОМНОЕ спасибо ЗА СТОЛЬ ПОДРОБНОЕ РАЗЪЯСНЕНИЕ...
Правда forms(2) в листинге страницы (mail.ru), среди html с совокупностью с Java script так и не обнаружил
просматривал страницу mail.ru через firefox от туда же и открывал код страницы - возможно не корректное отображение, исходного кода

во всём коде одно только упоминание закрывающего тега </form>
либо это правило заполнения

Код: Выделить всё

WebBrowser1.Document.Forms'...

а) почему тогда forms(2) -откуда индекс?
б)что является forms(1)?
за совет спасибо: "внимательно изучай HTML листинг ..."
p.s. буду учить примеры

[Хакер]

p.s. буду учить примеры

Чтобы потом наизусть на ночь читать детям?

[Invader]

p.s. буду учить примеры

Чтобы потом наизусть на ночь читать детям?

Не"а ....
чтоб дядю - спеЦиалиста по перфокартам, запугать, современными текнолоджи

p.s. ' vb6 - microSOFT forever
и да пребудет с нами терпение

[Vova_2581]

а) почему тогда forms(2) -откуда индекс?

Любой браузер является интерпретатором команд HTML-кода. Иными словами, HTML – это набор инструкций, выполняя которые он «рисует» на странице то, что ты указал в тэгах. Так вот, читая инструкции последовательно, он также последовательно индексирует одноименные объекты в HTML.

Можешь узнать, к примеру, количество объектов формы на странице --

Код: Выделить всё

Debug.Print WebBrowser1.Object.Document.Forms.Length

(отсчет ведется с нуля)

Прочитать их имена --

Код: Выделить всё

For Each MyObject In WebBrowser1.Document.getElementsByTagName("FORM") 'или WebBrowser1.Document.Forms
   Debug.Print MyObject.Name
Next 

И заполнить поля формы авторизации по индексу или имени формы --

Код: Выделить всё

With WebBrowser1.Document
  .Forms(2).Domain.Value = "mail.ru"
  .Forms(2).Login.Value = "Login"
  .Forms(2).Password.Value = "Password"
  .Forms(2).submit
  'тоже самое --
  .Forms("Auth").Domain.Value = "mail.ru"
  .Forms("Auth").Login.Value = "Login"
  .Forms("Auth").Password.Value = "Password"
  .Forms("Auth").submit
End With

Можешь выделить и отобразить в браузере только эту форму --

Код: Выделить всё

Dim HTML As String
HTML = WebBrowser1.Document.Forms("Auth").innerHTML
WebBrowser1.Document.Write HTML

Посмотри ссылку по Java, которую я дал вначале -- там все очень хорошо написано. Разбирайся и делай, что тебе надо.

[Хакер]

Любой браузер является интерпретатором команд HTML-кода. Иными словами, HTML – это набор инструкций, выполняя которые он «рисует» на странице то, что ты указал в тэгах. Так вот, читая инструкции последовательно, он также последовательно индексирует одноименные объекты в HTML.

Ерунду говоришь. Учи разницу между императивными и декларативными языками.

[Vova_2581]

Ерунду говоришь. Учи разницу между императивными и декларативными языками.

Ну вот и объясни человеку в чем разница.

[Vova_2581]

А на этом стало быть "ладушки"! Дальше пусть сам работает.

[Invader]

А на этом стало быть "ладушки"! Дальше пусть сам работает.

С превеликим рвением, СПАСИБО ТЕБЕ - всё доходчиво и внятно
и главное в примерах!!!!

[Invader]

возник вопрос,
обращаюсь я к странице http://www.google.ru
нашел поле ввода принадлежащей первой и единственной форме(0)
передал слово для поиска - "развлечения"
и определив кнопку submit
запустил поиск, получил список сайтов.
Заголовки которых лежат в тегах <h3 class="r"><a onmousedown="...')" class="l" target="_blank" собственно ссылка на страницу и сам заголовок</a></h3>
Другими словами,
получить список заголовок результатов, можно через тэг “а”
WebBrowser1.Document.getElementsByTagName("а")
но по тэгу “а” список другого рода - сервисы гугла.
Понимаю что тег "а" в контексте страницы используется часто
и что в моём случае, он вложен в дерево тегов, а именно <span class="tl"><h3 class="r"><a...> </a></h3></span> в тэг "span", но и .getElementsByTagName("span") не дал результата
мой код:

Код: Выделить всё

Option Explicit
Const READYSTATE_COMPLETE = 4

Private Sub Command1_Click()
Dim MyObject As Variant
With WebBrowser1.Document
  .getElementById("q").Value = "развлечения" 'слово вносимое в поиск
  .Forms(0).submit 'собсно кнопка поиск
End With
For Each MyObject In WebBrowser1.Document.getElementsByTagName("a")'вот здесь вопрос по передачи найденого
   List1.AddItem CStr(MyObject.innerText)
Next
End Sub



Private Sub Form_Load()
Dim MyObject As Variant

WebBrowser1.Navigate "http://google.ru"
While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
   DoEvents
Wend
For Each MyObject In WebBrowser1.Document.getElementsByTagName("ID")
   Debug.Print MyObject.innerHTML
   
Next
End Sub

и ещё вопрос почему когда я пытаюсь скрыть-сделать не видимым WebBrowser1, и вся форма с контролами становится также не видимой

[Antonariy]

Ты перебираешь ссылки в том же самом документе, в котором вносил в поиск слово.
После submit нужно завершать все действия с текущим документом и ожидать READYSTATE_COMPLETE с новым документом, в котором будут результаты поиска. Или как минимум вставить цикл while readystate (как в form_load) между submit и перебором.

[Invader]

спасибо за помощь, но не помогло ниже мой код на кнопке

Код: Выделить всё

Private Sub Command1_Click()
Dim MyObject As Variant
With WebBrowser1.Document
  .getElementById("q").Value = "развлечения" 'слово вносимое в поиск
  .Forms(0).submit 'собсно кнопка поиск
End With
While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
   DoEvents
Wend
For Each MyObject In WebBrowser1.Document.getElementsByTagName("a") 'вот здесь вопрос по передачи найденого
   List1.AddItem CStr(MyObject.innerText)
Next
End Sub

по тэгу "а" выдаёт
по прежнему не то
...Расширенный поискЯзыковые инструментыЖивой поиск включенЖивой поиск Подробнее...› Включить› Отключить...
проблема как мне кажется что все сылки начинаются с тега "а"
весь вопрос сводится к пути вложенности...
тоесть скажем результатов 7 штук
я определил что их контейнеры начинаются с тега "li"
в нём же прячутся два контейнера один для заголовка другой для краткого описания
описания начинаются с тэга h3
ВСЁ ПОЛУЧИЛОСЬ, СПАСИБО ЗА ПОМОЩЬ

[Invader]

но вот вопрос
почему при первом нажатии
я передал значения, но данные не получил, а лишь при втором нажатии
данные получаю в text1.text

Код: Выделить всё

Private Sub Command1_Click()
Dim s As String
s = Text2.Text
Dim MyObject As Variant
While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
   DoEvents

Wend
With WebBrowser1.Document
  .getElementById("q").Value = s 'слово вносимое в поиск
  .Forms(0).submit 'собсно кнопка поиск

End With
Text1.Text = Empty
For Each MyObject In WebBrowser1.Document.getElementsByTagName("h3") 'вот здесь вопрос по передачи найденого
   
   Text1.Text = Text1.Text + CStr(MyObject.innerText) + Chr(13) + Chr(10)
Next
End Sub

И ПОЧЕМУ ПРИ WebBrowser1.visible = false, а form1.visible=true
форма исчезает тоже

[Antonariy]

почему при первом нажатии

Во-первых, потому что херня написана. Почему цикл While WebBrowser1.ReadyState внезапно переехал в начало процедуры? Во-вторых, броузеру нужно какое-то время на загрузку. Чтобы не возникало желаний тыкать кнопки когда не надо, перед циклом ReadyState нужно кнопку выключать, а после включать.

И ПОЧЕМУ ПРИ WebBrowser1.visible = false, а form1.visible=true
форма исчезает тоже

Глюк. Тестовый проект в студию.

Код: Выделить всё

Chr(13) + Chr(10)

В чем vbCrLf провинилось?

[Invader]

вот сырой проект

[Antonariy]

Проблема была в том, что WebBrowser1.ReadyState = READYSTATE_COMPLETE сигнализирует об окончании загрузки html-текста, но новый документ на этот момент еще не сформирован. Так будет наверняка:

Код: Выделить всё

Command1.Enabled = False
While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
   DoEvents
Wend
While WebBrowser1.Document.ReadyState <> "complete"
   DoEvents
Wend
Command1.Enabled = True

По поводу исчезающей формы в примере нет ни строчки, но форма не прячется вслед за броузером.

[Invader]

Благодарю за помощь, вот только по поводу скрытия WebBrowser1....
код с исправлениями и с корректировкой видимости
'WebBrowser1.Visible = False
Form1.Visible = True
проблема в том, что WebBrowser1 прячется, форма видна.... НО при заполнении поля запроса и нажатия submint, вылетает ошибка object variable not set
в коде я пометил строчку

Код: Выделить всё

Const READYSTATE_COMPLETE = 4

Private Sub Command1_Click()
Dim s As String
s = Text2.Text
Dim MyObject As Variant

With WebBrowser1.Document
.getElementById("q").Value = s '(ошибка)здесь вылетает ошибка при WebBrowser1.Visible = False
  .Forms(0).submit 'собсно кнопка поиск

End With
Command1.Enabled = False
While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
   DoEvents
Wend
While WebBrowser1.Document.ReadyState <> "complete"
   DoEvents
Wend
Command1.Enabled = True
Text1.Text = Empty
For Each MyObject In WebBrowser1.Document.getElementsByTagName("h3") 'вот здесь вопрос по передачи найденого
   
   Text1.Text = Text1.Text + CStr(MyObject.innerText) + vbCrLf
Next
End Sub



Private Sub Form_Load()
'WebBrowser1.Visible = False 'если включено выше строчка помечена (ошибка)
Form1.Visible = True
Dim s As String
s = Text2.Text
Dim MyObject As Variant

WebBrowser1.Navigate "http://google.ru"
While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
   DoEvents
Wend
For Each MyObject In WebBrowser1.Document.getElementsByTagName("ID")
   Debug.Print MyObject.innerHTML
   
Next
End Sub