Запись переменных в текстовой файл

[G]

Как записать в *.txt переменные посланые asp скрипту из в Flash.
Может ли кто-нибуть написать конкретный пример?

Спасибо Grishechka

[skiperski]

Когда ASP-скрипт принимает вызов, то для него не важно откуда были посланы данные. Выбирай параметры из строки запросов QueryString или из коллекции Form в зависимости от метода передачи данных (Get/Post).

Код: Выделить всё

<%@ Language=VBScript%>
<%
Option Explicit

'Server Script Timeout in Seconds
Server.ScriptTimeout=60

Response.Buffer=True
Response.Expires=-100

Call Response.AddHeader("Pragma", "no-cache")
Call Response.AddHeader("Cache-Control", "no-cache")
Response.ContentType = "text/html; charset=windows-1251"

Function SaveParamsIntoFile(ByVal FileName)

   Const ForReading = 1
   Const ForWriting = 2
   Const ForAppending = 8

   Dim post, Source, v
   Dim fso, file, line

   post = (LCase(Request.ServerVariables("request_method")) = "post")
   If (post) Then
      Set Source = Request.Form
   Else
      Set Source = Request.QueryString
   End If

   FileName = Server.MapPath(FileName)
   Set fso = Server.CreateObject("Scripting.FileSystemObject")
   Set file = fso.OpenTextFile(FileName, ForWriting, True)
   With Source
      For Each v In Source
         line = v & "=" & Source(v)
         Response.Write line & "<br/>"
         file.WriteLine line
      Next
   End With
   file.Close

   Set file = fso.OpenTextFile(FileName, ForReading, True)
   SaveParamsIntoFile = file.ReadAll
   file.Close

   Set file = Nothing
   Set fso = Nothing
   Set Source = Nothing

End Function

Dim s

s = SaveParamsIntoFile("data.txt")
Response.Write "<hr>"
Response.Write s

%>


[G]

Огромное человеческое спасибо!!!