Конвертация из HEX

[Greis]

Часть строки
01000000 EABEFEFF 71BE0300 80F1FFFF
Как её преобразовать в такой вид?
1 -82198 245361 -3712

[GSerg]

Ты точно уверен, что это именно строка?

[Greis]

Да на 100%. Только уверенА
EABEFEFF = -82198 (32bit Signed Long)
EABEFEFF = 4294885098 (32bit Unsigned Long)

[GSerg]

Просто странно, что такое в виде строки. Такое обычно не бывает в виде строки, а если бывает, то это ручки

Код: Выделить всё

Option Explicit

Private Sub Form_Load()
  MsgBox ntohl("01000000")
  MsgBox ntohl("EABEFEFF")
  MsgBox ntohl("71BE0300")
  MsgBox ntohl("80F1FFFF")
End Sub

Private Function ntohl(s As String) As Long
  Dim t As Long
 
  t = CLng("&h" & s)
  ntohl = t And &HFF&
  If ntohl And &H80& Then ntohl = ((ntohl And &H7F&) * &H1000000) Or &H80000000 Else ntohl = ntohl * &H1000000
  ntohl = ntohl Or (((t And &HFF000000) \ &H1000000) And &HFF&) Or ((t And &HFF0000) \ &H100&) Or ((t And &HFF00&) * &H100&)
End Function

[Greis]

Спасибо.

Просто странно, что такое в виде строки. Такое обычно не бывает в виде строки, а если бывает, то это ручки

Да и ножки тоже Мы человеки малограмотные...вот и бродим по форумам в поисках подаяния.
Требовалось прочитать файл .bin по 4 байта и преобразовать его в подобие тех строк, что я написала. Изменить и обратно. Вот и выдернула от туда строчку. Потому как 2 дня поисков и чтений были безрезультатными. Даже непредставляла как эти числа получить. Самое интересное, после создания темы теоритически вопрос решила. 4294885098 из EABEFEFF - получила.
И появился вопрос: Нет ли функции конвертации из (single)4294885098 в (long)-82198 ?(если я правильно поняла их тип)
P.S. За пример ещё раз спасибо. Хочется уже побольше понять...раз уж тема создана. Циферь незнакомых много...пошла изучать

[FaKk2]

Greis
Он имел ввиду хендлы. В системе у всех обьектов (окон например) есть идентификационный номер. Например 150E56h или 1379926d

[Greis]

Greis
Он имел ввиду хендлы. В системе у всех обьектов (окон например) есть идентификационный номер. Например 150E56h или 1379926d

Вот только ненадо меня путать. Я и так мало понимаю. Для чего мне процессы?
Мне просто требуется прочитать файл, изменить и записать обратно. Да и с чтением разберусь. Интересует только перевод из в и обратно.

[GSerg]

Требовалось прочитать файл .bin по 4 байта и преобразовать его в подобие тех строк, что я написала. Изменить и обратно.

Вот именно.
По 4 байта. А не по 16+4, как в каждой из этих строк.
Почему после чтения бинарного файла образуется строка? Потому что содержимое файла было узрето в некоем hex-редакторе? Там оно, разумеется, от младшего байта к старшему. Так и должно быть. И берётся это одной командой get без всяких преобразований.

[Greis]

Почему после чтения бинарного файла образуется строка? Потому что содержимое файла было узрето в некоем hex-редакторе?

Потому, что я её даже не пыталась читать Мы как "умные" люди решили сразу с середины и неправильно (открыли в редакторе и решили получить то , что нужно). Честно говоря не думала, что так просто, но всё-равно есть проблемка. Формат файла.

Код: Выделить всё

4байта - количество блоков в файле(только один раз в начале)
====сам блок======
4байта     - кол-во символов в имени (n)
n*2байта - имя блока в юникод
4байта     - всегда 0
4байта     - кол-во координат (дальше сами координаты)
4байта     - индекс координаты(с 0 и до...уникальны по всему файлу)
4байта     - x
4байта     - y
4байта     - z
дальше повторяются координаты(всё по 4 байта) и по окончании сразу идёт второй блок.

Как его корректно прочитать - незнаю. Первое имя то я прочитаю, а дальше...блоки разные..имена разные...разделителей - невижу(после имени идёт 0...так некоторые координаты тоже 0) как и я тоже

[GSerg]

Почему такая мысль, как "Открыть документацию и прочитать её", в голову людям не приходит?
Количество подсказок ограничено. По их окончании будут только пинки в направлении мануалов.

Код: Выделить всё

private type Coord
  Index as long
  x as long
  y as long
  z as long
end type

private type Block
  Name as string
  Stuff as long
  CoordCount as long
  Coords() as Coord
end type

private type FileContent
  BlockCount as long
  Blocks() as Block
end type

private sub addsfs()
  dim fc as filecontent, fn as integer, i as long, t as long
 
  fn=freefile
  open "c:\1.dat" for binary access read as #fn
  get #fn,,fc.blockcount
  redim fc.blocks(1 to fc.blockcount)
  for i=1 to fc.blockcount
    with fc.blocks(i)
      get #fn,,t
      .name=space$(t*2)
      get #fn,,.name
      .name=strconv(.name, vbfromunicode)
      get #fn,,.stuff
      get #fn,,.coordcount
      redim .coords(1 to .coordcount)
      get #fn,,.coords
    end with
  next
  close #fn
 
  msgbox fc.blockcount
  msgbox fc.blocks(1).name
  msgbox fc.blocks(3).coords(3).y
end sub