NEW! Вопросы по UserControl: проблема c сохранением свойств

[Wolfie]

Приветствую - для знающего - ответ 1 минута - но для меня - тупик. Начал писать UC -
1.(уже все ясно) нужно сделать нормальное свойство FONT чтобы его PropertyBrowser показывал как пологается и чтобы всякие label.font=UC.Font работали... Как мне эти Let-Get описать? как stdFont объявлять или что?
2.(уже все ясно) можно ли вызвать из кода PropertyPage, ну чтобы не только создатель программы но и пользователь мог менять через PropertyBrowser свойства?
3.(уже все ясно) Возник еще вопрос - как можно сделать так, чтобы например кликнул по этому контролу, а в конкретном текстбоксе произошли изменения? Ну т.е. проассоциировать мой контрол с каким-либо другим контролом
4. (уже все ясно)Проблема: что-то я делаю не так (вернее как раз что-то не делаю) и после того как поменяю свойства в (Custom) [через PropPage] или даже через само окно свойств - свойства задаются только в дизайн-модэ, а в Рантайме опять стандартный.... что надо сделать?

Благодарю за ответы - если пошлете по ХОРОШЕЙ ссылки - схожу

CASE CLOSED \ Тема закрыта

[BV]

1. Да, как StdFont
2. Зачем PropertyPage? Разве окно Properties свойств не меняет?

[Wolfie]

BV
1. с stdFont -не получается - через лет-гет все время ошибка что With Block не выбран, а через сет - PropertyBrowser не понимает... привидите пример, если не сложно, пжлст.

2. в том то и дело, что речь идет не о програмере, пользующимся этим ActiveX в DesignMode, а том, чтобы в RunTime вывести эту страницу свойство для конечного пользователя. Ну и насчет PropPage - так удобнее, чем через простые Properties...

[tyomitch]

Нужно Get и Set.

[blinow]

Ну вот так можно

Код: Выделить всё

Public Property Let BackColorText(ByVal New_BackColor As OLE_COLOR)
    TextB.BackColor = New_BackColor
    Text1.BackColor = TextB.BackColor
    TextI.BackColor = TextB.BackColor
    UserControl.BackColor = TextB.BackColor
    PropertyChanged "BackColorText"
End Property

Public Property Get BackColorlist() As OLE_COLOR
    BackColorlist = ListB.BackColor
End Property

Public Property Let BackColorlist(ByVal New_BackColor As OLE_COLOR)
    ListB.BackColor() = New_BackColor
    PropertyChanged "BackColorList"
End Property

Public Property Get ForeColorText() As OLE_COLOR
    ForeColorText = TextB.ForeColor
End Property

Public Property Let ForeColorText(ByVal New_ForeColor As OLE_COLOR)
    TextB.ForeColor = New_ForeColor
    PropertyChanged "ForeColorText"
End Property

Public Property Get ForeColorList() As OLE_COLOR
    ForeColorList = ListB.ForeColor
End Property

Public Property Let ForeColorList(ByVal New_ForeColor As OLE_COLOR)
    ListB.ForeColor = New_ForeColor
    PropertyChanged "ForeColorList"
End Property

Public Property Get FontText() As Font
    Set FontText = TextB.Font
End Property

Public Property Set FontText(ByVal New_Font As Font)
    Set TextB.Font = New_Font
    Set ListB.Font = New_Font
    PropertyChanged "FontText"
End Property

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
    TextB.BackColor = PropBag.ReadProperty("BackColorText", &H80000005)
    ListB.BackColor = PropBag.ReadProperty("BackColorList", &H80000005)
    TextB.ForeColor = PropBag.ReadProperty("ForeColorText", &H80000012)
    ListB.ForeColor = PropBag.ReadProperty("ForeColorList", &H80000012)
    Set FontText = PropBag.ReadProperty("FontText", Ambient.Font)
End Sub

Private Sub UserControl_WriteProperties(PropBag As PropertyBag)
    Call PropBag.WriteProperty("BackColorText", TextB.BackColor, &H80000005)
    Call PropBag.WriteProperty("BackColorList", ListB.BackColor, &H80000005)
    Call PropBag.WriteProperty("ForeColorText", TextB.ForeColor, &H80000012)
    Call PropBag.WriteProperty("ForeColorList", ListB.ForeColor, &H80000012)
    Call PropBag.WriteProperty("FontText", TextB.Font, Ambient.Font)
End Sub



[schalexey]

Wolfie для начинающего можно использовать встроенную тулзу "VB ActiveX Control Interface Wizard" в Add-In добавляется. Там сможешь свзять все стандартные свойства и события что те надо для контрола со своими. А потом подчистить код

[Wolfie]

Спасибо, господа, за помощь - связал
я и так использую стандартную Wizard для создания PropPage, но учту

А как быть с пунктами 2 и 3? как в 3 сделать - set ... as Object или as Control или as Что?

[Wolfie]

Ну что, никто никогда не пользовался UserControl'ом? Никто не может мне подсказать эти вещи:

2. можно ли вызвать из кода PropertyPage, ну чтобы не только создатель программы но и пользователь мог менять через PropertyBrowser свойства?
3. Возник еще вопрос - как можно сделать так, чтобы например кликнул по этому контролу, а в конкретном текстбоксе произошли изменения? Ну т.е. проассоциировать мой контрол с каким-либо другим контролом

[VB-constructor]

3. Возник еще вопрос - как можно сделать так, чтобы например кликнул по этому контролу, а в конкретном текстбоксе произошли изменения? Ну т.е. проассоциировать мой контрол с каким-либо другим контролом

в свойстве пропиши findwindow и делай, что хочешь

[keks-n]

VB-constructor
Сам хоть понял, что сказал?
Wolfie
В Design-mode по идее - никак. Можно, правда, установить имя и индекс целевого контрола, а потом через UserControl.Parent.Controls его вытаскивать, но это некрасиво. В рантайме можно сделать через Property Set объявив как TextBox

[Wolfie]

keks-n в рантайме так в рантайме, значит

Код: Выделить всё

' UserControl
Dim Targ as TextBox
...
Property Set(Target as textbox)
   set targ=target
end property
...
private sub command1_Click()
targ.seltext="<" & targ.seltext & ">"
end sub

спасибо, попробую. Насчет дизайн-модэ - в коммонконтролах есть контрол который пристраивается к текстбоксу и делает больше\меньше его знчение, и если не ошибаюсь, то он в дизайне с текстбоксом линкится... вот как он это делает...

[VB-constructor]

Сам хоть понял, что сказал?

Да

Код: Выделить всё

Dim targ As Long
Property Set sendTextBox(Target as String)
targ = findwindow(Target, "")
SetWindowText targ, "текст"
end property

keks-n

Сам хоть понял, что сказал?

А вы можете нормально общаться на форуме?

[GSerg]

VB-constructor, можем. Только на глупость, сказанную уверенным тоном, будем реагировать именно так. Вот ты её сейчас снова повторил, да ещё и бредовым кодом - поэтому вопрос, сам хоть понял, что сказал?

[VB-constructor]

Зато рабочим и выполняющим требования автора

[GSerg]

То есть (на время опустим остальные аспекты бредовости этого кода) ты его даже не удосужился проверить.
Ну-ну.

[Konst_One]

3. читай про биндинг коллекшен, примеры смотри в сборнике примеров , которые идут к VS 6.0

ЗЫ
или я не совсем понял что ты хочешь получить. может ты хочешь сделать что-то похожее на UpDown контрол? тогда это все ручками надо позиционировать, а внешний контрол, к которому привязываешься искать через UserControl.ParentControls

[Wolfie]

Насчет 3 - спасибо, господа! хорошо работает вариант с set...as textbox Насчет UpDown - именно о нем я и говорил, т.е. в идеале - чтобы в дизайн-модэ связывать по имени с произвлольным текст-боксом, но и так хорошо

Видимо, без Ваших советов мне контрол не дописать... насчет 4 и 2 подсобите!
Не хочется дублировать PropPage на отдельной форме

[Wolfie]

Я же правдо не знаю!

4. Проблема: что-то я делаю не так (вернее как раз что-то не делаю) и после того как поменяю свойства в (Custom) [через PropPage] или даже через само окно свойств - свойства задаются только в дизайн-модэ, а в Рантайме опять стандартный.... что надо сделать?

[Konst_One]

2. Можно (GUID свой только поставь)

Код: Выделить всё

Private Type GUID
    Data1                   As Long
    Data2                   As Integer
    Data3                   As Integer
    Data4(7)                As Byte
End Type

Private Declare Function CLSIDFromString Lib "ole32.dll" (ByVal lpszProgID As Long, pCLSID As GUID) As Long
Private Declare Function GetSystemDefaultLCID Lib "kernel32" () As Long
Private Declare Function OleCreatePropertyFrame Lib "oleaut32.dll" (ByVal hWndOwner As Long, ByVal x As Long, ByVal y As Long, ByVal lpszCaption As Long, ByVal cObjects As Long, ByRef ppUnk As Long, ByVal cPages As Long, ByRef pPageClsID As GUID, ByVal lcid As Long, ByVal dwReserved As Long, ByVal pvReserved As Long) As Long
'

Public Sub ShowMyProperty(ByVal hWnd As Long, ByVal Caption As String, ByRef MyObject As Object)
Dim CLSID As GUID
'эту константу надо заменить на свою
Const myGeneralPage = "{CC72240A-CFB5-4124-A007-296F23BC7822}"

    CLSIDFromString StrPtr(myGeneralPage), CLSID
    OleCreatePropertyFrame hWnd, 0&, 0&, StrPtr(Caption), 1, ObjPtr(MyObject), 1, CLSID, GetSystemDefaultLCID, 0&, 0&

End Sub

Public Sub ShowFontProperty(ByVal hWnd As Long, ByVal Caption As String, ByRef MyObject As Object)
Dim CLSID As GUID

    CLSIDFromString StrPtr("{7EBDAAE0-8120-11CF-899F-00AA00688B10}"), CLSID
    OleCreatePropertyFrame hWnd, 0&, 0&, StrPtr(Caption), 1, ObjPtr(MyObject), 1, CLSID, GetSystemDefaultLCID, 0&, 0&

End Sub

Вызов из контрола:

Код: Выделить всё

Private Sub UserControl_DblClick()
        ShowMyProperty hWnd, "Основные свойства", Me
        RaiseEvent DblClick
End Sub

[Wolfie]

Konst_One спасибо, а мне как этот GUID получить - самому как-то нехочется придумывать - их там столько в реестре

[Konst_One]

когда скопилишь свой OCX в реестре найдешь GUID для его PropertyPage

[Wolfie]

Konst_One
Спасибо - знаю где копаться теперь! Но у меня кстати не OCX - все равно прокатит? (UC в EXE)

ALL Ну не знаю я как мне сохранять свойства в контроле!

4. Проблема: что-то я делаю не так ...

[Wolfie]

Всем спасибо, моя проблема решилась в http://bbs.vbstreets.ru/viewtopic.php?p=6649896