Процессор

[lister]

Нужно узнать частоту процессора, его модель.

Пока могу узнать только по разделу реестра HKEY_LOCAL_MACHINE\HARDWARE\DESCRIPTION\System\CentralProcessor\0

Есть еще варианты?

P.S. Поиск по форумам конференции ничего не дал

[uhm]

Ага, есть. Фпоиск.

[keks-n]

uhm
Он там уже был.

P.S. Поиск по форумам конференции ничего не дал

Лучше объяснил бы ему как искать

[lister]

Лучше объяснил бы ему как искать

Ну уж если поиск по слову "процессор" ничего не дает... то уж действительно, давайте учите как искать...

Видимо, народ спрашивает как узнать частоту чего-то иного, либо пишет с издевательствами над русским языком...

может искать по фразе "керамическая плитка с металлическими ножками"?...

[keks-n]

Гугл как всегда рулит:

Класс Win32_Processor
Каждому процессору в системе соответствует экземпляр класса Win32_Processor в WMI. На многопроцессорной машине таких экземпляров будет несколько. Пример получения информации:

Код: Выделить всё

On Error Resume Next
Set objService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\CIMV2")
If Err.Number <> 0 Then
   WScript.Echo Err.Number & ": " & Err.Description
   WScript.Quit
End If
For Each objProc In objService.ExecQuery("SELECT * FROM Win32_Processor")
   WScript.Echo objProc.Caption 'краткое описание процессора
   WScript.Echo objProc.Description 'краткое описание процессора
   WScript.Echo Trim(objProc.Name) 'наименование процессора
   'номер версии процессора, зависящий от архитектуры (не исп. в Windows 95):
   WScript.Echo objProc.Version
   WScript.Echo objProc.Manufacturer 'производитель
   WScript.Echo objProc.DeviceID 'уникальный идентификатор процессора в системе
   'статус:
   '0 - Unknown
   '1 - CPU Enabled
   '2 - CPU Disabled by User via BIOS Setup
   '3 - CPU Disabled By BIOS (POST Error)
   '4 - CPU is Idle
   '5 - Reserved
   '6 - Reserved
   '7 - Other
   WScript.Echo objProc.CpuStatus 'статус
   WScript.Echo objProc.LoadPercentage 'загрузка процессора в прошлую секунду (в проц.)
   WScript.Echo objProc.CurrentClockSpeed 'текущая скорость процессора - в MHz
   WScript.Echo objProc.MaxClockSpeed 'максимальная скорость процессора - в MHz
   WScript.Echo objProc.ExtClock 'частота внешн. таймера (external clock frequency) в MHz
   WScript.Echo objProc.L2CacheSize 'размер кэша процессора Level 2
   WScript.Echo objProc.L2CacheSpeed 'скорость кэша процессора Level 2 - в MHz
   'тип процессора:
   '1 - Other
   '2 - Unknown
   '3 - Central Processor
   '4 - Math Processor
   '5 - DSP Processor
   '6 - Video Processor
   WScript.Echo objProc.ProcessorType 'тип процессора
   WScript.Echo objProc.SocketDesignation 'тип chip socket'а
   WScript.Echo objProc.SystemName 'имя компьютера
Next

[lister]

Спасибо!

Поиск по "winmgmts" сразу вывел на тему "марка и частота проца" с неплохим примером http://bbs.vbstreets.ru/viewtopic.php?t ... t=winmgmts

Вот было бы вместо "проца" слово "процессора", не было бы этой ненужной темы...

[uhm]

Да, я именно эту тему действительно и имел в виду
Не обратил внимания, что она не находится по слову "процессор", сорри.