В FSO маска выбора файлов есть ? или нет ?

[Edward]

целый день мучаюсь понять не могу.
Используя оператора Dir можно использовать маску для выбора определенных файлов.
А в FSO что то не могу найти как это сделать.
в архиве сообщений что то не нашел как это сделать.
на яндексе тоже.
Подскажите кто знает.
Спасибо.
С уважением.
Эдуард.

[Sebas]

нет такого, перебирай коллекция с оператором LIKE

[Firestorm]

поконкретней опиши свою проблему и суть действий...
может чем-нить поможет обычный файллистбокс со свей маской?

[Edward]

Я хочу выбирать из папки только определенные файлы, например , только txt или htm, или exe.
Просто мне нужно еще отслеживать разные атрибуты файла.
поэтому хочу использовать FSO.
То есть хочу выбирать строго определнные файлы .
Например:
sFile = Dir$("D:\Dannye\*.txt") будут отобраны только файлы txt , а как это сделать в FSO ?

А с помощью Like сравнивать на значение , это же же.е.е.е.е.
Спасибо.
С уважением.
Эдуард.

[RayShade]

Ну так примерно:

mask = "*.txt"

Set folder = fso.getfolder(path)

for each file in folder.files

if file.name like mask then list1.additem file.name

next file

[Edward]

Ну так примерно:
mask = "*.txt"
Set folder = fso.getfolder(path)
for each file in folder.files
if file.name like mask then list1.additem file.name
next file

Спасибо RayShade !!! , ты настоящий друг ))))
Попробую.
О результатах постараюсь сообщить.
Удачи.
С уважением .
Эдуард.

[aaf]

Ну так примерно:
mask = "*.txt"
Set folder = fso.getfolder(path)
for each file in folder.files
if file.name like mask then list1.additem file.name
next file

Чей то я до сегодня like только в SQL встречал. Чем Instr то перестал устраивать общественность? Может быстрее работает? Или еще чего?

[GSerg]

Чей то я до сегодня like только в SQL встречал. Чем Instr то перестал устраивать общественность? Может быстрее работает? Или еще чего?

Чел! Like находит кучу вещей при помощи мощных шаблонов подстановки, а Instr находит только то, что написали. Работают они быстро оба, Like медленнее, но круче.

[Emzari]

Можно использоват оператор Right
например так дапустим в строковой переменной strFileName хранится имя фаила

IF Right(strFileName, 3) = "txt" Then
подходит
Else
не подходит
End If

Можно организоват цикл и все.

[Edward]

БОЛЬШОЕ человеческое спасибо всем.
сделал по следующему :
через Dir нахожу нужные файлы
их названия заношу в массив.
а потом зная названия файлов использую FSO для работы с их атрибутами.

Удачи всем.

[-=Jaga=-]

Вот и мне помогло:).
Самое интересное что FSO легко удаляет файлы по маске, но fso.FileExists ничего по маске не находит. Не совсем хорошо (ИМХО) .

[kibernetics]

всё-таки вместо FSO лучше юзать АПИ.
там и маску можно задавать в виде (*) и (?)
например, *.ht* вернёт файлы как
*.htm, так и *.html
а, *.ht? вернёт только
*.htm

[-=Jaga=-]

А пример с объявлением API и кодом не приведете?

[kibernetics]

-=Jaga=- держи

Код: Выделить всё

Option Explicit
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Copyright ©1996-2006 VBnet, Randy Birch, All Rights Reserved.
' Some pages may also contain other copyrights by the author.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Distribution: You can freely use this code in your own
'               applications, but you may not reproduce
'               or publish this code on any web site,
'               online service, or distribute as source
'               on any media without express permission.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Const vbDot = 46
Private Const MAX_PATH As Long = 260
Private Const INVALID_HANDLE_VALUE = -1
Private Const vbBackslash = ""
Private Const ALL_FILES = "*.*"

Private Type FILETIME
   dwLowDateTime As Long
   dwHighDateTime As Long
End Type

Private Type WIN32_FIND_DATA
   dwFileAttributes As Long
   ftCreationTime As FILETIME
   ftLastAccessTime As FILETIME
   ftLastWriteTime As FILETIME
   nFileSizeHigh As Long
   nFileSizeLow As Long
   dwReserved0 As Long
   dwReserved1 As Long
   cFileName As String * MAX_PATH
   cAlternate As String * 14
End Type

Private Type FILE_PARAMS
   bRecurse As Boolean
   bFindOrExclude As Long  '1=find matching, 0=exclude matching
   nCount As Long
   nSearched As Long
   sFileNameExt As String
   sFileRoot As String
End Type

Private Declare Function FindClose Lib "kernel32" _
  (ByVal hFindFile As Long) As Long
   
Private Declare Function FindFirstFile Lib "kernel32" _
   Alias "FindFirstFileA" _
  (ByVal lpFileName As String, _
   lpFindFileData As WIN32_FIND_DATA) As Long
   
Private Declare Function FindNextFile Lib "kernel32" _
   Alias "FindNextFileA" _
  (ByVal hFindFile As Long, _
   lpFindFileData As WIN32_FIND_DATA) As Long

Private Declare Function GetTickCount Lib "kernel32" () As Long

Private Declare Function lstrlen Lib "kernel32" _
    Alias "lstrlenW" (ByVal lpString As Long) As Long

Private Declare Function PathMatchSpec Lib "shlwapi" _
   Alias "PathMatchSpecW" _
  (ByVal pszFileParam As Long, _
   ByVal pszSpec As Long) As Long

Private FP As FILE_PARAMS  'holds search parameters


Private Sub Form_Load()

   Text1.Text = "c:"
   Text2.Text = "*.doc; *.xls; *.ppt"
   Option1(0).Value = True
   Command1.Caption = "Begin Search"

End Sub


Private Sub Command1_Click()

   Dim tstart As Single   'timer var for this routine only
   Dim tend As Single     'timer var for this routine only
   
   Text3.Text = ""
   Text4.Text = ""
   Text5.Text = ""
   List1.Clear
   List1.Visible = False
   
   With FP
      .sFileRoot = QualifyPath(Text1.Text) 'start path
      .sFileNameExt = Text2.Text           'file type(s) of interest
      .bRecurse = Check1.Value = 1         'True = recursive search
      .nCount = 0                          'results
      .nSearched = 0                       'results
      .bFindOrExclude = IIf(Option1(0).Value = True, 1, 0) '0=include, 1=exclude
   End With
 
   tstart = GetTickCount()
   Call SearchForFiles(FP.sFileRoot)
   tend = GetTickCount()
   
   List1.Visible = True
   Text3.Text = Format$(FP.nSearched, "###,###,###,##0")
   Text4.Text = Format$(FP.nCount, "###,###,###,##0")
   Text5.Text = FormatNumber((tend - tstart) / 1000, 2) & "  seconds"
                                   
End Sub


Private Sub SearchForFiles(sRoot As String)

   Dim WFD As WIN32_FIND_DATA
   Dim hFile As Long
 
   hFile = FindFirstFile(sRoot & ALL_FILES, WFD)
 
   If hFile <> INVALID_HANDLE_VALUE Then
   
      Do
                 
        'if a folder, and recurse specified, call
        'method again
         If (WFD.dwFileAttributes And vbDirectory) Then
            If Asc(WFD.cFileName) <> vbDot Then

             If FP.bRecurse Then
                  SearchForFiles sRoot & TrimNull(WFD.cFileName) & vbBackslash
               End If
            End If
           
         Else
         
           'must be a file..
            If MatchSpec(WFD.cFileName, FP.sFileNameExt) Then
               FP.nCount = FP.nCount + 1
               List1.AddItem sRoot & TrimNull(WFD.cFileName)
            End If  'If MatchSpec
     
         End If 'If WFD.dwFileAttributes
     
         FP.nSearched = FP.nSearched + 1
     
      Loop While FindNextFile(hFile, WFD)
   
   End If 'If hFile
 
   Call FindClose(hFile)

End Sub


Private Function QualifyPath(spath As String) As String

   If Right$(spath, 1) <> vbBackslash Then
      QualifyPath = spath & vbBackslash
   Else
      QualifyPath = spath
   End If
     
End Function


Private Function TrimNull(startstr As String) As String

   TrimNull = Left$(startstr, lstrlen(StrPtr(startstr)))
   
End Function


Private Function MatchSpec(sFile As String, sSpec As String) As Boolean

   MatchSpec = PathMatchSpec(StrPtr(sFile), StrPtr(sSpec)) = FP.bFindOrExclude
   
End Function

кидай в код формы.
на форму не забудь кинуть:
ListBox(List1), 5 TextBox'oв(Text1-Text5), 2 OptionButton(Option1) и ChecBox(Check1) он определяет искать ли файлы в поддиректориях....

[-=Jaga=-]

Огромное спасибо!

[Cytron]

Я не совсем понял, чем автора темы не устраивают GetAttr и SetAttr?