Бестелесное окно

[Neo_]

Подскажите, пожалуйста, возможно ли как-нибудь сделать так, чтоб при нажатии на форму, это нажатие воспринимало окно, находящееся под данным, т.е. окно... Как бы протыкалось насквозь! =) И как это реализовать на VB6 или VB.NET?

[keks-n]

Перечсислить все окна, найти все, в которых находится эта точка, после чего выбрать самое верхнее. Далее, необходимо через координаты верхнего угла найти относительные координаты. после чего перечисляем дочерние окна на предмет совпадения, если надо рекурсивно, и отправляем через SendMessage свой клик

[Neo_]

Спасибо! =)

[Хакер]

Во-первых, tag_warning.
Во-вторых, я помню, что есть стиль, установка которого окну придаёт ему подобное поведение. Как назло, забыл, что за стиль.

[burik]

Хакер, а можешь это где-нибудь посмотреть? Я такого нигде не нахожу. В Appleman'е вроде множество стилей есть, но я такого не нашел..

[Atoman]

Поковырявшись немного в стилях вот что получилось.

Код: Выделить всё

Option Explicit

Private Declare Function SetWindowLong Lib "user32.dll" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32.dll" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32.dll" (ByVal hwnd As Long, ByVal crKey As Long, ByVal bAlpha As Byte, ByVal dwFlags As Long) As Long
Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const GWL_EXSTYLE As Long = -20
Private Const WS_EX_LAYERED As Long = &H80000
Private Const WS_EX_TRANSPARENT As Long = &H20&
Private Const LWA_ALPHA As Long = &H2
Private Const HWND_TOPMOST As Long = -1
Private Const SWP_NOMOVE As Long = &H2
Private Const SWP_NOSIZE As Long = &H1

Private Sub Form_Load()
Dim ExStyle As Long
    ExStyle = GetWindowLong(Me.hwnd, GWL_EXSTYLE) Or WS_EX_LAYERED Or WS_EX_TRANSPARENT
    Call SetWindowLong(Me.hwnd, GWL_EXSTYLE, ExStyle)
    Call SetLayeredWindowAttributes(Me.hwnd, 0, 120, LWA_ALPHA)
    Call SetWindowPos(Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE)
End Sub

[Хакер]

Ага. Оно самое.

Кстати, про него (WS_EX_TRANSPARENT) ещё в теме о часах писали.

[Neo_]

Спасибо, жалко, в .NET это не работает...

[Atoman]

Как не работает?
Замени в АПИ объявлении тип Long на Integer,
а в коде Me.hWnd на Me.Handle

-----------------------------------------------------------

Код: Выделить всё

Private Declare Function SetWindowLong Lib "user32.dll" Alias "SetWindowLongA" (ByVal hWnd As IntPtr, ByVal nIndex As Integer, ByVal dwNewLong As Integer) As Integer

[Neo_]

УРААА!!!!!!!!!!
Все работает!!! Спасибо большое! =)
Просто сначала, когда я объявлял функции, при попытке их использования вылезала ошибка разбалансировки стека, видимо это все из-за несоответствия типов данных...

[Хакер]

Это из-за того, что Integer имеет разный размер (2 / 4) в VB / VB.NET

[Twister]

Neo_
http://www.wasm.ru/forum/viewtopic.php?id=19576

[Neo_]

Да, спасибо! Это, в принципе, тоже самое, что написал Atoman... =)