Need help!!!

[intell]

Люди, помогите! Нужно сделать так, чтобы картинка, находящаяся в пикчебоксе
двигалась только в ней, то есть не скравалась частично за ее бордером.
Есть код на передвижение. Визуально, передвижение должно быть таким же:

Private Declare Function SendMessage Lib "User32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Sub ReleaseCapture Lib "User32" ()
Private Const WM_NCLBUTTONDOWN = &HA1
Private Const HTCAPTION = 2
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, x As Single, Y As Single)
Dim ReturnValue As Long
If Button = 1 Then
Call ReleaseCapture
ReturnValue = SendMessage(KARTINKA.hwnd, WM_NCLBUTTONDOWN, HTCAPTION, 0&)
End If
End Sub

[alibek]

С таким кодом это не выйдет.
Нужно использовать MouseMove. Набросок кода такой (Picture1 - контейнер, Image1 - картинка)

Код: Выделить всё

Option Explicit

Private X0 As Single, Y0 As Single, fMoved As Boolean, fBusy As Boolean

...

Private Sub Image1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Button <> 1 Then Exit Sub
fMoved = True
X0 = X
Y0 = Y
End Sub

Private Sub Image1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim DX As Single, DY As Single
If fBusy Then Exit Sub
If Button <> 1 Then Exit Sub
fBusy = True
DX = X - X0
DY = Y - Y0
If Image1.Left + DX < Picture1.ScaleLeft Then DX = Picture1.ScaleLeft - Image1.Left
If Image1.Top + DY < Picture1.ScaleTop Then DY = Picture1.ScaleTop - Image1.Top
If Image1.Left + Image1.Width + DX > Picture1.ScaleLeft + Picture1.ScaleWidth Then DX = (Picture1.ScaleLeft + Picture1.ScaleWidth) - (Image1.Left + Image1.Width)
If Image1.Top + Image1.Height + DY > Picture1.ScaleTop + Picture1.ScaleHeight Then DY = (Picture1.ScaleTop + Picture1.ScaleHeight) - (Image1.Top + Image1.Height)
Image1.Move Image1.Left + DX, Image1.Top + DY
fBusy = False
End Sub

Private Sub Image1_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Button <> 1 Then Exit Sub
fMoved = False
End Sub