Запуск процедуры на сервере

[MOV]

Oracle8
Серверная часть работает, то есть если в плюсе пускаешь процедуру, она отрабатывает, а если так:

Код: Выделить всё

Dim WithEvents CN As ADODB.Connection
Dim WithEvents RS As ADODB.Recordset


Private Sub CN_ConnectComplete(ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pConnection As ADODB.Connection)
    Me.Refresh
    RS.ActiveConnection = CN
End Sub

Private Sub Command1_Click()
    Set CN = New ADODB.Connection
    Set RS = New ADODB.Recordset
    CN.ConnectionString = "Provider=OraOLEDB.Oracle.1;Persist Security " & _
                        "Info=False;User ID=us; PASSwORD= asg6hty73; Data Source=MYSOURCE"
    CN.Open
    Dim a As Integer
    QueryString = "myschema.myprocedure(12345,78,1)"
    RS.Open (QueryString)
    CN.Close
End Sub

Ругается типа инвалид sql-statement, а в sqlplus нормально отрабатывает.
Предполагаю, что открытием рекордсета не очень правильно запускать процедуру - как это делать лучше?

[Sebas]

cn.execute

[MOV]

О! спасиб. попробую

[Konst_One]

Лучше так:

Код: Выделить всё

Public Function ORA_UPD_STATUS_SMS_MESSAGE(ByVal MessageID As Long, ByVal NewStatus As String) As Long
On Error GoTo Err_debug
Dim cmd As ADODB.Command
Dim p As ADODB.Parameters

    ' Вызов процедуры обновления статуса сообщения
    mMain.WriteWorkLog "Выполняем процедуру: CUST.UPD_STATUS_SMS_MESSAGE"
    Set cmd = New ADODB.Command
    Set cmd.ActiveConnection = CN_ORA
    cmd.CommandTimeout = 20
    cmd.CommandType = adCmdStoredProc
    cmd.CommandText = "CUST.UPD_STATUS_SMS_MESSAGE"
    ' Описание параметров
    Set p = cmd.Parameters
    p.Append cmd.CreateParameter("RET", adInteger, adParamReturnValue)
    p.Append cmd.CreateParameter("MessageID", adInteger, adParamInput, , MessageID)
    p.Append cmd.CreateParameter("NewStatus", adVarChar, adParamInput, 2, NewStatus)
    cmd.Execute
    ORA_UPD_STATUS_SMS_MESSAGE = p("RET").Value
lb_out:
    Set p = Nothing
    Set cmd = Nothing
    Exit Function
   
Err_debug:
    LogError "ORA_UPD_STATUS_SMS_MESSAGE"
    Resume lb_out
   
End Function