Screensever

[|( () ( T |/| |(]

Чтобы на заднем фоне был рабочий стол, сначала сохраняю screenshot в bmp на диске, потом создаю полигон:

Dim v(3) As BACKGROUND
v(0) = H_BACKGROUND(0, 0, 0, 1, -1, 0, 0)
v(1) = H_BACKGROUND(PRESENT_PARAMS.BackBufferWidth, 0, 0, 1, -1, 1, 0)
v(2) = H_BACKGROUND(0, PRESENT_PARAMS.BackBufferHeight, 0, 1, -1, 0, 1)
v(3) = H_BACKGROUND(PRESENT_PARAMS.BackBufferWidth, PRESENT_PARAMS.BackBufferHeight, 0, 1, -1, 1, 1)
Set VB_BACKGROUND = D3DDevice.CreateVertexBuffer(Len(v(0)) * 4, D3DUSAGE_WRITEONLY, D3DFVF_BACKGROUND, D3DPOOL_MANAGED)
D3DVertexBuffer8SetData VB_BACKGROUND, 0, Len(v(0)) * 4, 0, v(0)

Загружаю текстуру из bmp, налаживаю на него, и ..... возникает два вопроса.
1. Текстура рабочего стола получаеться с кокимто зглаживание, его отключаю, как это испрвить?
2. Можноли какнибуть пропустить этап сохранения screenshot-а на HD?

[FAER]

На первый вопрос ответ не знаю, сглаживание может происходить по многим причинам. А вот на второй вопрос отвечу стопроцентно - нельзя. Эксперементально подтверждено.

[DirectXManiac]

Видимо стоит не тот текстурный фильтр! Попробуй поменять!

[|( () ( T |/| |(]

А вот на второй вопрос отвечу стопроцентно - нельзя. Эксперементально подтверждено.

Оказалось что можно

Private Const BI_RGB = 0&
Private Const DIB_RGB_COLORS = 0
Private Type BITMAPINFOHEADER
biSize As Long
biWidth As Long
biHeight As Long
biPlanes As Integer
biBitCount As Integer
biCompression As Long
biSizeImage As Long
biXPelsPerMeter As Long
biYPelsPerMeter As Long
biClrUsed As Long
biClrImportant As Long
End Type
Private Type RGBQUAD
rgbBlue As Byte
rgbGreen As Byte
rgbRed As Byte
rgbReserved As Byte
End Type
Private Type BITMAPINFO
bmiHeader As BITMAPINFOHEADER
bmiColors As RGBQUAD
End Type
Private Declare Function CreateCompatibleDC Lib "gdi32" _
(ByVal hdc As Long) As Long
Private Declare Function CreateDIBSection Lib "gdi32" _
(ByVal hdc As Long, _
pBitmapInfo As BITMAPINFO, _
ByVal un As Long, _
ByVal lplpVoid As Long, _
ByVal handle As Long, _
ByVal dw As Long) As Long
Private Declare Function GetDIBits Lib "gdi32" _
(ByVal aHDC As Long, _
ByVal hBitmap As Long, _
ByVal nStartScan As Long, _
ByVal nNumScans As Long, _
lpBits As Any, _
lpBI As BITMAPINFO, _
ByVal wUsage As Long) As Long
Private Declare Function SelectObject Lib "gdi32" _
(ByVal hdc As Long, _
ByVal hObject As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" _
(ByVal hdc As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" _
(ByVal hObject As Long) As Long
Private Declare Function BitBlt Lib "gdi32" _
(ByVal hDestDC As Long, _
ByVal X As Long, _
ByVal Y As Long, _
ByVal nWidth As Long, _
ByVal nHeight As Long, _
ByVal hSrcDC As Long, _
ByVal xSrc As Long, _
ByVal ySrc As Long, _
ByVal dwRop As Long) As Long
Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)

Private Function ScreenShot(d3dx As D3DX8, dev As Direct3DDevice8, Width As Integer, Height As Integer) As Direct3DTexture8
Dim bi24BitInfo As BITMAPINFO, bBytes() As Byte
Dim iBitmap As Long
Dim iDC As Long
With bi24BitInfo.bmiHeader
.biBitCount = 24
.biCompression = BI_RGB
.biPlanes = 1
.biSize = Len(bi24BitInfo.bmiHeader)
.biWidth = Width
.biHeight = Height
End With
Len_Array = bi24BitInfo.bmiHeader.biWidth * bi24BitInfo.bmiHeader.biHeight * 3
ReDim bBytes(-17 To Len_Array) As Byte
iDC = CreateCompatibleDC(0)
iBitmap = CreateDIBSection(iDC, bi24BitInfo, DIB_RGB_COLORS, _
ByVal 0&, ByVal 0&, ByVal 0&)
SelectObject iDC, iBitmap
BitBlt iDC, 0, 0, bi24BitInfo.bmiHeader.biWidth, _
bi24BitInfo.bmiHeader.biHeight, _
GetDC(0), 0, 0, vbSrcCopy
GetDIBits iDC, iBitmap, 0, bi24BitInfo.bmiHeader.biHeight, _
bBytes(1), bi24BitInfo, DIB_RGB_COLORS
DeleteDC iDC
DeleteObject iBitmap
bBytes(-15) = 2
CopyMemory bBytes(-5), Width, 2
CopyMemory bBytes(-3), Height, 2
bBytes(-1) = &H18
Set ScreenShot = d3dx.CreateTextureFromFileInMemory(dev, bBytes(-17), Len_Array)
End Function