Вызов arj из программы

[optimizm]

Подскажите кто сталкивался, как правильнее распаковывать файлы из программы. Пытась просто вызывать командную строку типа
arj e 1.arj но в этом случае как узнать распокавался он или нет.

[tyomitch]

GetExitCodeProcess

[optimizm]

А есть примеры использования этой функции? Я сделал так
Private Declare Function GetExitCodeProcess Lib "kernel32" _
(ByVal hProcess As Long, _
lpExitCode As Long) As Long

myApp = Shell(str, 4)
s=GetExitCodeProcess(myApp, Ret)
Здесь и Ret и s всегда 0. Я так понимаю это означает ошибка. но arj отрабатывает нормально, все распаковывает.

[tyomitch]

Потому что Shell возвращает PID, а GetExitCodeProcess принимает hProcess. Чтобы получить этот хендл, процесс нужно открыть функцией OpenProcess.

[optimizm]

Спасибо. А как вы думаете намного хуже будет если я сделаю вот так?
myApp = Shell(str, 4)
Err:
On Error Resume Next
AppActivate myApp
If Err.Number = 0 Then
GoTo Err
End If

[alibek]

Никак не будет, потому что это вообще не в тему. Err не ловит ошибки других приложений.

[CORBA]

Никак не будет, потому что это вообще не в тему. Err не ловит ошибки других приложений.

Поэтому - GetLastError

[alibek]

CORBA, иногда лучше жевать, чем говорить. Твой ответ совершенно не в тему.

[Sebas]

Я не думаю, что arj.exe устанавливает код завершения. Давно это было...

А unrar.ocx, тут не прокатит? (не пробовал)

[alibek]

Я не думаю, что arj.exe устанавливает код завершения. Давно это было...

ERRORLEVEL точно устанавливает. А перейдет ли он в ExitCode, это у VDM надо спрашивать, но думаю перейдет.

[tyomitch]

Я не думаю, что arj.exe устанавливает код завершения. Давно это было...

Делов-то, проверить. Так нет же, и тут схоластику разводят.

Код: Выделить всё

Option Explicit
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function GetExitCodeProcess Lib "kernel32" (ByVal hProcess As Long, lpExitCode As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Const PROCESS_QUERY_INFORMATION = &H400
Private Const SYNCHRONIZE = &H100000

Sub Main()
Dim hProcess As Long, ReturnCode As Long
hProcess = OpenProcess(PROCESS_QUERY_INFORMATION Or SYNCHRONIZE, 0, Shell("c:\dos\util\arj l " + InputBox("Имя архива")))
WaitForSingleObject hProcess, -1
Debug.Assert GetExitCodeProcess(hProcess, ReturnCode)
CloseHandle hProcess
MsgBox ReturnCode, , "Код возврата"
End Sub


А unrar.ocx, тут не прокатит? (не пробовал)

Не прокатит.