PrintScreen

[Dex]

Как делать PrintScreen экрана в VB и занасить его в Image или в PictureBox

[GSerg]

getdc(0)
bitblt оттуда на picture1.hdc

[Dex]

GSerg чо-то нечего не получается

[GSerg]

Код: Выделить всё

Option Explicit

Private Declare Function StretchBlt Lib "gdi32.dll" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal nSrcWidth As Long, ByVal nSrcHeight As Long, ByVal dwRop As Long) As Long
Private Declare Function GetDC Lib "user32.dll" (ByVal hwnd As Long) As Long

Private Sub Form_Load()
  Me.ScaleMode = vbPixels
End Sub

Private Sub Form_Paint()
  StretchBlt Me.hdc, 0, 0, Me.ScaleWidth, Me.ScaleHeight, GetDC(0), 0, 0, Screen.Width \ Screen.TwipsPerPixelX, Screen.Height \ Screen.TwipsPerPixelY, vbSrcCopy
End Sub

[Dex]

GSerg Many thanks

[Dex]

GSerg то-чо ты мне предложил не-то картинка заносится Form.Picture
А как мне сделать код для таймера мне нужно чтоб через интервал в таймере делался PrintScreen и занасился именно в Image.Напиши мне код что-ли как вызывать нажатие кнопки PrintScreen(чтоб в буфер занасилося чоб потом можно была вставить из буфера) или предложи свой способ но чоб через таймер и в Image

[GSerg]

У Image нет DC.
Могу предложить picturebox.
Но если этот конверт ты не сможешь сделать сам...

[Dex]

Окей обьясни мне через PictureBox но только чоб

А как мне сделать код для таймера мне нужно чтоб через интервал в таймере делался PrintScreen и занасился именно в PictureBox

через таймер

[BuilderSoft]

GSerg
молодец

[GSerg]

Form_Paint видишь? Замени на Timer1_Timer.
Me.hDC видишь? Замени на Picture1.hDC.

[Dex]

А когда AutoRedraw на True меняешь то PrintScreen'иться не хочет а мне нужно в моей проге чоб
Picture был вне поле видимости и мне нужно ещё каждую новую картинку от PrintScreen'еную
сохранять в тех размерах какое разрешение экрана а не в таких размерах каких размеров
Picture.Подскажи GSerg ну очень надо!!!

[GSerg]

__asm
{
Подскажи equ Refresh
}

[Dex]

GSerg чо ты написал я не понял наверно просто скажи мне как вызвать одно нажатие кнопки PrintScreen и всё

[tyomitch]

Ну а самому подумать слабо? Только cut-n-paste-ить код из форума в проект можешь?
Сколько я вижу твои сообщения, они все проникнуты мыслью, что все на этом форуме обязаны тебе помогать. И не просто укзывать путь к решению, а давать его целиком.
Может, тебе и весь проект целиком написать, а?

[Dex]

tyomitch я что-то не понял помоему этот форум для того чтоб задавать на нём вопросы по програмированию а каких масштабов нет разницы
и я не требую написать мне код я прошу и спрашиваю

[tyomitch]

Я не заметил никаких усилий с твоей стороны для решения твоей проблемы. Мне показалось, ты считаешь, что люди будут помогать тебе просто потому, что им нечем больше заняться.
Если я ошибся - прошу прощения, но уж шибко неприглядно ты смотришься.

[Dex]

tyomitch я над PrintScreen'ом долбаюсь уже месяц перепробовал все
способы которые знал и поэтому мне ничего ни остаётся как спрашивать код для PrintScreen

[marvan]

'на форме
'Command1 CommandButton
'Picture1 PictureBox
Private Declare Sub keybd_event Lib "user32" ( _
    ByVal bVk As Byte, _
    ByVal bScan As Byte, _
    ByVal dwFlags As Long, _
    ByVal dwExtraInfo As Long)
Private Const VK_SNAPSHOT As Byte = 44

Private Sub Command1_Click()
   On Error GoTo BkmErr
   Clipboard.Clear
   DoEvents
   Call keybd_event(VK_SNAPSHOT, 0, 0, 0)
   DoEvents
   Picture1.Picture = Clipboard.GetData(vbCFBitmap)
   Exit Sub
BkmErr:
   Beep
   MsgBox Err.Description, vbExclamation, "Print Screen"
End Sub

[CodeName33]

А чем тебя не устраивает модуль захвата (тут где-то в примерах лежал). Весь экран в объект stdPicture захватывает. Всё работает и можно сохранить нормально.



{
Option Explicit
Option Base 0
Private Type PALETTEENTRY
peRed As Byte
peGreen As Byte
peBlue As Byte
peFlags As Byte
End Type
Private Type LOGPALETTE
palVersion As Integer
palNumEntries As Integer
palPalEntry(255) As PALETTEENTRY ' Enough for 256 colors
End Type
Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(7) As Byte
End Type
Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type
Private Type PicBmp
Size As Long
Type As Long
hBmp As Long
hPal As Long
Reserved As Long
End Type
Private Const RASTERCAPS As Long = 38
Private Const RC_PALETTE As Long = &H100
Private Const SIZEPALETTE As Long = 104
Private Declare Function CreateCompatibleBitmap Lib "GDI32" (ByVal hDC As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
Private Declare Function GetDeviceCaps Lib "GDI32" (ByVal hDC As Long, ByVal iCapabilitiy As Long) As Long
Private Declare Function GetSystemPaletteEntries Lib "GDI32" (ByVal hDC As Long, ByVal wStartIndex As Long, ByVal wNumEntries As Long, lpPaletteEntries As PALETTEENTRY) As Long
Private Declare Function CreateCompatibleDC Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function CreatePalette Lib "GDI32" (lpLogPalette As LOGPALETTE) As Long
Private Declare Function SelectPalette Lib "GDI32" (ByVal hDC As Long, ByVal hPalette As Long, ByVal bForceBackground As Long) As Long
Private Declare Function RealizePalette Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function SelectObject Lib "GDI32" (ByVal hDC As Long, ByVal hObject As Long) As Long
Private Declare Function BitBlt Lib "GDI32" (ByVal hDCDest As Long, ByVal XDest As Long, ByVal YDest As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hDCSrc As Long, ByVal XSrc As Long, ByVal YSrc As Long, ByVal dwRop As Long) As Long
Private Declare Function GetWindowDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function ReleaseDC Lib "user32" (ByVal hwnd As Long, ByVal hDC As Long) As Long
Private Declare Function DeleteDC Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long
Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function GetForegroundWindow Lib "user32" () As Long
Private Declare Function OleCreatePictureIndirect Lib "olepro32.dll" (PicDesc As PicBmp, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long
Public LDX As Long, LDY As Long, SELI As Long

Public Function CreateBitmapPicture(ByVal hBmp As Long, _
ByVal hPal As Long) As Picture
Dim r As Long
Dim Pic As PicBmp
Dim IPic As IPicture
Dim IID_IDispatch As GUID
With IID_IDispatch
.Data1 = &H20400
.Data4(0) = &HC0
.Data4(7) = &H46
End With
With Pic
.Size = Len(Pic) ' Length of structure
.Type = vbPicTypeBitmap ' Type of Picture (bitmap)
.hBmp = hBmp ' Handle to bitmap
.hPal = hPal ' Handle to palette (may be null)
End With
r = OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)
Set CreateBitmapPicture = IPic
End Function
Public Function CaptureWindow(ByVal hWndSrc As Long, _
ByVal bClient As Boolean, ByVal LeftSrc As Long, _
ByVal TopSrc As Long, ByVal WidthSrc As Long, _
ByVal HeightSrc As Long) As Picture

Dim hDCMemory As Long
Dim hBmp As Long
Dim hBmpPrev As Long
Dim r As Long
Dim hDCSrc As Long
Dim hPal As Long
Dim hPalPrev As Long
Dim RasterCapsScrn As Long
Dim HasPaletteScrn As Long
Dim PaletteSizeScrn As Long
Dim LogPal As LOGPALETTE
If bClient Then
hDCSrc = GetDC(hWndSrc) 'Get DC for Client area.
Else
hDCSrc = GetWindowDC(hWndSrc) 'Get DC for entire window.
End If
hDCMemory = CreateCompatibleDC(hDCSrc)
hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
hBmpPrev = SelectObject(hDCMemory, hBmp)
RasterCapsScrn = GetDeviceCaps(hDCSrc, RASTERCAPS) 'Raster capabilities
HasPaletteScrn = RasterCapsScrn And RC_PALETTE 'Palette support
PaletteSizeScrn = GetDeviceCaps(hDCSrc, SIZEPALETTE) 'Palette size
If HasPaletteScrn And (PaletteSizeScrn = 256) Then
LogPal.palVersion = &H300
LogPal.palNumEntries = 256
r = GetSystemPaletteEntries(hDCSrc, 0, 256, LogPal.palPalEntry(0))
hPal = CreatePalette(LogPal)
hPalPrev = SelectPalette(hDCMemory, hPal, 0)
r = RealizePalette(hDCMemory)
End If
r = BitBlt(hDCMemory, 0, 0, WidthSrc, HeightSrc, hDCSrc, _
LeftSrc, TopSrc, vbSrcCopy)
hBmp = SelectObject(hDCMemory, hBmpPrev)
If HasPaletteScrn And (PaletteSizeScrn = 256) Then
hPal = SelectPalette(hDCMemory, hPalPrev, 0)
End If
r = DeleteDC(hDCMemory)
r = ReleaseDC(hWndSrc, hDCSrc)
Set CaptureWindow = CreateBitmapPicture(hBmp, hPal)
End Function

Public Function CaptureScreen() As Picture
Dim hWndScreen As Long
hWndScreen = GetDesktopWindow()
With Screen
Set CaptureScreen = CaptureWindow(hWndScreen, False, 0, 0, _
.Width \ .TwipsPerPixelX, .Height \ .TwipsPerPixelY)
End With
End Function
}

[Dex]

marvan твой код фотографирует токо саму форму а не весь экран еслиб токо весь экран то всё было бы ок

[A.A.Z.]

Почему? Может, ты просто форму на весь экран развернул?

[Dex]

Форма не развёрнута на весь экран

[Andrey Fedorov]

я над PrintScreen'ом долбаюсь уже месяц перепробовал все
способы которые знал и поэтому мне ничего ни остаётся как спрашивать код для PrintScreen

Как вообще над этим можно столько "долбаться" - надоест ведь.
Если только не мозахист. Тем более примеров в интернете на эту тему море.

В свое время я вот на приведенную ниже утилитку дня три или четыре потратил (до этого PrintScreen-ом вообще не интересовался):

http://www.planet-source-code.com/vb/scripts/ShowCode.asp?txtCodeId=43136&lngWId=1

В общем, если не охота возиться то можешь пользовать ее.

P.S Есть несколько более продвинутый вариант, но его нужно чистить от лишнего кода (он встраивался в одно коммерческое приложение), а лень... В общем данный пример, думаю, ответит на все вопросы...

[marvan]

приведённый мной код - 100% эмуляция нажатия на кнопку Print Screen, и послелующей вставкой данных из буфера обмена. Копия именно всего экрана. Для проверки после нажатия на Command1 - запусти Paint и нажми Ctrl-V. Вот если бы Call keybd_event(VK_SNAPSHOT, 1, 0, 0) - тогда действительно активное окно.
К стати, использование буфера - серьёзный недостаток этого примера.

[Dex]

marvan вот как раз при Call keybd_event(VK_SNAPSHOT, 1, 0, 0) и делается PrintScreen всего экрана!

[marvan]

Нефига людей путать. У тебя на клаве клавиша Alt залипла.

[Dex]

marvan ничего у меня на клаве не залепало я клаву кипул недавно

[MOV]

Извиняюсь, может я что-то не понимаю, но столько шума из-за принт-скрина?

По моему marvan ответил легко и понятно:

Код: Выделить всё

Private Declare Sub keybd_event Lib "user32" _
(ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, _
ByVal dwExtraInfo As Long)

Private Sub Timer1_Timer()
    keybd_event &H2C, 1, 0, 0
    'keybd_event &H2C, 0, 0, 0 'это как помню, скриншот активной формы
    Picture1.Picture = Clipboard.GetData(vbCFBitmap) ' ну короче, абираешь из буфера
End Sub

Хотя лучше по моему использовать sleep, вместо таймера.
Месяц на это - удивительно, по моему ты что-то не договариваешь или я что-то не так прочитал в вопросе.