Поиск листа по названию

[Sandra_83]

Подскажите как сделать...

Я по нажатию на кнопку добавляю листы с названием, которое соответстует определенной ячейке ("Company").
Вопрос в том, как сделать проверку, что если лист с таким же названием как ячейка "Company" уже существет, то выдавалась бы ошибка. Чтобы исключить возможность добавления листов с одинаковыми названиями.

Вот код, который сейчас:

Sub CopySheet()
Application.ScreenUpdating = False
On Error Resume Next
'Sheets("Шаблон").Visible = True
Worksheets("Шаблон").Select
Worksheets("Шаблон").Copy After:=Worksheets("Данные")
Worksheets("Шаблон (2)").Range("CompName").Value = Range("Company").Value
Worksheets("Шаблон (2)").Name = Range("Company").Value
'Sheets("Шаблон").Visible = False
Worksheets("Данные").Activate

Application.ScreenUpdating = True
End Sub

[Genyaa]

Можно сделать так (проверяя все имена листов):

Код: Выделить всё

Flag = False
For each nn in Sheets
   If nn.Name = Range("Company").Value Then
      Flag = True
      Exit For
   End If
Next nn
If Flag Then
   MsgBox "Лист с таким именем уже существует!"
   Exit Sub
End If

Или так (делая попытку обратиться к листу с предполагаемым именем - если будет успешно - то существует):

Код: Выделить всё

On Error Resume Next
Err.Clear
AnyThing = Worksheets(Range("Company").Value).Name
If Err.Number = 0 Then
    MsgBox "Лист с таким именем уже существует!"
    Exit Sub
End If
Err.Clear

[Nicky]

Придирки:

Код: Выделить всё

Worksheets("Шаблон").Select 'это необязательно
Worksheets("Шаблон").Copy After:=Worksheets("Данные")


Код: Выделить всё

Worksheets("Шаблон (2)").Range("CompName").Value = Range("Company").Value

А если лист "Шаблон (2)" существовал до копирования?

Код: Выделить всё

Worksheets("Шаблон").Copy After:=Sheets(Sheets.Count)
Sheets(Sheets.Count).Name = Range("Company").Value
Sheets(Sheets.Count).Range("CompName").Value = Range("Company").Value

[Sandra_83]

Спасибки всем большое