Vozmojno pomenyat tsvet menyu?

[Vicenza]

Sdelal v moem proekte menu cherez "Menu editor" i ne znau kak pomenyat ego tsvet.
Skajite kak pomenyat.
Spasibo.

[A.A.Z.]

Код: Выделить всё

Private Declare Function CreateBrushIndirect Lib "gdi32" (lpLogBrush As LOGBRUSH) As Long
Private Declare Function GetMenu Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function GetMenuInfo Lib "user32" (ByVal hMenu As Long, lpcmi As tagMENUINFO) As Long
Private Declare Function SetMenuInfo Lib "user32" (ByVal hMenu As Long, lpcmi As tagMENUINFO) As Long

Private Type LOGBRUSH
lbStyle As Long
lbColor As Long
lbHatch As Long
End Type

Private Type tagMENUINFO
cbSize As Long
fMask As Long
dwStyle As Long
cyMax As Long
hbrBack As Long
dwContextHelpID As Long
dwMenuData As Long
End Type

Private Const BS_SOLID = 0
Private Const MIM_APPLYTOSUBMENUS = &H80000000
Private Const MIM_BACKGROUND = &H2

Private Sub Form_Load()
Dim ret As Long
Dim hMenu As Long
Dim hBrush As Long
Dim lbBrushInfo As LOGBRUSH
Dim miMenuInfo As tagMENUINFO
lbBrushInfo.lbStyle = BS_SOLID
lbBrushInfo.lbColor = vbRed    'ЦВЕТ МЕНЮ ЗДЕСЬ
lbBrushInfo.lbHatch = 4
hBrush = CreateBrushIndirect(lbBrushInfo)
hMenu = GetMenu(Me.hwnd)
miMenuInfo.cbSize = Len(miMenuInfo)
ret = GetMenuInfo(hMenu, miMenuInfo)
miMenuInfo.fMask = MIM_APPLYTOSUBMENUS Or MIM_BACKGROUND
miMenuInfo.hbrBack = hBrush
ret = SetMenuInfo(hMenu, miMenuInfo)
End Sub

Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Button = vbRightButton Then
Me.PopupMenu mnuMenu
End If
End Sub

Private Sub Form_paint()
Me.Line (0, 0)-(Me.Width, 0), &H808080
DrawStyle = 0
Me.Line (0, 2)-(Me.Width, 2), &HC0C0C0
End Sub