Маска формата времени.

[$Yastrebov$]

Как получить маску установленного в системе (по региональным стандартам) формата времени? Что-то вроде такого "H:mm:ss".

[$Yastrebov$]

Нашел сам, если кому нужно:

Код: Выделить всё

Private Declare Function GetUserDefaultLCID Lib "kernel32" () As Long

Private Declare Function GetLocaleInfo Lib "kernel32" Alias "GetLocaleInfoA" ( _
  ByVal Locale As Long, _
  ByVal LCType As Long, _
  ByVal lpLCData As String, _
  ByVal cchData As Long) As Long
 
Private Const LOCALE_SSHORTDATE = &H1F      ' Краткий формат даты.
Private Const LOCALE_SLONGDATE = &H20       ' Длинный формат даты
Private Const LOCALE_STIMEFORMAT = &H1003   ' Формат времени.
Private Const LOCALE_SDATE = &H1D           ' Разделитель даты.
Private Const LOCALE_STIME = &H1E           ' Разделитель времени.

Public Sub GetDateTimeSettings()
    Dim str As String * 100
   
    GetLocaleInfo GetUserDefaultLCID, LOCALE_SSHORTDATE, str, 99
    Debug.Print fnTrimNull(str)
   
    GetLocaleInfo GetUserDefaultLCID, LOCALE_SLONGDATE, str, 99
    Debug.Print fnTrimNull(str)
   
    GetLocaleInfo GetUserDefaultLCID, LOCALE_STIMEFORMAT, str, 99
    Debug.Print fnTrimNull(str)
   
    GetLocaleInfo GetUserDefaultLCID, LOCALE_SDATE, str, 99
    Debug.Print fnTrimNull(str)
   
    GetLocaleInfo GetUserDefaultLCID, LOCALE_STIME, str, 99
    Debug.Print fnTrimNull(str)
End Sub

Function fnTrimNull( _
  ByVal strValue As String) As String
    Dim intPos As Integer
   
    intPos = InStr(strValue, vbNullChar)
   
    Select Case intPos
        Case 0
        Case 1
            fnTrimNull = ""
        Case Is > 1
            fnTrimNull = Left(strValue, intPos - 1)
    End Select
End Function

[Saturn.65]

А так что?

Код: Выделить всё

Label1.Caption = Format(Time, "hh:nn:ss")

[$Yastrebov$]

Так получишь формат времени hh:nn:ss, независимо от региональных настроек. И если у человека время "1:03:55 PM", то он должен лицезреть непривычное для него: 13:03:55

[Saturn.65]

И если у человека время "1:03:55 PM", то он должен лицезреть непривычное для него: 13:03:55

Читал про формат Media Time. Который и дает PM.

[Joo]

Код: Выделить всё

Format(Time,"t")