Возможны ли действия над макросом с пом.VBA

[Владимир7]

Возможны ли действия над макросом с помощью VBA например редактирование, переименование или хотя бы удаление?

[dr.MIG]

Добавлять можно, на форуме уже был этот пример:

Код: Выделить всё

obj.VBProject.VBComponents(1).CodeModule.AddFromString "Sub Макрос1" & vbCrLf & "MsgBox ""Hello!""" & vbCrLf & "End Sub" 'где obj -- это Workbook или ActiveDocument

Однако будет сообщение об ошибке.

Кроме того у CodeModule есть метод DeleteLines. Судя по названию он делает то, что требуется.

[Владимир7]

Создать макрос VBA тем же самым VBA получилось с Вашей помощью (сообщения об ошибке не было) - спасибо!
А вот удалить макрос кодом VBA - не идет.
Нашел на форуме упоминаемый Вами пример, может не тот конечно, всё равно - не движется.
Привожу свои попытки решения вопроса:
'ActiveWorkbook.VBProject.CodeModule("Module1").DeleteLines "УдалямыйМакрос"
'ActiveWorkbook.VBProject.CodeModule("Module1").DeleteLines startline:=2, Count:=3
ActiveWorkbook.VBProject.CodeModule("Module1").DeleteLines 1

[Alec]

CodeModule - это не коллекция, вместо CodeModule("Module1") нужно писать VBComponents("Module1").CodeModule.
Для удаления определенного макроса (или процедуры) нужно удалять строки, его содержащие. Эти строки находятся так:

Код: Выделить всё

' начало процедуры
ProcStart = ActiveWorkbook.VBProject.VBComponents("Module1").CodeModule.ProcStartLine "УдалямыйМакрос", vbext_pk_Proc
'количество строк
ProcCount = ActiveWorkbook.VBProject.VBComponents("Module1").CodeModule.ProcCountLines "УдалямыйМакрос", vbext_pk_Proc
'удаляем
ActiveWorkbook.VBProject.VBComponents("Module1").CodeModule.DeleteLines ProcStart, ProcCount


соответственно можно и так

Код: Выделить всё

ProcName = "УдалямыйМакрос"
With ActiveWorkbook.VBProject.VBComponents("Module1").CodeModule
    .DeleteLines .ProcStartLine (ProcName, vbext_pk_Proc),.ProcCountLines (ProcName, vbext_pk_Proc)
End With


Переименование модуля:

Код: Выделить всё

ActiveWorkbook.VBProject.VBComponents("Module1").Name="MySuperModule"


Удаление модуля:

Код: Выделить всё

ActiveWorkbook.VBProject.VBComponents.Remove ActiveWorkbook.VBProject.VBComponents("Module1")


Однако будет сообщение об ошибке.

сообщения об ошибке не было

Сообщение об ошибке возникает, когда отключено "Доверять доступ к Visual Basic Project" (Меню [Сервис] - [Макрос>] - [Безопасность...], закладка "Надежные источники") (эта возможность появилась начиная с Office XP с целью защиты от распространения макровирусов). Возможно у тебя там галочка стоит, или офис старше. Ну в любом случае нужно иметь в ввиду, что по умолчанию доверия нет, поэтому на других компьютерах твой проект скорее всего не заработает без настройки.

[Владимир7]

Большое спасибо за разъяснение! Сайт вообще супер! Вопрос не остался без ответа.
И скорее всего надо последавать приведенной цитате
"Лучше вовремя остановиться...
И начать заново!"
Открываю заново В.Г.Кузменко "Программирование на VBA"

[viter.alex]

Добавлять можно, на форуме уже был этот пример:

Код: Выделить всё

obj.VBProject.VBComponents(1).CodeModule.AddFromString "Sub Макрос1" & vbCrLf & "MsgBox ""Hello!""" & vbCrLf & "End Sub" 'где obj -- это Workbook или ActiveDocument

Однако будет сообщение об ошибке.

Кроме того у CodeModule есть метод DeleteLines. Судя по названию он делает то, что требуется.

В пошаговом режиме это вызывает предупреждение, но работу продолжает.