Получение значений из модального окна

[BasiС]

Доброго времени суток, уважаемые All!

Подскажите плиз, если кто сталкивался с такой проблемой.

Суть: Вызывается модальная форма, в ней юзером заполняются поля. Затем, форма закрываются и эти значения должны попасть в процедуру которая собственно и вызвала эту форму. Возможно ли это сделать не плодя глобальные переменные?

Пробовал так:

Код: Выделить всё

Load frmRecEdit
With frmRecEdit
    .Show vbModal, Me
    MsgBox .txtEdit(0).Text
End With

Но возвращается значение, которое было присвоено txtEdit(0) при загрузке формы.

[Хакер]

Да, не выгружать форму, а делать Me.Hide.

В процедуре - получать значения, а уже потом делать Unload frmRecEdit

[BasiС]

Не поверишь! получилось =)

А я целый день голову ломаю...


Спасибо!

[Хакер]

Ну почему-же не поверю? Я так на протяжении многих лет делаю, и получается, однако.

Ну забудь про события QueryUnload. Ибо если юзер закроет окно, то она всё же будет Unload-ed. Смотри UnloadMode и делай Cancel если нужно.

[BasiС]

На будущее, может кому понадобится...

Для того, чтобы узнать, загружена форма или нет, можно это проверить функцией:

Код: Выделить всё

Public Function IsFormaObject(frmstr As String) As Boolean
'Проверка - загружена форма или нет
Dim x As Integer
For x = 0 To Forms.count - 1
    If Forms(x).name = frmstr Then
        IsFormaObject = True
        Exit Function
    End If
Next
IsFormaObject = False
End Function

Спасибо EUGY http://bbs.vbstreets.ru/viewtopic.php?t ... 6%E5%ED%E0

Мой код принял законченный вид:

Код: Выделить всё

Load frmRecEdit
With frmRecEdit
    .Show vbModal
    If Not IsFormaObject("frmRecEdit") Then Exit Sub
    MsgBox .txtEdit(0).Text
End With
Unload frmRecEdit

[Antonariy]

Код: Выделить всё

r = frmRecEdit.CreateForm

'форма
Dim lCancel As Boolean

Public Function CreateForm() As String
    lCancel = False
    Show 1
    If Not lCancel Then CreateForm = txtEdit(0).Text
    Unload Me
End Function

Private Sub cmdCancel_Click()
    lCancel = True
    Hide
End Sub

Private Sub cmdOk_Click()
    Hide
End Sub

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    lCancel = UnloadMode = 0
End Sub

[keks-n]

Лично я получение данных из модальных окон организую так:
Есть у формы метод типа Run или ещё чего. Он ByRef последовательно или структурой получает параметры, которые форма должна изменять.
Оттуда вызывается Me.Show vbModal. После того как форма отработала и управление вернулось, просто копирую данные в переданные параметрами.

[GSerg]

Странные вы...

Форма, которая unloaded - она прекрасно существует и в ней доступны все её переменные и свойства... ни разу в жизни не использовал Hide...

frmMain

Код: Выделить всё

Option Explicit

Private Sub cmdShowDialog_Click()
  Dim f As frmDialog
 
  Set f = New frmDialog
  f.Show vbModal
 
  MsgBox f.UserSelectedValue
End Sub

frmDialog

Код: Выделить всё

Option Explicit

Private mUserSelectedValue As String

Public Property Get UserSelectedValue() As String
  UserSelectedValue = mUserSelectedValue
End Property

Private Sub cmdOK_Click()
  Unload Me
End Sub

Private Sub Form_Unload(Cancel As Integer)
  mUserSelectedValue = Text1.Text
End Sub

[Хакер]

Дело в том, что иногда требуется валидация введённых значений. Причём валидация делается после опроса, и в коде формы она не возможна. Если использовать Хайд, то в вызывающей процедуре, можно после выполнения валидации, в случае возникновения ошибки во введённых данных, показать соотв. мессаг и вернуть пользователя в исходное состояие (Show форму). Причём форма покажется в том же самом состоянии, в котором она была до того как пользователь её закрыл.

А если её unload-ить, то значения полей придётся восстанавливать заново.

[Sergeant Pepper]

Можно использовать WithEvents и в вызывающей форме обрабатывать события открытой модально формы.

[Хакер]

[cuted, из-за неактуальности]
Это насчёт формулировки.

А на счёт идеи - да, можно, но только если модальная форма вызывается из формы. А если из кода?

[Sergeant Pepper]

А на счёт идеи - да, можно, но только если модальная форма вызывается из формы. А если из кода?

Ну не только же из формы, можно из модуля класса.
Открытие формы из стандарного модуля почему-то неактуальный вариант для меня.

[Хакер]

А я всегда делаю это именно из функии, обяъявленной в модуле.