PrintDlg проблема с PD_ENABLESETUPHOOK

[Golart]

Решил задействовать диалог PrintSetup без CommonDialog. При установке флагов в структуре PrintDlg PD_PRINTSETUP+PD_ENABLESETUPHOOK и передаче адреса hook-процедуры VB IDE падает. Посмотрел аналогичный код в VCL Delphi (компонент PrintSetupDialog) - там при таком сочетании флагов все работает. В моей hook-функции - код центрирования диалога на экране. Диалоги цвета, шрифта с такими же hook'ами работают нормально.

ЧТО ДЕЛАТЬ?Я идиот! Убейте меня, кто-нибудь!Я идиот! Убейте меня, кто-нибудь!Я идиот! Убейте меня, кто-нибудь!Я идиот! Убейте меня, кто-нибудь!Я идиот! Убейте меня, кто-нибудь!???

[alibek]

А как центруешь?
Через API или методами VB?

[Golart]

Через API

GetSystemMetrics(X) 'ширина экрана
GetSystemMeyrics(Y)'высота экрана

GetWindowRect 'положение диалога на экране
'Вычисляю положение окна
MoveWindow

Все это происходит по WM_INITDIALOG

[Viper]

Больше кода давай + вопрос, а в откомпилированном виде тож падает?

З.Ы. Хук для стандартных диалогов штука коварная, там есть камушки подводные

[Golart]

В откомпилированном тоже падает - еще быстрее

Только что конвертнул на Delphi - все работает

Код: Выделить всё

Public Function ShowPrinter(ByVal hWnd As Long) As Long
Dim PrintDialog As PrintDlg   

With PrintDialog
    .hwndOwner = hWnd
    .lStructSize = Len(PrintDialog)
    .flags = PD_PRINTSETUP + PD_ENABLESETUPHOOK
    .lpfnSetupHook = GetProc(AddressOf DialogHook)
End With

ShowPrinter = PrintDlg(PrintDialog)
End Function

Private Function DialogHook(ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Select Case Msg
  Case WM_INITDIALOG
    CenterDialog hWnd
  Case Else
End Select
End Function

Private Sub CenterDialog(ByVal hWnd As Long)
Dim screenWidth As Long, screenHeight As Long
Dim dialogLeft As Long, dialogTop As Long
Dim dialogWidth As Long, dialogHeight As Long
Dim R As RECT

screenWidth = GetSystemMetrics(SM_CXSCREEN)
screenHeight = GetSystemMetrics(SM_CYSCREEN)

GetWindowRect hWnd, R

dialogHeight = R.Bottom - R.Top
dialogWidth = R.Right - R.Left

dialogLeft = (screenWidth - dialogWidth) / 2
dialogTop = (screenHeight - dialogHeight) / 3

MoveWindow hWnd, dialogLeft, dialogTop, dialogWidth, dialogHeight, Abs(True)
End Sub

Private Function GetProc(lProc As Long) As Long
  GetProc = lProc
End Function

[alibek]

А почему процедура ничего не возвращает?
Кроме того, WM_INITDIALOG передается в диалоговое окно до того, как будет вызвана хук-процедура.
Попробуй указать DialogHook=-1 после центровки.

[Viper]

1. как объявлял структуру и функцию?
2. без хука падает или как?

[Golart]

Вот структурка и функция

Код: Выделить всё

Private Type PRINTDLG
        lStructSize As Long
        hwndOwner As Long
        hDevMode As Long
        hDevNames As Long
        hdc As Long
        flags As Long
        nFromPage As Integer
        nToPage As Integer
        nMinPage As Integer
        nMaxPage As Integer
        nCopies As Integer
        hInstance As Long
        lCustData As Long
        lpfnPrintHook As Long
        lpfnSetupHook As Long
        lpPrintTemplateName As String
        lpSetupTemplateName As String
        hPrintTemplate As Long
        hSetupTemplate As Long
End Type

Private Declare Function PRINTDLG Lib "comdlg32.dll" Alias "PrintDlgA" (pPrintdlg As PRINTDLG) As Long

1.если поставить -1 то все равно падает
2.без хука (без флагов) - все отлично, диалог загружается

[alibek]

WM_INITDLG, в отличии от всех остальных сообщений, поступает вначале в диалог, а только после этого в хук-процедуру. Возможно дело в этом. Попробуй сабклассить окно диалога и центровать в нем.

[Golart]

я сделал так:

Код: Выделить всё

Public Function ShowPrinter(ByVal hwnd As Long) As Long
   
    PrintDialog.hwndOwner = hwnd
    PrintDialog.lStructSize = Len(PrintDialog)
    'если раскомментировать эту строку то отобразится другое окно печати
    'PrintDialog.flags = PD_ENABLESETUPHOOK
    hHook = SetWindowsHookEx(WH_CBT, AddressOf CenterDialog, App.hInstance, App.ThreadID)
         
    ShowPrinter = PrintDlg(PrintDialog)
End Function

Private Function CenterDialog(ByVal lMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim R As RECT
Dim cx As Integer, cy As Integer
Dim dtop As Integer, dleft As Integer, dwidth As Integer, dheight As Integer
CenterDialog = 0
If lMsg = HCBT_ACTIVATE Then
    cx = GetSystemMetrics(SM_CXSCREEN)
    cy = GetSystemMetrics(SM_CYSCREEN)
    GetWindowRect wParam, R

    dwidth = R.Right - R.Left
    dheight = R.Bottom - R.Top

    dtop = (cy - dheight) / 3
    dleft = (cx - dwidth) / 2

    MoveWindow wParam, dleft, dtop, dwidth, dheight, Abs(True)
    UnhookWindowsHookEx hHook
    CenterDialog = -1
  End If
End Function

и все работает
З.Ы. в дельфях работают оба варианта

[Golart]

Если кто-нить знает еще какие-нибудь варианты, намекните, не стесняйтесь...