Двумерный массив

[DRU]

Доброго времени суток!
Возникла следующая проблема: необходимо создать двумерный массив textbox'ов, но я не понимаю как это осуществить. Если это невозможно, то подскажите какой компонент можно использовать и как к нему обращаться.

[iGrok]

Доброго времени суток!
Возникла следующая проблема: необходимо создать двумерный массив textbox'ов, но я не понимаю как это осуществить. Если это невозможно, то подскажите какой компонент можно использовать и как к нему обращаться.

Какой-нибудь Grid.

[DRU]

Доброго времени суток!
Возникла следующая проблема: необходимо создать двумерный массив textbox'ов, но я не понимаю как это осуществить. Если это невозможно, то подскажите какой компонент можно использовать и как к нему обращаться.

Какой-нибудь Grid.

Можно по-подробнее?
Может есть у кого-то примерчик с использованием "Grid"?

[iGrok]

Доброго времени суток!
Возникла следующая проблема: необходимо создать двумерный массив textbox'ов, но я не понимаю как это осуществить. Если это невозможно, то подскажите какой компонент можно использовать и как к нему обращаться.

Какой-нибудь Grid.

Можно по-подробнее?
Может есть у кого-то примерчик с использованием "Grid"?

Грид - это элемент управления. Таблица. Как, к примеру, в Excel. Гриды бывают разные. Многие сделаны для работы с БД(базой данных), некоторые позволяют работать с ними прямо так.
К примеру FlexGrid, DBGrid, DataGrid. Поищи по форуму и в гугле из названия. Информации должно быть достаточно. )

Просто всё рассказывать - это придётся тут такую статью писать...

[Денис]

необходимо создать двумерный массив textbox'ов, и как к нему обращаться.

Мне Хакер подсказал, а я тебе подскажу: Остаток от простого деления дает одну координату, целочисленное деление дает вторую координату. Массив одномерный. Делишь максимальное значение координаты на индекс текущего контрола.

[Alprog]

Если нужно создать именно массив, содержащий контролы, то можно создать двумерный массив TextBox, в котором каждый элемент будет ссылаться на элемент из одномерного массива. Вот так, примерно:

Код: Выделить всё

Option Explicit
Private Const Col As Integer = 7 'Количество столбцов
Private Const Row As Integer = 5 'Количество строк
Dim Arr() As TextBox

Private Sub Form_Load()
    ReDim Arr(Col - 1, Row - 1) As TextBox
   
    Dim n As Integer, m As Integer, Id As Integer
    For n = 0 To Col - 1
    For m = 0 To Row - 1
        Id = n * Row + m
        If Id Then
            Load Text(Id) 'Добавляем контролы на форму. Чтобы код работал, на форме должен лежать text(0)
            With Text(Id)
                .Left = Text(0).Left + Text(0).Width * n
                .Top = Text(0).Top + Text(0).Height * m
                .Visible = True
            End With
            Set Arr(n, m) = Text(Id) 'Делаем ссылку из нашего двухмерного массива к контролу
        End If
    Next
    Next
End Sub

Обращаться к массиву очень просто:
Arr(3, 4).Text = "Тест"

Но можно обойтись и без массива, а завести фунцию, возвращающую TextBox:

Код: Выделить всё

Option Explicit

Private Const Col As Integer = 7
Private Const Row As Integer = 5

Private Sub Form_Load()
    Dim n As Integer, m As Integer, Id As Integer
    For n = 0 To Col - 1
    For m = 0 To Row - 1
        Id = n * Row + m
        If Id Then
            Load Text(Id)
            With Text(Id)
                .Left = Text(0).Left + Text(0).Width * n
                .Top = Text(0).Top + Text(0).Height * m
                .Visible = True
            End With
        End If
    Next
    Next
End Sub

Function Arr(n As Integer, m As Integer) As TextBox
    Set Arr = Text(n * Row + m)
End Function

Обращаться тем не менее, можно точно также:
Arr(3, 4).Text = "Тест"

[DRU]

Огромное спасибо, Alprog!

[DRU]

И ещё вопросик: я взял первый код Alprog за основу, но не могу сделать так, чтобы можно было вводить только числа. Написал так, но это не работает

Код: Выделить всё

With Text(Id)
                .Left = Text(0).Left + Text(0).Width * n
                .Top = Text(0).Top + Text(0).Height * m
                .Visible = True
                .DataFormat.Format = Number
                .MaxLength = 3
 
End With


[ACiD]

Код: Выделить всё

Private Sub Text_KeyPress(Index As Integer, KeyAscii As Integer)
    If (KeyAscii < 48) Or (KeyAscii > 58) Then KeyAscii = 0
End Sub

[Alprog]

сделать так, чтобы можно было вводить только числа

Самый простой способ написал ACiD, но это не спасёт, если пользователь вставит текст через Ctrl+V.
Если же хочется защитится и от Ctrl+V, то легче всего при изменении содержимого, проверять является ли оно числом, и если нет, то очищать окошко.
Вот так:

Код: Выделить всё

Private Sub Text_Change(Index As Integer)
    On Local Error GoTo err:
    Dim I As Integer
    I = Text(Index)
    Exit Sub
err:
    Text(Index) = ""
End Sub

Чуть более продвинутый способ. Здесь место очищения окошка делается откат к старому значению:

Код: Выделить всё

Private Sub Text_Change(Index As Integer)
    On Local Error GoTo err:
    With Text(Index)
        If .Text <> "" And .Text <> "-" Then
            Dim I As Integer
            I = .Text
        End If
        .Tag = .Text
        Exit Sub
err:
        .Text = .Tag
        .SelStart = Len(.Text)
    End With
End Sub

Private Sub Text_LostFocus(Index As Integer)
    If Text(Index) = "-" Then Text(Index) = -1
End Sub

Во втором варианте можно вводить даже отрицательные числа. Причём если оставить в поле только минус, то он автоматически поменяется на -1.

[Alprog]

DRU

Предчувствую твой следущий вопрос: "Как переключаться между TextBox'ами с помощью клавиатуры?"

На всякий случай отвечу сразу:

Код: Выделить всё

Private Sub Text_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)
    With Text(Index)
        Select Case KeyCode
            Case vbKeyDown
                If Index < Row * Col - 1 Then
                    Text(Index + 1).SetFocus
                    Text(Index + 1).SelStart = 0
                End If
            Case vbKeyUp
                If Index Then
                    Text(Index - 1).SetFocus
                    Text(Index - 1).SelStart = 0
                End If
            Case vbKeyRight
                If Index + Row < Col * Row And .SelStart = Len(.Text) Then
                    Text(Index + Row).SetFocus
                    Text(Index + Row).SelStart = 0
                End If
            Case vbKeyLeft
                If Index >= Row And .SelStart = 0 Then
                    Text(Index - Row).SetFocus
                    Text(Index - Row).SelStart = Len(Text(Index - Row))
                End If
        End Select
    End With
End Sub

[iGrok]

Мда.
А мысль о том, что использовать нормальный грид с возможностью задания формата данных в ячейке будет проще и удобнее, никому в голову, похоже, так и не пришла..

[DRU]

Код: Выделить всё

Private Sub Text_KeyPress(Index As Integer, KeyAscii As Integer)
    If (KeyAscii < 48) Or (KeyAscii > 58) Then KeyAscii = 0
End Sub

Про Ascii я знаю , но я не могу понять почему не работает dataformat? Или я что-то не правильно понял (он вообще для чего предназначен?))). Я как-то писал прогу, где мне надо было также вводить в текстбокс числа и только числа, после всего написанного я засомневался конечно, но с уверенстью в 40% могу сказать что у меня все работало. Стукните меня молотком если dataformat - это вообще не туда.
====================================================================
Спасибо за многочисленные отзывы, думаю что по этому вопросу больше вас напрягать не буду. Напишу через ascii и курсач готов)))

[DRU]

DRU

Предчувствую твой следущий вопрос: "Как переключаться между TextBox'ами с помощью клавиатуры?"

На всякий случай отвечу сразу:

Код: Выделить всё

Private Sub Text_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)
    With Text(Index)
        Select Case KeyCode
            Case vbKeyDown
                If Index < Row * Col - 1 Then
                    Text(Index + 1).SetFocus
                    Text(Index + 1).SelStart = 0
                End If
            Case vbKeyUp
                If Index Then
                    Text(Index - 1).SetFocus
                    Text(Index - 1).SelStart = 0
                End If
            Case vbKeyRight
                If Index + Row < Col * Row And .SelStart = Len(.Text) Then
                    Text(Index + Row).SetFocus
                    Text(Index + Row).SelStart = 0
                End If
            Case vbKeyLeft
                If Index >= Row And .SelStart = 0 Then
                    Text(Index - Row).SetFocus
                    Text(Index - Row).SelStart = Len(Text(Index - Row))
                End If
        End Select
    End With
End Sub

Я думаю что мне достаточно будет использовать Tab, но за пример все-равно спасибо

[iGrok]

Стукните меня молотком если dataformat - это вообще не туда.

Молотком не буду, но в общем да. Не туда.
Если я не особо ошибаюсь - этот DataFormat используется при работе с БД. Задаёт формат отображения данных.