output parameter

[RuslanG]

Подскажите пожалуйста как вызвать хранимую процедуру с output parameter из vb с использованием ADO

[GSerg]

А как ты вызываешь хранимую процедуру с input параметром?

[Antonariy]

Не через объект ли Command?

[RuslanG]

Смотрите, есть код

objCmd1.CommandText = "GetKeyWordDescription"
objCmd1.CommandType = adCmdStoredProc
Set objConn = GetNewConnection
objCmd1.ActiveConnection = objConn
objCmd1.Parameters.Refresh
objCmd1(1) =listview1.SelectedItem.Text
Set objRs = objCmd1.Execute

GetKeyWordDescription эта функция имеет 1 входной и один выходной параметр. входной параметр я знаю как объявить, а как объявить выходной параметр и извлечь его значение после выполнения процедуры?

[Antonariy]

Что за бардак в терминологии? Что значит "объявить"? Объявлен он в хранимой процедуре - @param int output
Может все таки "получить значение"? ObjCmd.Parameters("param").Value

[RuslanG]

Прежде чем получить значение, надо создать выходной параметр и добавить его в объект Cmd.Как это сделать?

[Antonariy]

Во-первых, ты сказал, что знаешь, как добавить входной параметр. Выходной точно так же. А во-вторых тебе этого вообще делать не нужно. Ты же делаешь .Parameters.Refresh.

[Konst_One]

Код: Выделить всё

Public Function sys_Module_GetKey(ByVal ModuleID As Integer, ByVal ModuleName As String, ByVal KeyName As String, ByRef KeyValue As String) As Long
Dim cmd As ADODB.Command, p As ADODB.Parameters
    Set cmd = New ADODB.Command
    cmd.ActiveConnection = modADO.GetConnectionString()
    cmd.CommandType = adCmdStoredProc
    cmd.CommandText = "sys_Module_GetKey"
    Set p = cmd.Parameters
    p.Append cmd.CreateParameter("RETURN_VALUE", adInteger, adParamReturnValue)
    p.Append cmd.CreateParameter("@ModuleID", adSmallInt, adParamInput, , ModuleID)
    p.Append cmd.CreateParameter("@ModuleName", adVarChar, adParamInput, 50, ModuleName)
    p.Append cmd.CreateParameter("@KeyName", adVarChar, adParamInput, 20, KeyName)
    p.Append cmd.CreateParameter("@KeyValue", adVarChar, adParamOutput, 2000)
    p.Append cmd.CreateParameter("@IsEncrypted", adBoolean, adParamOutput)

    cmd.Execute , , adExecuteNoRecords

    KeyValue = p("@KeyValue")

    sys_Module_GetKey = p("RETURN_VALUE").Value
    Set p = Nothing
    Set cmd = Nothing
End Function

[RuslanG]

Antonariy , спасибо тебе чувак! опять помог
ступил я что-то, рефреш все переменные собирает уже.
Konst_One тоже спасибо, но у меня твой код не компилировался,
ругался на тип Parameters