Doevents своими руками

[arthur2]

Собственно, вопрос к Хакеру:

есть ли альтернатива DoEvents?

PeekMessage->TranslateMessage->DispatchMessage
<...>
DoEvents делает то же самое в числе прочего.

GetMessage->(TranslateMessage)->DispatchMessage
<...>
DoEvents делает то, что я написал + кучу лишнего.

Так как всё-таки правильней: PeekMessage или GetMessage?

[Хакер]

Смотря какая цель.

[arthur2]

Я имею ввиду, как это происходит внутри Doevents? И чего ещё там есть в "куче лишнего" и "числе прочего" - тоже интересно

[Хакер]

Логически, пик, хотя можно сделать и через гет.


В числе прочего всякие COM/RPC-штуки. Ну и Sleep, конечно же.

[arthur2]

Поискал разницу
Через гет не получается - такой дуеэвентс остановит программу, если ничто не происходит. Так что, наверно, всё-таки пик

Кстати, а почему цикл с дуеветсом грузит систему на 100%, а с дуэвентсем + слипом - не грузит, если слип уже есть в дуэвентсе?

всякие COM-штуки

какие, интересно?

RPC - Remote Procedure Call. Удалённый вызов процедур — класс технологий, позволяющих компьютерным программам вызывать функции или процедуры в другом адресном пространстве

А это ещё там зачем?

[Хакер]

Через гет не получается - такой дуеэвентс остановит программу, если ничто не происходит.

Пока не придёт сообщение. Кто тебе сказал, что оно не придёт?

какие, интересно?

Уже не помню.

[arthur2]

Пока не придёт сообщение. Кто тебе сказал, что оно не придёт?

Сам попробовал. Если ничего не двигать и не нажимать, то с гетом код замрёт, а с пиком - естественно - нет, как и с дуэвентсем.

Кстати, а почему цикл с дуеветсом грузит систему на 100%, а с дуэвентсем + слипом - не грузит, если слип уже есть в дуэвентсе?

И ещё - на сколько я понимаю, дуевентс даёт обработаться ВСЕМ сообщениям, успевшим накопиться в очереди. Значит, пик тоже нужно прогнать в цикле, пока в очереди есть сообщения (если есть)? Так?

[Хакер]

Пока не придёт сообщение. Кто тебе сказал, что оно не придёт?

Сам попробовал. Если ничего не двигать и не нажимать, то с гетом код замрёт, а с пиком - естественно - нет, как и с дуэвентсем.

Ты смотришь, но не видишь. Вернее, читаешь, но не можешь уловить посылку.

Ну ладно, раскрою: можно запустить таймер, который сработает через 100 мс и пришёл сообщение и вызвать GetMessage.

И ещё - на сколько я понимаю, дуевентс даёт обработаться ВСЕМ сообщениям, успевшим накопиться в очереди.

Не знаю, всем ли. Наверное всем.

Значит, пик тоже нужно прогнать в цикле, пока в очереди есть сообщения (если есть)? Так?

Кому нужно? Когда и где нужно? Мне, вот, сейчас — так вообще не нужно.

[arthur2]

Кому нужно?

Нужно, чтобы сделать свой дуэвентс

Про гет и таймер как постовщик сообщений я тоже думал (пока не наткнулся на вариант с пиком - так что нужды в гете теперь, вроде, нет)

Пытаюсь сделать так:

Код: Выделить всё

For i = 0 To 1000000
Caption = i
myDoEvents
Next i


Код: Выделить всё

Sub myDoEvents()
    Static MSG As MSG
    PeekMessage MSG, 0&, 0&, 0&, PM_NOREMOVE
    TranslateMessage MSG
    DispatchMessage MSG
End Sub


Заголовок обновляется, но так, как в моём дуэвентсе обрабатывается всего одно сообщение, больше ничего не происходит - и окно не перерисовывается и мышкой его подвинуть не получается
Пробую так:

Код: Выделить всё

Sub myDoEvents()
  Static MSG As MSG
  Do While PeekMessage(MSG, 0&, 0&, 0&, PM_NOREMOVE)
    TranslateMessage MSG
    DispatchMessage MSG
  Loop
End Sub


Получается совсем плохо: паузы в пиках не возникает, видимо, потому что обработка одних сообщений порождает новые.

Решить, на сколько я понимаю, можно так: узнать, сколько сообщений накопилось в очереди, и дать обработаться только им, а вновь поступающие проигнорировать. Вопрос - как?

[0xy]

A чем не устраивает msvbvm60.rtcDoEvents?

[arthur2]

Тем, что так я сам смогу решать, какие эвентс будут ду, а какие не будут ду

[Хакер]

PM_NOREMOVE то зачем?

Вариант с циклом верный, проблему искать нужно где-то ещё.

[arthur2]

PM_NOREMOVE то зачем?

я просто недопонял механизм этоих флагов, нужно было как раз PM_REMOVE

Всё заработало! Спасибо огромное

Код: Выделить всё

Sub myDoEvents()

  Dim MSG As MSG
  Do While PeekMessage(MSG, 0&, 0&, 0&, PM_REMOVE)
    TranslateMessage MSG
    DispatchMessage MSG
  Loop
 
End Sub



А что бы ты посоветовал, чтобы не загружать циклом систему на сто процентов? Вставить-таки в мой дуэевентс sleep 1 ? Или может есть способ покрасивей?

[Хакер]

Ты, вероятно, собираешь вызывать DoEvents в каком-то цикле?

[arthur2]

Мне просто нужен был дуэвентс, который бы не позволял обрабатываться клавишам и мыши, но позволял отрисовываться окнам. Это у меня теперь уже есть.

Ещё мне нужен свой слип, но, опять же, без заморозки отрисовок. Так что хотел сделать как раз через цикл.

Пока такая мысль:

Код: Выделить всё

Sub mySleep(ByVal dwMillisecond As Long)
    Dim idTm As Long, MSG As MSG, start As Long
    Dim endInterval As Long
   
    endInterval = GetTickCount + dwMillisecond 'когда закончить интервал
    idTm = SetTimer(fm.hWnd, 1&, dwMillisecond, 0&) 'генерируем событие на случай, если оно не произойдёт само
    Do
      GetMessage MSG, 0&, 0&, 0& 'получаем все сообщения, если они есть (по истечении интервала событие будет от таймера, на случай, если других не произошло)
      'тут ещё нужны условия, какие из сообщений проигнорировать
      TranslateMessage MSG
      DispatchMessage MSG
   
      If MSG.Time >= endInterval Then Exit Do
    Loop
   
    KillTimer fm.hWnd, idTm
End Sub


Пойдёт?

[Хакер]

В чём смысл обрабатывать отрисовку, но не обрабатывать ввод?

[arthur2]

В чём смысл обрабатывать отрисовку, но не обрабатывать ввод?

Иногда - надо. Ну, например, чтобы визуально показать, что пару секунд ввод невозможен Или вот: viewtopic.php?p=6726243#p6726243

Ты скажи: код mySleep - пойдёт? Есть там грабли?

[Хакер]

От лукавого всё это.

Если не нужно принимать ввод, надо трогать свойство Enabled, а не фильтровать сообщения.

[Денис]

надо трогать свойство Enabled, а не фильтровать сообщения.

[offtop]Падажжи! "Свой" Enabled у него - следующим пунктом идет в его грандиозном плане.[/offtop]

[arthur2]

Если не нужно принимать ввод, надо трогать свойство Enabled, а не фильтровать сообщения.

Ну что ты, честное слово Случаи бывают разные. Если ввод перекрыть на пару минут - тогда да (всегда, кстати, так и делаю), а вот если просто на пару секунд...

Допустим, юзер набирает текст по образцу - бац, ошибка, юзер слышит бряньк, видит, как сгорает один бонус (мультиком) и его отбрасывает на начало слова - всё это он должен внятно разглядеть, и в этот момент не должны ловится удары по клавишам, которые наверняка будут по инерции тарабанить дальше. Раньше я делал это громоздкой системой флагов, теперь - просто своим новым дуэвентом.

И ещё раз на бис: Что ты скажешь за мою неблокирующую mySleep?

[offtop]Падажжи! "Свой" Enabled у него - следующим пунктом идет в его грандиозном плане.[/offtop]

Ага, а третьим пунктом - захват почты и телеграфа и мир во всём мире.

[Денис]

[offtop]Падажжи! "Свой" Enabled у него - следующим пунктом идет в его грандиозном плане.[/offtop]

Ага, а третьим пунктом - захват почты и телеграфа и мир во всём мире.

На самом деле, я неспроста эту фразу написал. Мне припомнилось, что ранее кто-то спрашивал на форуме, как изменить имя класса для формы VB, ему ответили, что невозможно такое, да и ни к чему, при этом показали, как создать в VB на API полностью свое окно, со своим именем класса (отображаемым в диспетчерах задач всевозможных). Такое окно было бы полностью управляемо только на одних оконных сообщениях. Вот это окно я и имел ввиду.

Если изобретатель хороший, и знает, что он делает и чего хочет добиться, то изобретение велосипедов не возбраняется.

[Хакер]

Идея с фильтрацией всё равно плоха. Делай нормально.

[arthur2]

Ты сам предложил заменить дуэвентс на последовательность PeekMessage->DispatchMessage. В чём смысл такой замены, если не использовать те дополнительные возможности, которые она даёт? Только в том, что такой самодельный дуэвентс - быстрее?

Например, при использовании DoEvents может «схаваться» какое-нибудь ненужное событие, например клик по кнопке, и неизвестно, к чем может это привести.

А может ему нужно нажимать на кнопки.

И что? Разве предложенный мною вариант не даёт ему выбор? Разве предложенный тобою — даёт?

И всё-таки - четвёртый раз: каков на предмет наличия граблей этот код: viewtopic.php?p=6740624#p6740624

[Хакер]

Cмысл таков, что у меня в одном проекте DoEvents вешал код на 5 секунд, и этот висяк был явно в COM/RPC-части DoEvents-а.

DoEvents делал то, что мне не требовалось. Делал лишние действия. Это нарушало принцип лени.

В mySleep много граблей.

[arthur2]

В mySleep много граблей.

Ну же???

[Хакер]

Предполагалось, что ты напряжёшь мозги и сам проанализируешь. А я уж поправлю. Не-а?

З.Ы. Ты ЛС вообще читаешь?

[arthur2]

Так ты скажи, идея-то хоть верная?

Ну, я вижу только одну граблю - в момент, когда обнуляется системное время.

А установку таймера, кстати, вообще переделал на отправку в никуда: idTm = SetTimer(0&, 0&, dwMillisecond, 0&)Всё равно сообщение отправляется и гетом отлавливается

DoEvents делал то, что мне не требовалось. Делал лишние действия.

Вот и у меня так: я часто использовал дуэвентс только и исключительно для того, чтобы произошла перерисовка, а он делал лишние действия - обрабатывал случайные клики и нажатия на клавиши, чем сильно сбивал мне все карты. Я выставлял хитрые флаги, чтобы в подобные моменты кипрессы обнулялись, а мышь не обрабатывалась. Добавляя тем самым к лишним действиям самого дуэветса ещё и собственные лишние действия.

З.Ы. Пропустил Сейчас отпишусь

[Хакер]

«Идея-то хоть» как раз неверная. Совсем.

Смысл в своём ML — затормозить выполнение кода, заблокировать его внутри нужной процедуры пока не произойдёт что-то. Заблокировать UI — совсем другая опера, и решается не своим ML, а Disable-ингом.

Ну, я вижу только одну граблю - в момент, когда обнуляется системное время.

Вот такой грабли как раз нет. Чтобы понять это, попытайся объяснить мне природу проблем при обнулении счётчика тиков.

Есть другая проблема со временем: если на момент вызова функции счётчик тиков будет иметь значение из промежутка от (0x7fffffff - SpecifiedDelay; 0x7fffffff], то тебя ждёт Overflow со стороны VB. Если бы это был код на С/С++, произошло бы переполнение, которые не нарушило бы арифметику. Решения: кривое — отключить в настройках оптимизации проверку переполнений, правильное — складывать не VB-шным оператором сложения, а чем-то внешним, например функцией InterlockedExchangeAdd.

Даже если ты сделаешь такую замену, от оператора >= тоже придётся избавиться, ибо он сразу же выкинет тебя из цикла, хотя время ещё не настало.

Другие бывшие грабли: указание идентификатора таймера. При указании идентификатора, если таймер с таким идентификатором уже был, произойдёт замена, вместо добавления. С учётом того, что функция mySleep может быть вызвана из самой себя, это плохо.

Другие бывшие стилевые грабли: использование глобальной переменной со ссылкой на экземпляр формы.

Принципиальные грабли: при обработке какого-то сообщения обработчик породит свой ML, который случайно обработает твоё таймерное событие. Тогда тебе придётся ждать нового таймерного события, но и его может кто-нибудь съесть.

[arthur2]

Смысл в своём ML — затормозить выполнение кода, заблокировать его внутри нужной процедуры пока не произойдёт что-то. Заблокировать UI — совсем другая опера, и решается не своим ML, а Disable-ингом.

Переведи Хотя бы аббревиатуры. А то я даже не очень понял, о чём речь

В остальном - вот проба устранить те грабли, которые понял:

Код: Выделить всё

Sub mySleep(ByVal dwMillisecond As Long)
    Dim idTm As Long, MSG As MSG
    Dim endInterval As Long
    On Error GoTo errH
    endInterval = GetTickCount + dwMillisecond
    On Error GoTo 0
   
'   idTm = SetTimer(0&, 0&, dwMillisecond, AddressOf TimerProc)
    idTm = SetTimer(0&, 0&, dwMillisecond, 0&)
   
    Do
      GetMessage MSG, 0&, 0&, 0&
      TranslateMessage MSG
      DispatchMessage MSG
      If MSG.Time < 0 Then If endInterval >= 0 Then Exit Do
      If MSG.Time >= endInterval Then Exit Do
    Loop
   
    KillTimer 0&, idTm
Exit Sub
errH:
   If Err.Number = 6 Then 'переполнение
     endInterval = &H80000000 + dwMillisecond - (&H7FFFFFFF - GetTickCount)
   End If
   Resume Next
End Sub


[Хакер]

ML — message-loop.
UI — user inteface.
Код оценю завтра.