Реестр...

[klop086]

Я тут почитал Api-Guide и там есть цельный пример по работе с реестром, только в нём показано как работать с двоичными числами, а мне нужно записать в реестр строку. Попробовал разобраться - не получается.

Мне нужен пример: создание, просмотр и удаление Текстового параметра в реестре.

[Igor_123]

Прошу прощения но API под рукой не было

Код: Выделить всё

Dim strProperty As String
'Это я пишу в программе на VB
SaveSetting "ViewDesign", "Offer", "Offer", PathF & mvarNameZakazForFileName & ".txt"
'а это я читаю в макросе на VBA
Const strREG_SETTINGS_BASE_KEY As String = "HKEY_CURRENT_USER\SOFTWARE\VB and VBA Program Settings\ViewDesign\Offer\"
strProperty = System.PrivateProfileString("", strREG_SETTINGS_BASE_KEY, "Offer")
'а это оттуда-же удаляю
VBA.Interaction.DeleteSetting "ViewDesign", "Offer", "Offer"

и все прекрасно равотает

[Dzhon]

А вот пример с API:

'---------ПРИМЕРЫ ИСПОЛЬЗОВАНИЯ МОДУЛЯ-----------
''Удаление целой папки
'Call DeleteKey(HKEY_CURRENT_USER, "Software\SharCO")
''Создать определенную папку
'Call SaveKey(HKEY_CURRENT_USER, "Software\SharCO")
''Сохранить значение String
'Dim strString As String
'strString = InputBox("Please type in a string to save to the Registry.")
'If strString = "" Then Exit Sub
'Call SaveString(HKEY_CURRENT_USER, "Software\SharCO\Program", "String", strString)
''Получить значение String
'Dim strString As String
'strString = GetString(HKEY_CURRENT_USER, "Software\SharCO\Program", "String")
'MsgBox strString
''Удаление String
'Call DeleteValue(HKEY_CURRENT_USER, "Software\SharCO\Program", "String")
''Сохранить значение Dword
'Dim lngDword As Long
'Dim strInput As String
'strInput = InputBox("Please type in a string to save to the Registry.")
'If strInput = "" Then Exit Sub
'lngDword = CLng(strInput)
'Call SaveDword(HKEY_CURRENT_USER, "Software\SharCO\Program", "Dword", lngDword)
''Получить значение Dword
'Dim lngDword As String
'lngDword = GetDword(HKEY_CURRENT_USER, "Software\SharCO\Program", "Dword")
'MsgBox lngDword
''Удаление Dword
'Call DeleteValue(HKEY_CURRENT_USER, "Software\SharCO\Program", "Dword")
'\\\\\\\\\\\\\\\\\\\\\\\\\\\\-----------------/////////////////////////////
Declare Function RegCloseKey Lib "advapi32.dll" (ByVal Hkey As Long) As Long
Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal Hkey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal Hkey As Long, ByVal lpSubKey As String) As Long
Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal Hkey As Long, ByVal lpValueName As String) As Long
Declare Function RegOpenKey Lib "advapi32.dll" Alias "RegOpenKeyA" (ByVal Hkey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal Hkey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
Declare Function RegSetValueEx Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal Hkey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal cbData As Long) As Long
Public Const REG_SZ = 1
Public Const REG_DWORD = 4
Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_USERS = &H80000003
Public Const HKEY_PERFORMANCE_DATA = &H80000004
Public Const ERROR_SUCCESS = 0&
Public Function GetString(Hkey As Long, strPath As String, strValue As String)
Dim keyhand As Long
Dim datatype As Long
Dim lResult As Long
Dim strBuf As String
Dim lDataBufSize As Long
Dim intZeroPos As Integer
r = RegOpenKey(Hkey, strPath, keyhand)
lResult = RegQueryValueEx(keyhand, strValue, 0&, lValueType, ByVal 0&, lDataBufSize)
If lValueType = REG_SZ Then
strBuf = String(lDataBufSize, " ")
lResult = RegQueryValueEx(keyhand, strValue, 0&, 0&, ByVal strBuf, lDataBufSize)
If lResult = ERROR_SUCCESS Then
intZeroPos = InStr(strBuf, Chr$(0))
If intZeroPos > 0 Then
GetString = Left$(strBuf, intZeroPos - 1)
Else
GetString = strBuf
End If
End If
End If
End Function
Public Sub SaveString(Hkey As Long, strPath As String, strValue As String, strdata As String)
Dim keyhand As Long
Dim r As Long
r = RegCreateKey(Hkey, strPath, keyhand)
r = RegSetValueEx(keyhand, strValue, 0, REG_SZ, ByVal strdata, Len(strdata))
r = RegCloseKey(keyhand)
End Sub
Function GetDword(ByVal Hkey As Long, ByVal strPath As String, ByVal strValueName As String) As Long
Dim lResult As Long
Dim lValueType As Long
Dim lBuf As Long
Dim lDataBufSize As Long
Dim r As Long
Dim keyhand As Long
r = RegOpenKey(Hkey, strPath, keyhand)
lDataBufSize = 4
lResult = RegQueryValueEx(keyhand, strValueName, 0&, lValueType, lBuf, lDataBufSize)
If lResult = ERROR_SUCCESS Then
If lValueType = REG_DWORD Then
GetDword = lBuf
End If
End If
r = RegCloseKey(keyhand)
End Function
Function SaveDword(ByVal Hkey As Long, ByVal strPath As String, ByVal strValueName As String, ByVal lData As Long)
Dim lResult As Long
Dim keyhand As Long
Dim r As Long
r = RegCreateKey(Hkey, strPath, keyhand)
lResult = RegSetValueEx(keyhand, strValueName, 0&, REG_DWORD, lData, 4)
r = RegCloseKey(keyhand)
End Function
Public Sub SaveKey(Hkey As Long, strPath As String)
Dim keyhand&
r = RegCreateKey(Hkey, strPath, keyhand&)
r = RegCloseKey(keyhand&)
End Sub
Public Function DeleteKey(ByVal Hkey As Long, ByVal strKey As String)
Dim r As Long
r = RegDeleteKey(Hkey, strKey)
End Function
Public Function DeleteValue(ByVal Hkey As Long, ByVal strPath As String, ByVal strValue As String)
Dim keyhand As Long
r = RegOpenKey(Hkey, strPath, keyhand)
r = RegDeleteValue(keyhand, strValue)
r = RegCloseKey(keyhand)
End Function