Список таблиц в базе Access

[XPress]

Дорогия братья, обожаемые коллеги!
Не подскажите, возможно ли из MS ACCESS извлечь посредством SQL имена таблиц в базе, если нет, то каким образом возможно? Если к базе я подключаюсь следующим образом:

Код: Выделить всё

Public db As New ADODB.Connection
Public rs As New ADODB.Recordset
db.CursorLocation = adUseClient
db.ConnectionString = "Provider=Microsoft.Jet.OLEdB.4.0;Data Source=" & App.Path & "\Sotrudniki.mdb"
db.Open

Или вообще подскажите как подключится по другому, если этим способом не получится изять список таблиц моей базы!
Всем огромное спасибо!

[GSerg]

http://msdn.microsoft.com/library/en-us ... chemax.asp

[Alexanbar]

Код: Выделить всё

Dim db As Database
Dim tb As TableDef

fn$ = "C:\dddd\mybase.mdb"
Set db = OpenDatabase(fn, , , "Access")

For Each tb In db.TableDefs
    MsgBox tb.Name
Next tb

[XPress]

Вот нашел ...

Код: Выделить всё

Private Sub op()
    On Error GoTo ErrorHandler

    Dim Cnxn As ADODB.Connection
    Dim rstSchema As ADODB.Recordset
    Dim strCnxn As String
       
    Set Cnxn = New ADODB.Connection
    strCnxn = "Provider=Microsoft.Jet.OLEdB.4.0;Data Source=Sotrudniki.mdb;"
    Cnxn.Open strCnxn
       
    Set rstSchema = Cnxn.OpenSchema(adSchemaTables)
   
    Do Until rstSchema.EOF
        If rstSchema!TABLE_TYPE = "TABLE" Then
            List1.AddItem rstSchema!TABLE_NAME
        End If
        rstSchema.MoveNext
    Loop
   
    ' clean up
    rstSchema.Close
    Cnxn.Close
    Set rstSchema = Nothing
    Set Cnxn = Nothing
    Exit Sub
   
ErrorHandler:
    ' clean up
    If Not rstSchema Is Nothing Then
        If rstSchema.State = adStateOpen Then rstSchema.Close
    End If
    Set rstSchema = Nothing
   
    If Not Cnxn Is Nothing Then
        If Cnxn.State = adStateOpen Then Cnxn.Close
    End If
    Set Cnxn = Nothing
   
    If Err <> 0 Then
        MsgBox Err.Source & "-->" & Err.Description, , "Error"
    End If

End Sub