Проблема с работающим классом

[Kiryusha]

Вобщем, скачал исходники проги для добавлении иконки в трэй. Состоиит прога из формы и класса. Этот класс фактически все и делает, вот ну я его закинул в свою прогу, все повторил как в той программе, но не работает вызов popupmenu теряюсь в догадках почему. Вобщем там есть вот такая вот процедурка:

Код: Выделить всё


'вызвать ивент
Public Sub CallEvent(X As Single, Y As Single)
   'проверка, было ли действие по окну или по иконке в трее
      If Y Then Exit Sub
     
   'получаем тип действия
      Dim MouseButton As Integer
      MouseButton = (X And &HFF) / Screen.TwipsPerPixelX
   
   'генерируем ивент
      RaiseEvent OnIcon(MouseButton)
     
End Sub


В оригинале программы он работает, а в моей нет. То есть по щелчку мыши в MouseButton не код события, а 0 как будто ничего не произошло. Может я что-то не так сделал?

[Viper]

а тебя тип параметров Single не смущает?

[Хакер]

2Кирюша, вот класс который юзаю я, у меня работает, только надо ReleaseCapture сделать там в одном месте, чтоб не тормозил после клика.
2Модераторы, не ругайтесь, что так длинно:

Код: Выделить всё


'*********************************************************************
'*                            TrayIcon                               *
'*             Библиотека для работы с SystemTray                    *
'*-------------------------------------------------------------------*
'
'  Ивенты:
'     OnIcon ( MouseButton as integer )
'                       ; генерируется при действии над иконкой в трее.
'                       ; MouseButton соответствует - Enum TRAYICON_MOUSE_*.
'  Свойства:
'     hWnd (Long)       ; hWnd окна, к которому привязана иконка
'     Icon (Long)       ; указатель на иконку. Иконка должна быть 16 цветная.
'     ToolTipText       ; всплывающий текст
'
'  Методы:
'     Add ( )           ; добавление иконки в трей. Заранее нужно установить все свойства.
'     Modify ( )        ; изменение иконки в трее.
'     Delete ( )        ; удаление иконки из трея
'     CallEvent ( X as single, Y as single )
'                       ; вызывается из Form_MouseDown, ей передаются значения X и Y
'
'---------------------------------------------------------------------
'     Version 0.90 Beta * Copyright (с) А.Щербаков * May 17, 2000
'*********************************************************************
   Option Explicit

'декларация функций Win32API
   Private Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long
   Private Declare Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Long
   Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

'константы и структуры Win32API
   Private Const NIF_MESSAGE = &H1
   Private Const NIF_ICON = &H2
   Private Const NIF_TIP = &H4
   Private Const NIM_ADD = &H0
   Private Const NIM_MODIFY = &H1
   Private Const NIM_DELETE = &H2
   Private Const WM_RBUTTONDOWN = &H204
   Private Const WM_NULL = &H0
   Private Type NOTIFYICONDATA
       cbSize           As Long
       hwnd             As Long
       uID              As Long
       uFlags           As Long
       uCallbackMessage As Long
       hIcon            As Long
       szTip            As String * 64
   End Type
   Private NID As NOTIFYICONDATA

'---------------------------------------------------------------------

'переменные и структуры модуля
   Private m_hWnd          As Long
   Private m_Icon          As Long
   Private m_ToolTipText   As String
   Public Enum TrayIcon_Mouse
      TRAYICON_MOUSE_NONE = 0
      TRAYICON_MOUSE_LEFTDOWN = 1
      TRAYICON_MOUSE_LEFTUP = 2
      TRAYICON_MOUSE_LEFTDBLCLICK = 3
      TRAYICON_MOUSE_RIGHTDOWN = 4
      TRAYICON_MOUSE_RIGHTUP = 5
      TRAYICON_MOUSE_RIGHTDBLCLICK = 6
   End Enum

'ивенты
   Public Event OnIcon(MouseButton As Integer)
   

'---------------------------------------------------------------------
'  Свойства

'получить свойство hWnd
Public Property Get hwnd() As Long
      hwnd = m_hWnd
End Property

'присвоить свойство hWnd
Public Property Let hwnd(ByVal NewValue As Long)
      m_hWnd = NewValue
End Property


'получить свойство Icon
Public Property Get Icon() As Long
      Icon = m_Icon
End Property

'присвоить свойство Icon
Public Property Let Icon(ByVal NewValue As Long)
      m_Icon = NewValue
End Property


'получить свойство ToolTipText
Public Property Get ToolTipText() As String
      ToolTipText = m_ToolTipText
End Property

'присвоить свойство ToolTipText
Public Property Let ToolTipText(ByVal NewValue As String)
      m_ToolTipText = NewValue
End Property

'---------------------------------------------------------------------
'  Методы

'добавление иконки в Tray
Public Sub Add()
   Dim ret As Long
     
   'заполняем структуру
      NID.uID = m_hWnd
      NID.hwnd = m_hWnd
      NID.hIcon = m_Icon
      NID.szTip = Left$(m_ToolTipText, 63) & Chr$(0)
      NID.uFlags = NIF_TIP + NIF_MESSAGE + NIF_ICON
      NID.uCallbackMessage = WM_RBUTTONDOWN
      NID.cbSize = Len(NID)
   
   'вызываем функцию API
      ret = Shell_NotifyIcon(NIM_ADD, NID)
     
End Sub

'изменение иконки и ToolTip в Tray
Public Sub Modify()
   Dim ret As Long
   
   'заполняем структурку
      NID.hIcon = m_Icon
      NID.szTip = Left$(m_ToolTipText, 63) & Chr$(0)
      NID.uFlags = NIF_TIP + NIF_ICON
      NID.cbSize = Len(NID)
     
   'вызываем функцию API
      ret = Shell_NotifyIcon(NIM_MODIFY, NID)
     
End Sub

'удаление иконки из Tray
Public Sub Delete()
   Dim ret As Long
   
   'заполняем структурку
      NID.cbSize = Len(NID)
   
   'вызываем функцию API
      ret = Shell_NotifyIcon(NIM_DELETE, NID)
     
End Sub


'вызвать ивент
Public Sub CallEvent(X As Single, Y As Single)
   'проверка, было ли действие по окну или по иконке в трее
      If Y Then Exit Sub
     
   'получаем тип действия
      Dim MouseButton As Integer
      MouseButton = (X And &HFF) / Screen.TwipsPerPixelX
   
   'генерируем ивент
      RaiseEvent OnIcon(MouseButton)
     
End Sub

'вызов всплывающего меню
Public Sub CallPopupMenu(Window As Form, PopMenu As Menu, Optional Flags, Optional X, Optional Y, Optional DefMenu)
     
   'устанавливаем окно
      SetForegroundWindow m_hWnd
     
   'выводим всплывающее меню
      Window.PopupMenu PopMenu, Flags, X, Y, DefMenu
     
   'посылаем сообщение окну
      PostMessage m_hWnd, WM_NULL, 0, 0

End Sub


[Kiryusha]

!Viper! не смущает потому что в свойсте Form_MouseDown X и Y тоже сингл

Хакер я именно его и юзаю и у меня он не пашет на моей проге, а на оригнале пашет вот я и не знаю что делать

[Viper]

Код: Выделить всё

   'получаем тип действия
      Dim MouseButton As Integer
      MouseButton = (X And &HFF) / Screen.TwipsPerPixelX   
End Sub


странноватое како-то действие для типа Single. Я имею ввиду операцию And.

А в событии MouseDown помимо X и Y еще и Button c Shift имеются. Тип Integer.

[Хакер]

Не нужно на это обращать внимание. Проблема в другом. У меня этот класс работает (да хотябы см. Наши проекты->I-Net Money Counter)

[Kiryusha]

Дк я еще раз повторяю! На скаченной проге этот класс пашет(!) иначе зачем бы я его вообще совал в свой проект, просто когда тот в моей проге, то на иксе всегда 0 тоесть щелкаю я не щелкаю всегда 0, а сегодня вот провел мышкой по верху формы, просто так, и тут раз и сработал этот класс! Я вообще в шоке, из-за чего может быть такая херь? (Кстати может это потому что курсор просто залез в форме по координатам скажем (5,0) что соответсвует например нажатию правой кнопки?)

[GSerg]

Координаты выстави форме в пиксели.

[Kiryusha]

да там итак в форме я не по твипам а по пикселям работаю

[Хакер]

1) А ты класс копи-пастишь или вставляешь в проект готовый (из сущ. CLS файла)?

2) Форма обычная или SuperGiper-навороченная?

[Kiryusha]

1) Я вставляю готовый класс (Добавить файл...)

2) Что ты имеешь ввиду поду супер навороченой и причем тут вообще форма?

[Хакер]

Супер навороченная прога: с регионами, прозрачностью колоркеем, и субклс (т.е. с подменённым WndProc) и прочая дрянь на форме...


СОВЕТ: Сделай новую форму и опробуй класс на ней... Если класс не будет работать и с новой формой, то уже совсем др. дело.

[Kiryusha]

Ну ниче го из перечисленного тобой у мея не используется там прога не столь навороченная ччтобы это все использовать, хотя прозрачность скорее всего будет... Ну вобщем, попробую с другой формой...

[Kiryusha]

Попробовал с другой прогой класс работает, дк почему же тогда не работает с моей прогой? Какие еще варианты?

[Хакер]

Проджект в студию либо сам методом исключения находи в чём причина...

[Kiryusha]

блин все народ я щас сдохну или меня в дурку заберут, вобщем стоило мне в вот этот код (который работал):

Код: Выделить всё

Private Sub cTray_OnIcon(MouseButton As Integer)
    If MouseButton = TRAYICON_MOUSE_LEFTUP Then Form1.Show
End Sub


вставить несколько строк и получить вот это:

Код: Выделить всё

Private Sub cTray_OnIcon(MouseButton As Integer)
    Dim koord As POINTAPI

    If MouseButton = TRAYICON_MOUSE_LEFTUP Then
        Form1.Show
    End If
    If MouseButton = trayicon_mouse_rightup Then
        GetCursorPos koord
        cTray.CallPopupMenu Form1, Me.mnuFile, , koord.x * Screen.twipsPerPixelX, koord.y * Screen.TwipsPerPixelY
    End If
End Sub


Как класс опять перестал работать, причем когда я удаляю новые строки, он все равно не работает. А код кинуть я не могу коммерческая тайна.