Считывание струкруры IO_COUNTERS

[M.A.R.K]

Привет всем.

Код: Выделить всё

Private Declare Function GetProcessIoCounters Lib "kernel32.dll" (ByVal hProcess As Long, IoCounters As Any) As Long
Private Declare Function GetCurrentProcess Lib "kernel32.dll" () As Long
Private Type IO_COUNTERS
    ReadOperationCount As Long
    WriteOperationCount As Long
    OtherOperationCount As Long
    ReadTransferCount As Long
    WriteTransferCount As Long
    OtherTransferCount As Long
End Type
Dim IO_C As IO_COUNTERS
Private Sub Command1_Click()
Call GetProcessIoCounters(GetCurrentProcess(), ByVal VarPtr(IO_C))
MsgBox (IO_C.ReadOperationCount)
End Sub

MsgBox показывает количество операций считывания у текущего процесса, после чего VB вылетает...
Спецы, подскажите что я забыл, что не учел?
Заранее благодарен.

[alibek]

Во-первых, просто IO_C, без ByVal VarPtr. Либо в декларации укажи ByVal As Long.
Во-вторых, у меня есть подозрение, что ULONGLONG -- это не dword, а qword, используй Currency и умножай на 10000.
И в третьих, если с предыдущими двумя замечаниями я прав, то прекрати злоупотреблять данным разделом.

[M.A.R.K]

1) alibek, "...прекрати злоупотреблять данным разделом..." Возможно ты прав...
Но у меня есть вопрос про привилегии у процесса, я надеюсь это можно задать в этом разделе?
2) Мой код должен иметь, примерно такой вид:

Код: Выделить всё

Private Declare Function GetProcessIoCounters Lib "kernel32.dll" (ByVal hProcess As Long, IoCounters As Long) As Long
Private Declare Function GetCurrentProcess Lib "kernel32.dll" () As Long
Private Type IO_COUNTERS
    ReadOperationCount As Long
    WriteOperationCount As Long
    OtherOperationCount As Long
    ReadTransferCount As Long
    WriteTransferCount As Long
    OtherTransferCount As Long
End Type
Dim IO_C As IO_COUNTERS
Private Sub Command1_Click()
Call GetProcessIoCounters(GetCurrentProcess(), byval VarPtr(IO_C))
MsgBox (IO_C.ReadOperationCount)
End Sub

3) Скажи, пожалуйста, что именно и где я должен исправить по твоему 2-рому замечанию "Во-вторых, у меня есть подозрение, что ULONGLONG -- это не dword, а qword, используй Currency и умножай на 10000"

[Viper]

Должно быть:

Код: Выделить всё

Private Type IO_COUNTERS
    ReadOperationCount As Currency
    WriteOperationCount As Currency
    OtherOperationCount As Currency
    ReadTransferCount As Currency
    WriteTransferCount As Currency
    OtherTransferCount As Currency
End Type

[alibek]

Код: Выделить всё

Private Declare Function GetProcessIoCounters Lib "kernel32.dll" (ByVal hProcess As Long, IoCounters As Any) As Long
Private Declare Function GetCurrentProcess Lib "kernel32.dll" () As Long
Private Type IO_COUNTERS
    ReadOperationCount As Currency
    WriteOperationCount As Currency
    OtherOperationCount As Currency
    ReadTransferCount As Currency
    WriteTransferCount As Currency
    OtherTransferCount As Currency
End Type
Dim IO_C As IO_COUNTERS
Private Sub Command1_Click()
Call GetProcessIoCounters(GetCurrentProcess(), IO_C)
MsgBox (IO_C.ReadOperationCount*10000)
End Sub

[M.A.R.K]

alibek,Viper, большое спасибо за помощь...
Все работает.