Ошибка при первом запуске программы

[Andr222]

Ситуация такая:
Пишу программу на VB 6.0. Есть база DBF сторонней программы. Я пишу прогу, которая будет выполнять запросы из базы DBF и вести свою базу MDB (Access).
Ошибка возникает при первом запуске программы после запуска VB:
Ошибка -2147467259,[Драйвер ODBC dBase] Выбранная последовательность сортировки не поддерживается операционной системой!
Далее нажимаю на остановку выполнения проекта. Запускаю вновь проект на выполнение, и программа запускается без ошибки.
Использую строку подключения к DBF:
ConnectionString = "Provider=MSDASQL.1;Persist Security Info=False;Data Source=dbfFPO;Initial Catalog=" & Text1 & "",
где Text1=Путь к каталогу с базой DBF
Запрос из базы выполняю так:
strSQL = "SELECT [OTDELEN#DBF].KODOTD, [OTDELEN#DBF].NAME From [OTDELEN#DBF] ORDER BY [OTDELEN#DBF].KODOTD"
With Adodc1
.ConnectionString = ConnectionString
.CommandType = adCmdText
.RecordSource = strSQL
.Refresh
.Recordset.MoveFirst
End With
Заметил еще: ошибка возникает иногда при долгом простое VB6, т.е. когда долго редактирую код, просто просматриваю код, без долгого запуска проекта.
И еще, кажется эта ошибка начала выскакивать после установки SP6 на VB6.
Подскажите пожалуйста, как избавиться от этой ошибки?

[FireFenix]

Пуск » Настройка » Панель управления » Язык и региональные стандарты = закладка "Языки", поставить галочку "Установить поддержку языков с письмом иероглифами".

Согласиться с предложением ОС о том, что потребуется дополнительно 230 Мб свободного места на винте, после копирования файлов перезагрузить комп.

[Andr222]

Пуск » Настройка » Панель управления » Язык и региональные стандарты = закладка "Языки", поставить галочку "Установить поддержку языков с письмом иероглифами".

Согласиться с предложением ОС о том, что потребуется дополнительно 230 Мб свободного места на винте, после копирования файлов перезагрузить комп.

НЕ ПОМОГАЕТ!!! Есть еще какие-нибудь решения? Пожалуйста.

[FireFenix]

Играться с настройками кодировки

Или выложи исходник + файл БД

[Andr222]

Исходники не получится, слишком большая база и сложный алгоритм подключение к ней. Долго объяснять, но база очень специфическая, в плане расположения DBF файлов в отдельных папках. Додключение я сделал динамическое, и теперь чтоб работал проект на другой машине, нужна вся база сторонней программы.
Если только отдельный фрагмент проекта, и один DBF файл, чтоб приспособить этот фрагмент на другой машине и попробовать выполнить запрос к одному DBF файлу!
Вот урезанный код, в котором возникает ошибка при открытии набора записей:

Public Sub MDIFormLoad()
Dim adorecRaion As ADODB.Recordset
Dim DB As ADODB.Connection
Dim DirResa As String 'директория DBF файла
Dim ConnectionString As String
Dim strSQL As String
Dim KodRaion As Integer 'переменная для выбора кода района в SQL запросе
KodRaion=1
ConnectionString = "Provider=MSDASQL.1;Persist Security Info=False;Data Source=dbfFPO;Initial Catalog=" & DirResa & ""
Set DB = New ADODB.Connection
Set adorecRaion = New ADODB.Recordset
DB.Open ConnectionString
strSQL = "SELECT * From [RAION#DBF] Where ([RAION#DBF].KODRAION) = " & KodRaion & ""
adorecRaion.Open strSQL, DB, adOpenStatic, adLockReadOnly
End Sub

Настройка источника данных dbfFPO во вложенном файле.
Файл RAION.DBF выкладываю, только расширение поменял на .XLS т.к. администрация сайта запрещает выкладывать DBF.

[Andrey Fedorov]

1.
Можно поставить нормальный Microsoft OLE DB Provider for Visual FoxPro 9.0 и подключайся к dbf-кам через него, забыв об ODBC как о страшном сне.

2.
Можно перехватить ошибку и сказать на нее Resume - коннект и откроется...

P.S
По мне так лучше вариант 1.

[Andr222]

Вот присмостырил кусок кода к форме. Вот здесь и возникает ошибка.

[Andr222]

1.
Можно поставить нормальный Microsoft OLE DB Provider for Visual FoxPro 9.0 и подключайся к dbf-кам через него, забыв об ODBC как о страшном сне.

2.
Можно перехватить ошибку и сказать на нее Resume - коннект и откроется...

P.S
По мне так лучше вариант 1.

Дело в том, что недавно начал изучать VB 6.0 и вообще программирование. Пытался подключаться с помощью других драйверов и провайдеров, ничего не получилось.
Может кинет кто-нибудь пример подключения к базе DBF, со всеми соответствующими настройками системы (источники данных и т.д и т.п.) с помощю Microsoft OLE DB Provider for Visual FoxPro 9.0.
P.S. Почему выбрал провайдера: ConnectionString = "Provider=MSDASQL.1;Persist Security Info=False;Data Source=dbfFPO;Initial Catalog=" & DirResa & "", хотелось чтоб стороннее приложение не конфликтовало с моим проектом. Стороннее приложение написано на Delphi, для доступа к базе данных использует BDE. Первое с чем я столкнулся при подключении к базе, это конфликт BDE с моим проектом.Т.е. невозможно было запустить мой проект одновременно с запущенным сторонним приложением. Возникала ошибка № не помню, но где то на форуме нашел как ее исправить. Все вылечилось путем изменения параметра BDE в реестре (в общем отключил BDE). При этом мой проект, заработал со сторонней программой при одновременно запущенных приложениях.

[Andr222]

Попробовал подключиться через Microsoft OLE DB Provider for Visual FoxPro 9.0
получилось абракадабра вместо шрифтов! Проект с подключением через Microsoft OLE DB Provider for Visual FoxPro 9.0 выкладываю.
Я думаю, что-то с настройками шрифтов.

[Andrey Fedorov]

Примеры с OLEDB и ODBC в приложенном файле. Для того чтобы OLEDB-провайдер правильно воспринимал кодировку она должна быть указана в 29-м байте DBF-файла - сравни мой RAION.DBF со своим. Может этом можно указать в строке подключения, но я уже не помню...

Для смены кодировок можно воспользоваться утилиткой CPDBF - см в соответствующем каталоге. Описание есть там же.

[Andr222]

Примеры с OLEDB и ODBC в приложенном файле. Для того чтобы OLEDB-провайдер правильно воспринимал кодировку она должна быть указана в 29-м байте DBF-файла - сравни мой RAION.DBF со своим. Может этом можно указать в строке подключения, но я уже не помню...

Для смены кодировок можно воспользоваться утилиткой CPDBF - см в соответствующем каталоге. Описание есть там же.

Да, с приложенным файлом OLEDB-провайдер работает. Пробовал утилиткой конвертировать файл DBF, тоже работает. Но все же база DBF сторонняя, и конвертировать файлы нежелательно и не удобно. Может есть другие варианты. Искал настройки OLEDB-провайдера на кодировку текста DOS. Ничего не нашел. И почему ODBC правильно воспринимает кодировку, вот только иногда выдает ошибку о неподдерживаемой сортировке?

[alibek]

Ну не конвертируй, а заменяй байт в файле в своей программе (перед открытием файла).

[Andr222]

Ну не конвертируй, а заменяй байт в файле в своей программе (перед открытием файла).

Как это сделать? Можно примерчик!

[Andrey Fedorov]

Да, с приложенным файлом OLEDB-провайдер работает. Пробовал утилиткой конвертировать файл DBF, тоже работает.

Утилита не конвертирует, а прописывает кодовую страницу в DBF-файл.

И почему ODBC правильно воспринимает кодировку, вот только иногда выдает ошибку о неподдерживаемой сортировке?

Там же есть пример обработки данной ошибки ODBC...

Собственно драйвер ODBC очень древний, и, скорей всего просто не знает что в DBF-файле может указываться его кодовая страница. Соответственно всегда воспринимает ее как OEM.

[Andrey Fedorov]

Как это сделать? Можно примерчик!

Ну типа так:

Код: Выделить всё

Option Explicit

Public Sub Main()
    OpenODBC
   
    OpenOLEDB
End Sub

Public Sub OpenOLEDB()
    Dim cn As New ADODB.Connection, r As New ADODB.Recordset
    Dim sFile As String
   
    SetCodePageDbf App.Path & "\RAION.DBF"
   
    On Error GoTo Err_
    cn.CursorLocation = adUseClient
    cn.Provider = "VFPOLEDB.1"
    cn.Open "Data Source=""" & App.Path & """;Collating Sequence=RUSSIAN"
   
    r.Open "SELECT * FROM RAION ORDER BY [NAME]", cn, adOpenStatic, adLockReadOnly
    Debug.Print
    Debug.Print "--== OpenOLEDB ==--"
    Do Until r.EOF
        Debug.Print r!Name
        r.MoveNext
    Loop
    Exit Sub

Err_:
    MsgBox Err.Description, vbCritical
End Sub

Public Sub OpenODBC()
    Dim cn As New ADODB.Connection, r As New ADODB.Recordset

    On Error GoTo Err_
    cn.CursorLocation = adUseClient
    cn.Provider = "MSDASQL.1"
    cn.Open "Persist Security Info=False;Data Source=dBASE Files;Initial Catalog=""" & App.Path & """"
   
    r.Open "SELECT * FROM RAION ORDER BY [NAME]", cn, adOpenStatic, adLockReadOnly
    Debug.Print
    Debug.Print "--== OpenODBC ==--"
    Do Until r.EOF
        Debug.Print r!Name
        r.MoveNext
    Loop
    Exit Sub

Err_:
    If Err.Number = -2147467259 Then If cn.Errors(0).NativeError = -5026 Then Resume
    MsgBox Err.Description, vbCritical
End Sub

Public Sub SetCodePageDbf(sFile As String, Optional iNewCodePage As Byte = &H26)
    Dim iHFile As Integer, iCP As Byte
   
    iHFile = FreeFile
    Open sFile For Binary Access Read Write Lock Write As #iHFile
    Get #iHFile, 30, iCP
    If iCP <> iNewCodePage Then Put #iHFile, 30, iNewCodePage
    Close #iHFile
End Sub

[Andr222]

НЕеее. Я про примерчик программного изменения 29-го байтика в DBF файле на VB 6.0.
Заинриговал меня Provider = "VFPOLEDB.1", закралась мысль изменить в своей программке ОDBC на OLEDB, но вот не решенная проблема с кодировкой русского текста. ЧТО ДЕЛАТЬ? Или добивать ОDBC, и ловить эту ошибку, или переходить на OLEDB, но проблема с кодировкой!!!
И еще вопрос- Что работает быстрее с DBF -----ОDBC или OLEDB?

[Andrey Fedorov]

НЕеее. Я про примерчик программного изменения 29-го байтика в DBF файле на VB 6.0.

В примере это есть! Смотри внимательней!

И еще вопрос- Что работает быстрее с DBF -----ОDBC или OLEDB?

Не мерил. Но сам по себе ODBC - еще та древность...

[Andr222]

Попробовал и OLEDB и ODBC. И все таки остановился на ODBC, с перехватом данной ошибки, т.к править 29 байт в чужой базе не есть "хорошо", и не известно как на это отреагирует сторонняя программа!
OLEDB приберегу к другому проекту!!!
Выражаю благодарность всем кто поддержал мою тему, в особенности Andrey Fedorov!
Думаю на данный момент тема закрыта!
PS. Хотя если у кого-нибудь возникнут идеи по этому вопросу, пишите. Буду очень признателен!